26
$\begingroup$

How do I control the shape of my arrow heads? LaTeX's TikZ package has a wide variety of predefined arrowhead styles, some of which I'd like to try to match for Mathematica figures I'm importing into a LaTeX document:

LaTeX arrow examples

But Mathematica's default arrowhead style comes nowhere near any of these. For example,

Graphics[{Thick, Arrow[{{0, 0}, {-50, 0}}]}] 

yields

Default Mathematica arrow

Earlier versions of Mathematica had options for controlling arrowhead shape, but those seem to be gone in 8.0.

How can I get the shape of my Mathematica arrowheads to match the LaTeX TikZ arrowhead styles?

$\endgroup$
  • $\begingroup$ In addition, Mathematica's arrows are scaled differently from LaTeX arrowheads, using a logic I can't discern. Ideally I'd like to also ensure that my Mathematica arrows scale the same way LaTeX arrows do; but that is perhaps a separate question. $\endgroup$ – orome Jun 19 '12 at 17:39
  • $\begingroup$ Have you looked at the documentation of Arrowheads? $\endgroup$ – Heike Jun 19 '12 at 17:42
  • $\begingroup$ Yes, naturally. Nothing there got me close. $\endgroup$ – orome Jun 19 '12 at 17:43
  • 2
    $\begingroup$ @Heike: that only gives one example for a custom arrowhead, but nothing about predefined types (though StreamPlot has a miriad of different built-in arrow styles). $\endgroup$ – István Zachar Jun 19 '12 at 17:44
  • 2
    $\begingroup$ See this question -- it will show how to define custom shapes, and set absolute arrowhead sizes. $\endgroup$ – Mr.Wizard Jun 19 '12 at 17:58
25
$\begingroup$

Here is a Manipulate to design yourself an Arrow:

DynamicModule[{top, baseMid, rightBase, outerMidRight, innerMidRight},
 Manipulate[
  top = {0, 0};
  baseMid = {1, 0} baseMid;
  rightBase = {1, -1} leftBase;
  outerMidRight = {1, -1} outerMidLeft;
  innerMidRight = {1, -1} innerMidLeft;
  h = Graphics[
    {
     Opacity[0.5],
     FilledCurve[
      {
       BSplineCurve[{baseMid, innerMidLeft, leftBase}],
       BSplineCurve[{leftBase, outerMidLeft, top}],
       BSplineCurve[{top, outerMidRight, rightBase}],
       BSplineCurve[{rightBase, innerMidRight, baseMid}]
       }
      ]
     }
    ],
  {{baseMid, {-2, 0}}, Locator},
  {{innerMidLeft, {-2, 0.5}}, Locator},
  {{leftBase, {-2, 1}}, Locator},
  {{outerMidLeft, {-1, 1}}, Locator}
  ]
 ]

Mathematica graphics

It is easy to add more control points if the need arises.

The arrowhead graphics is put in the variable h. Note that it contains an Opacity function for better visibility of the control points. You need to remove that if you want to have a fully saturated arrow head.

Some examples generated with this Manipulate using:

Graphics[
  { Arrowheads[{{Automatic, 1, h /. Opacity[_] :> Sequence[]}}],
    Arrow /@ 
        Table[{{0, 0}, {Sin[t], Cos[t]}}, {t, 0, 2 \[Pi] - 2 \[Pi]/20, 2 \[Pi]/20}]
  }, 
     PlotRangePadding -> 0.2
 ]

Mathematica graphics

The code for the arrow heads can be found in h. Just copy the graphics or the FullForm to store it for later use.

h /. Opacity[_] :> Sequence[] // FullForm

(* ==>
Graphics[{FilledCurve[{BSplineCurve[{{-0.496, 0.}, {-1., 0.48}, {-2,1}}],            
    BSplineCurve[{{-2, 1}, {-0.548, 0.44999999999999996}, {0, 0}}], 
    BSplineCurve[{{0, 0}, {-0.548, -0.44999999999999996}, {-2, -1}}], 
          BSplineCurve[{{-2, -1}, {-1., -0.48}, {-0.496, 0.}}]}]}
]
*)

