Getting a String from a list of strings

Question

Is there a way to write down Mathematica with a string such as:
{"M","a","t","h","e","m","a","t","i","c","a"}?

Answer 1

Supporting the maxim "there is always another way to do it":

list = {"M","a","t","h","e","m","a","t","i","c","a"};

StringJoin accepts lists directly, and in fact is faster this way:

StringJoin @ list

"Mathematica"

Also, StringJoin has the short form <> therefore you could also use:

"" <> list

"Mathematica"

Speed check:

large = Characters@ExampleData[{"Text", "LoremIpsum"}];

Do[StringJoin @@ large, {5000}] // Timing

Do[StringJoin @ large, {5000}]  // Timing

Do["" <> large, {5000}]         // Timing

Version 7.0.1 timings:

{1.622, Null}

{0.702, Null}

{0.718, Null}

Version 10.1.0 timings:

{0.6864, Null}

{0.4524, Null}

{0.4524, Null}

Answer 2

Just for something different Fold works too:

Fold[#1 <> #2 &, "", {"M", "a", "t", "h", "e", "m", "a", "t", "i", 
  "c", "a"}]

"Mathematica"

Answer 3

Use StringJoin:

StringJoin @@ {"M", "a", "t", "h", "e", "m", "a", "t", "i", "c", "a"}

"Mathematica"

Answer 4

If we're going to get silly about it:

TextRecognize @ Graphics @ MapIndexed[Text[Style[#1, 50], {#2[[1]], 0}] &, list]

Answer 5

At risk of taking "even more" too far here is a method that does not use any function with "String" in the name:

list = {"M", "a", "t", "h", "e", "m", "a", "t", "i", "c", "a"};

FromCharacterCode @ Flatten @ ToCharacterCode @ list

Or using an export function:

ExportString[{list}, "Table", "FieldSeparators" -> ""]

Or a formatting function:

ToString @ Row @ list

Answer 6

Just to stretch even more the limits of "there is always another way to do it" (Mr.Wizard), here is a way to NOT use StringJoin at all:

chars = {"M", "a", "t", "h", "e", "m", "a", "t", "i", "c", "a"};
Fold[StringInsert[#1, #2, -1] &, "", Flatten@chars]

"Mathematica"

And a simpler one:

StringExpression @@ chars

Using built-in path functions to complicate things (use ToFileName if prior to version 7):

StringReplace[FileNameJoin@chars, "\\" -> ""]

Answer 7

In versions 10.1+, there is also StringRiffle:

StringRiffle[list, ""]

"Mathematica"