Module function corrupts string? [closed]

Question

I have the module who should replace some elements of a matrix with checkboxes

addChekboxesTable[x0_] := Module[{x = x0},
  For[i = 1, i <= Length[x], i++,
    For[j = 1, j <= Length[x[[i]]], j++,
     If[x[[i, j]] == "x",
       x[[i, j]] = Checkbox[True];
       ]
      If[x[[i, j]] == "o",
       x[[i, j]] = Checkbox[False];
       ]
      If[x[[i, j]] == "u",
       x[[i, j]] = Checkbox[3, {1, 2, 3}];
       ]
     ]
    ]
   x
  ]

I call the module like:

pp = addChekboxesTable[{{"Datatype", "Variable Name", "S0", "S1", 
     "x"}}];

And then the string is corrupted :( It has some Nulls and Times

List[List[Times["Datatype",Null],Times["Variable Name",Null],Times["S0",Null],Times["S1",Null],Times[Null,Checkbox[True]]]]

I dont know why :(( Any ideas ?

Ps: if i extract the instruction from module, outside , the code works O_O

I changed the function to the next for by adding some ";" at the end of instructions. It fixed but i dont know why O_O

addChekboxesTable[x0_] := Module[{x = x0},
  For[i = 1, i <= Length[x], i++,
   For[j = 1, j <= Length[x[[i]]], j++,
     If[x[[i, j]] == "x",
      x[[i, j]] = Checkbox[True];
      ];
     If[x[[i, j]] == "o",
      x[[i, j]] = Checkbox[False];
      ];
     If[x[[i, j]] == "u",
      x[[i, j]] = Checkbox[3, {1, 2, 3}];
      ];
     ];
   ];
  x
  ]

Answer 1

There is a missing semicolon just behind the end of the outer For, just before the x, corrected below.

addChekboxesTable[x0_] := Module[{x = x0}, 
  For[i = 1, i <= Length[x], i++, 
   For[j = 1, j <= Length[x[[i]]], j++, 
    If[x[[i, j]] == "x", x[[i, j]] = Checkbox[True];] If[
      x[[i, j]] == "o", x[[i, j]] = Checkbox[False];] If[
      x[[i, j]] == "u", x[[i, j]] = Checkbox[3, {1, 2, 3}];]]]; x]

The result of the For block is Null so the result, without that semicolon, is Null times x.

Answer 2

Replacement rules make this much easier, as Ymareth indicated.

Make a list of rules like:

r2 = {"x" -> Checkbox[True], "o" -> Checkbox[False], 
   "u" -> Checkbox[3, {1, 2, 3}]};

Then apply these to the matrix m as:

m/.r2

---

Note that this code is idiomatic Mathematica and imminently readable by anyone familiar with it. Nested For loops and term by term rewriting are both strongly discouraged in Mathematica - and not just for aesthetic reasons - rule based and functional programming are typically much more efficient. Let's compare the two approaches. First, we'll generate a matrix of characters, which is (admittedly) absurdly large to illustrate the point.

m = RandomChoice[{"x", "o", "j"}, {1000, 1000}];

OK, let's try out the approach here:

mOut = m /. r2;  // AbsoluteTiming
mOut[[1;;10,1;;10]] // Grid
(* Out: {0.275804, Null} *)

Just over a quarter second - and looks good too! Let's try the other approach.

addChekboxesTable[m]; // AbsoluteTiming
(* Out: {58.618144, Null} *)

Nearly a full minute.