1
$\begingroup$

The inverse Laplace transform is only returning exponentials. I know it is from the definition $$ \frac{1}{2\pi i}\int_{\gamma - i\infty}^{\gamma + i\infty}F(s)e^{st}ds = \sum\text{Res} $$ However, I would like to have the results returned as cosine and sine functions. I tried FullSimplify and TrigReduce but this does nothing. Is there anyway to force Mathematica to return trig functions?

InverseLaplaceTransform[(
 12*183.26)/((s^2 + 183.26^2) (55*s^2 + (
    5.5*s^2 (s*24.2525 + 784.243))/(5.5*s^2 + 24.2525*s + 784.243) + 
    8000)), s, t]
$\endgroup$
  • 2
    $\begingroup$ Have you tried ExpToTrig? $\endgroup$ – bbgodfrey Dec 10 '14 at 16:20
  • 1
    $\begingroup$ Try using the ExpToTrig command. $\endgroup$ – TransferOrbit Dec 10 '14 at 16:20
1
$\begingroup$
lap = InverseLaplaceTransform[(12*183.26)/((s^2 + 183.26^2) (55* s^2 + (5.5*s^2 (s*24.2525 + 784.243))/
               (5.5*s^2 + 24.2525*s + 784.243) + 8000)), s, t];

{re, im} = (Simplify[#@lap, Assumptions -> t ∈ Reals] // ComplexExpand // Chop) & /@ {Re, Im};

re
(* 

 0.0000328276 E^(-0.675566 t) Cos[10.5332 t] - 
 0.0000164059 E^(-1.74968 t) Cos[13.5317 t] - 
 0.0000164059 E^(-1.74968 t) Cos[13.5317 t] - 
 1.59052*10^-8 Cos[183.26 t] + 
 0.0000551514 E^(-0.675566 t) Sin[10.5332 t] + 
 0.0000214317 E^(-1.74968 t) Sin[13.5317 t] + 
 0.0000214317 E^(-1.74968 t) Sin[13.5317 t] - 
 6.52719*10^-6 Sin[183.26 t]

*)

The imaginary part is of course negligible

Edit: One step more:

p = (Plus @@@  Gather[List @@ re, (List @@ Last[List @@ (#1)] == 
                                   List @@ Last[List @@ (#2)] &)]) /. 
                                    f_[a_ t] :> f[Round[a, .0000001] t]

Plus @@ (FullSimplify /@ p)

(*

-1.59052*10^-8 Cos[183.26 t] + 
 E^(-0.675566 t) (0.0000328276 Cos[10.5332 t] + 0.0000551514 Sin[10.5332 t]) + 
 E^(-1.74968 t) (-0.0000328117 Cos[13.5317 t] + 0.0000428634 Sin[13.5317 t]) -    
 6.52719*10^-6 Sin[183.26 t]
*)
|improve this answer|||||
$\endgroup$

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service, privacy policy and cookie policy

Not the answer you're looking for? Browse other questions tagged or ask your own question.