EDIT
One more control point will cover most common shapes:

DynamicModule[{top, baseMid, outerMidRight, innerMidRight, 
  innerBaseRight, outerBaseRight},
 Manipulate[
  top = {0, 0};
  baseMid = {1, 0} baseMid;
  innerBaseRight = {1, -1} innerBaseLeft;
  outerBaseRight = {1, -1} outerBaseLeft;
  outerMidRight = {1, -1} outerMidLeft;
  innerMidRight = {1, -1} innerMidLeft;
  h = Graphics[
    {
     Opacity[0.5],
     FilledCurve[
      {
       BSplineCurve[{baseMid, innerMidLeft, innerBaseLeft}],
       Line[{innerBaseLeft, outerBaseLeft}],
       BSplineCurve[{outerBaseLeft, outerMidLeft, top}],
       BSplineCurve[{top, outerMidRight, outerBaseRight}],
       Line[{outerBaseRight, innerBaseRight}],
       BSplineCurve[{innerBaseRight, innerMidRight, baseMid}]
       }
      ]
     }
    ],
  {{baseMid, {-2, 0}}, Locator},
  {{innerMidLeft, {-2, 0.5}}, Locator},
  {{innerBaseLeft, {-2, 1}}, Locator},
  {{outerBaseLeft, {-2, 1.1}}, Locator},
  {{outerMidLeft, {-1, 1}}, Locator}
  ]
 ]

Mathematica graphics

Mathematica graphics

$\endgroup$
  • $\begingroup$ Amazing! Thanks! $\endgroup$ – orome Jun 20 '12 at 16:13
23
$\begingroup$

One source of arrowhead shapes is Graph which comes with a list of predefined arrowhead shapes that you can set using the option EdgeShapeFunction. You can get the names of these shapes by doing something like

arrowheadNames = GraphElementData["Edge"];

Unfortunately, these names by themselves are useless in Arrowheads. Luckily there is a way to extract the Graphics specifications of these arrowheads by converting a Graph to Graphics using Show and extracting the Arrowheads directives:

headlist = 
  Flatten[Cases[
      Show[Graph[{1 <-> 2}, EdgeShapeFunction -> #]], 
      Arrowheads[a_] :> 
       Cases[a, b_GraphicsBox :> ToExpression[b], Infinity, 1], 
      Infinity, 1] & /@ arrowheadNames];

GraphicsGrid[Partition[headlist, 5, 5, {1, 1}, ""], Frame -> All]

Mathematica graphics

You can use these in Arrowheads as follows:

grlist = Graphics[{Arrowheads[{{.3, 1, #}}], Arrow[{{0, 0}, {1, 1}}]}] & /@ headlist;

GraphicsGrid[Partition[grlist, 5, 5, {1, 1}, ""], Frame -> All]

Mathematica graphics

$\endgroup$
  • $\begingroup$ I can't get this code to work anymore. $\endgroup$ – orome Apr 16 '15 at 18:06
  • $\begingroup$ Same here, on Mathematica 10.1, this code does not work anymore. $\endgroup$ – jibe Jul 15 '15 at 12:32
  • 2
    $\begingroup$ For this to work in Mathematica 10, replace the GraphicsBox with Graphics: headlist = Flatten[Cases[ Show[Graph[{1 \[DirectedEdge] 2}, EdgeShapeFunction -> #]], Arrowheads[a_] :> Cases[a, _Graphics, Infinity, 1], Infinity, 1] & /@ arrowheadNames]; $\endgroup$ – Gerli Jul 23 '15 at 9:52
  • $\begingroup$ There is a mistyping, Headlist is written at the beginning with a small l “Headlist” at the end with a capital L “HeadList”... $\endgroup$ – user41426 Jul 2 '16 at 12:22
  • $\begingroup$ I've fixed it, @Phil. $\endgroup$ – J. M. is away Jul 2 '16 at 12:29

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service, privacy policy and cookie policy

Not the answer you're looking for? Browse other questions tagged or ask your own question.