4
$\begingroup$

Consider the $2\times 2$ matrices \begin{align} A=\begin{bmatrix} a_{11} & a_{12} \\ a_{21} & a_{22} \end{bmatrix} \end{align} and \begin{align} B=\begin{bmatrix} b_{11} & b_{12} \\ b_{21} & b_{22} \end{bmatrix} \end{align} and the vector \begin{align} u=\begin{bmatrix}\cos\theta \\ \sin\theta\end{bmatrix} \end{align} For all $\theta\in[0,2\pi]$, and given $A$ and $B$, consider the set of 2-D points whose co-ordinates are given as $(u^TAu,u^TBu)$, How do I plot this region?

$\endgroup$
  • 2
    $\begingroup$ ParametricPlot[{u.a.u, u.b.u}, {θ, 0, 2 π}] $\endgroup$ – Rahul Jan 2 '15 at 5:51
7
$\begingroup$

Consider

A = {{1, 2}, {3, 4}};
B = {{5, 6}, {7, 8}};

Then

ParametricPlot[
 {
  {Cos[θ], Sin[θ]}.A.{Cos[θ], Sin[θ]},
  {Cos[θ], Sin[θ]}.B.{Cos[θ], Sin[θ]}
  },
 {θ, 0, 2 π}]

enter image description here

Or more generally,

A = {{1, 2}, {3, 4}};
B = {{5, 6}, {x, 8}};

ParametricPlot[
 Table[{{Cos[θ], Sin[θ]}.A.{Cos[θ], 
      Sin[θ]}, {Cos[θ], Sin[θ]}.B.{Cos[θ],
       Sin[θ]}}, {x, -9, 9}] // Evaluate, {θ, 0, 
  2 π}, AspectRatio -> 1]

Mathematica graphics

$\endgroup$
  • $\begingroup$ I hope you don't mind the edit... $\endgroup$ – chris Jan 2 '15 at 8:44
  • $\begingroup$ Probably, this is not the right place, but am just trying. Any explanation or thoughts as to why this looks like a ellipse? $\endgroup$ – dineshdileep Jan 2 '15 at 16:41
  • 1
    $\begingroup$ It is an ellipse. Here {x,y}.A.{x,y} is a quadratic form in x and y: a x^2 + b x + c y^2 + d6 + e, and likewise for matrix B. Thus the general solutions are the quadratics (circle, ellipse, hyperbola, etc.)... however for our case, {x,y} = {Cos[Theta],Sin[Theta]} and hence with bound norm of 1.0, restricting the solutions to generalized ellipses: ellipses, circles, (degenerate) lines, and (degenerate) points. Let A = B to see one degenerate case. $\endgroup$ – David G. Stork Jan 2 '15 at 16:58
3
$\begingroup$

Any explanation or thoughts as to why this looks like a ellipse?

A = Array[a, {2, 2}];
B = Array[b, {2, 2}];
u = {Cos[t], Sin[t]};
({u.A.u, u.B.u} // TrigReduce // Simplify)
  /. {a[i_, j_] :> Subscript[a, i, j], b[i_, j_] :> Subscript[b, i, j]}

$$\left\{\frac{1}{2} \left(\left(a_{1,2}+a_{2,1}\right) \sin (2 t)+\left(a_{1,1}-a_{2,2}\right) \cos (2 t)+a_{1,1}+a_{2,2}\right),\frac{1}{2} \left(\left(b_{1,2}+b_{2,1}\right) \sin (2 t)+\left(b_{1,1}-b_{2,2}\right) \cos (2 t)+b_{1,1}+b_{2,2}\right)\right\}$$

So the plot is a translated Lissajous figure with both frequencies equal to $2$. As the frequencies are equal, the figure is an ellipse.

$\endgroup$

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service, privacy policy and cookie policy

Not the answer you're looking for? Browse other questions tagged or ask your own question.