How would I programmatically add a row to a Dataset?

Question

I would like to use a Dataset to track the process of a lengthy calculation over a large volume of material. Dataset appeals to me because of the power of the queries and it also looks like it may offer a simple way to serialize results to a data store.

I have not been able to figure out how to programmatically add rows to an existing Dataset.

If I initialize a Dataset named eMap:

          eMap = Dataset[{<|"ModuleId"->0,
                       "SegmentId"->0,
                       "x1"->0, "y1"->0, "z1"->0,
                       "x2"->0, "y2"->0, "z2"->0|>}]

How would I programmatically add an additional row with the same columns to eMap so that eMap may be queried?

I have tried Append and AppendTo without success.

  eMap = AppendTo[eMap, {<|"ModuleId"->0,
                       "SegmentId"->0,
                       "x1"->0, "y1"->0, "z1"->0,
                       "x2"->0, "y2"->0, "z2"->0|>}]];

After the call above, if I issue:

eMap[1]

I get an error: Cannot apply Append to an expression of the form {__Association}.

Answer 1

If the curly braces are left out, this seems to work.

 Remove[eMap];
eMap = Dataset[{<|"ModuleId" -> 0, "SegmentId" -> 0, "x1" -> 0, 
     "y1" -> 0, "z1" -> 0, "x2" -> 0, "y2" -> 0, "z2" -> 0|>}];
eMap = AppendTo[
   eMap, <|"ModuleId" -> 0, "SegmentId" -> 1, "x1" -> 1, "y1" -> 0, 
    "z1" -> 0, "x2" -> 1, "y2" -> 0, "z2" -> 0|>];

One quick comment - the article referenced by b.gatessucks is well worth a look. This could be a basis for a very useful set of metadata management functions that allow developers to do SQL-Like operations similar to Alter Structure commands.

Answer 2

Append[eMap // Normal, eMap[1] // Normal] // Dataset

{<|"ModuleId" -> 0, "SegmentId" -> 0, "x1" -> 0, "y1" -> 0, "z1" -> 0, "x2" -> 0, "y2" -> 0, "z2" -> 0|>, <|"ModuleId" -> 0, "SegmentId" -> 0, "x1" -> 0, "y1" -> 0, "z1" -> 0, "x2" -> 0, "y2" -> 0, "z2" -> 0|>}

Note: using eMap[1] as per your example.

At this point, Dataset is not fully integrated with the rest of the language, hence the Normal workaround.

Answer 3

You can just use Join (in version 12.1):

eMap = Dataset[{<|"ModuleId" -> 0, "SegmentId" -> 0, "x1" -> 0, "y1" -> 0, 
    "z1" -> 0, "x2" -> 0, "y2" -> 0, "z2" -> 0|>}]

(* Dataset[{<|"ModuleId" -> 0, "SegmentId" -> 0, "x1" -> 0, "y1" -> 0, "z1" -> 0, 
       "x2" -> 0, "y2" -> 0, "z2" -> 0|>}] *)

eMap2 = Join[eMap, 
  Dataset@{<|"ModuleId" -> 0, "SegmentId" -> 0, "x1" -> 0, "y1" -> 0, 
     "z1" -> 0, "x2" -> 0, "y2" -> 0, "z2" -> 0|>}]

(* Dataset[{<|"ModuleId" -> 0, "SegmentId" -> 0, "x1" -> 0, "y1" -> 0, "z1" -> 0, 
       "x2" -> 0, "y2" -> 0, "z2" -> 0|>, <|"ModuleId" -> 0, 
   "SegmentId" -> 0, "x1" -> 0, 
       "y1" -> 0, "z1" -> 0, "x2" -> 0, "y2" -> 0, "z2" -> 0|>}] *)