I'm trying to convert an image with several overlapping dots into a Graph. The goal is to be able to derive the Kirchhoff matrix for the randomly created "network of resistors" a.k.a dots with the function KirchhoffMatrix[]. Any thoughts or ideas?

Here's the image I'm trying to extract the graph from: enter image description here

Haha, sorry I suppose I have been pretty vague with this question. I am currently researching percolation simulations. The dots in the image represent metallic particles. The dots the overlap represent metallic particles connected via a resistor. We randomize the dots on the screen, group the ones that are touching with MorphologicalComponents[] // Colorize , and then we Isolate the 'BackBone Cluster' a.k.a the largest component with DeleteSmallComponents[]. We check to see if the cluster spans all the way from the top to the bottom and if it does, the sample percolated. We are then trying to find the conductance of the sample from the BackBone cluster. We have been using the Finite Element Method for this, which requires the KirchhoffMatrix[].

Your answer, Vitaliy Kaurov, looks like it will very thoroughly answer my question. I'm going to test things before I accept it but thank you for putting so much time into it!!

  • $\begingroup$ What do you mean by "overlapping"? Contiguous pixels? $\endgroup$ Commented Jun 13, 2012 at 20:09
  • $\begingroup$ I can see how dots can be resistors in a network. Their role in the graph will be that of edges, but what will determine the vertices? $\endgroup$ Commented Jun 13, 2012 at 21:15
  • 2
    $\begingroup$ Possibly related: mathematica.stackexchange.com/q/5152/8 I can see how the dots are vertices but how do you know which ones are connected? That's where the percolation approach might be relevant. $\endgroup$
    – Verbeia
    Commented Jun 14, 2012 at 5:28
  • 2
    $\begingroup$ Could you please give some details/background to your problem, maybe some references? I am curious. $\endgroup$ Commented Jun 14, 2012 at 7:09
  • $\begingroup$ It's not clear to me either how you get from this image to a graph. Please explain a bit. What are those dots in the image? $\endgroup$
    – Szabolcs
    Commented Jun 14, 2012 at 8:10

1 Answer 1


==== Method 1 ===

Here is a way to get a graph from an image. MorphologicalGraph can get you started.

img = Import["https://i.sstatic.net/9HXZ5.png"];
g = MorphologicalGraph[img]

enter image description here

And here is your KirchhoffMatrix of the graph. Please note that MatrixPlot averages values for the best visual representation, - actual plot would be too detailed to be a good representation.

m = KirchhoffMatrix[g]; MatrixPlot[m]

enter image description here

A good guess is that your graph, due to its random nature, not all entirely connected. This maybe important in your case, because with no connection you have no conductance. Here is the way to find all connected components, highlight them and compute their own KirchhoffMatrix.

cc = ConnectedComponents[g];
index = Length /@ ConnectedComponents[g];
ctrl = Sort[MapThread[Rule, {cc, index}], #1[[2]] > #2[[2]] &];
 GraphicsRow[{HighlightGraph[g, Subgraph[g, n], 
    GraphStyle -> "LargeNetwork"], 
   MatrixPlot[KirchhoffMatrix[Subgraph[g, n]], 
    ColorFunction -> "DarkBands"]}, 
  ImageSize -> 600], {{n, ctrl[[1, 1]], "Vertex number"}, ctrl}, 
 FrameMargins -> 0]

enter image description here

Let's do some math now. Here is a famous property:

The number of times 0 appears as an eigenvalue in the KirchhoffMatrix is the number of connected components in the graph.

The number of connected comments (separate sub-graphs) is found as

 ConnectedComponents[g] // Length


And as you can see it is equal to the number of zero eigenvalues :

 ev = Chop[Eigenvalues[N@m]]; Count[ev, 0]


Isn't it great to see programming and math matching up perfectly?

Here is the way to list all connected sub-graphs separately. Mouse-over will give KirchhoffMatrix.

   MatrixPlot[KirchhoffMatrix[Subgraph[g, #]], 
    ColorFunction -> "DarkBands", 
    ImageSize -> 200]] & /@ (Subgraph[g, #, ImageSize -> 80, 
     VertexSize -> 0] & /@ ctrl[[All, 1]])

enter image description here

Note some extra image processing before MorphologicalGraph would result in different graphs. For example finding first SkeletonTransform or DistanceTransform would change the game:

GraphicsRow[{DistanceTransform[Dilation[img, 3]] // ImageAdjust,
  SkeletonTransform[img]}, ImageSize -> 600]

enter image description here

So if you now apply MorphologicalGraph function to these images you of course will get different graphs as result. This maybe useful because there is no exact guarantee that MorphologicalGraph will give you always what you need in all cases, especially with low-res images. Below is an example of possible issue - with real question being where exactly is the boundary between these two cases?

Grid@{{r = .6; 
   img = ColorNegate@
     Graphics[{Disk[{0, 0}, r], Disk[{.5, .9}, r], Disk[{1, 0}, r]}],
   MorphologicalGraph[img, VertexSize -> .1]},
  {r = 1.2; 
   img = ColorNegate@
     Graphics[{Disk[{0, 0}, r], Disk[{.5, .9}, r], Disk[{1, 0}, r]}],
   MorphologicalGraph[img, VertexSize -> .1]}}

enter image description here

So this is just the word of caution - you may need some image pre-processing before you get your MorphologicalGraph. Or you may use something else - see method below.

==== Method 2 ===

This is just an outline, not complete solution:

1) This question and answers by @Verbeia and @Szabolcs and Fred Simons on MathGroup are a starting point

2) They work only if you know center and radius of every point in your image - which you do NOT

3) You can get center and radius of every point by using for example ComponentMeasurements function. Then you can apply methods by @Verbeia and @Szabolcs and Fred Simons on MathGroup.

  • Example 1: This Wolfram Blog gives code for finding what you need even in the case of overlapping particles, like this (image - courtesy of Wolfram Research):

enter image description here

enter image description here

  • $\begingroup$ +1 for SkeletonTransform - what other nuggets of amazingness are hidden away in little-used corners of this language? $\endgroup$
    – Verbeia
    Commented Jun 14, 2012 at 7:32
  • 1
    $\begingroup$ FWIW: since the Kirchhoff matrix is symmetric anyway, one could just use MatrixRank[] to help in computing the number of zero eigenvalues: Length[m] - MatrixRank[m]. $\endgroup$ Commented Jun 14, 2012 at 7:56
  • $\begingroup$ @Verbeia thanks ;-) Added another "corner" DistanceTransform. $\endgroup$ Commented Jun 14, 2012 at 8:09

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service and acknowledge you have read our privacy policy.

Not the answer you're looking for? Browse other questions tagged or ask your own question.