I need to create a VOLUME under f[x,y]= x (y^3 + 1)^(1/2) that's above the triangular region bounded by y=x/3, y=2, and x=0.
I know how to make the plot of the function over an area, such as Plot3D[f[x, y], {x, 0, 6}, {y, 0, 2}]. However, I do not know how to make it exclusively over the triangle.
$\begingroup$
$\endgroup$
0
Add a comment
|
4 Answers
$\begingroup$
$\endgroup$
f[x_, y_] = x (y^3 + 1)^(1/2);
Plot3D[f[x, y], {x, 0, 6}, {y, x/3, 2}, Filling -> 0]
Plot3D[f[x, y], {x, 0, 6}, {y, 0, 2},
RegionFunction -> Function[{x, y}, x/3 <= y <= 2 && x >= 0],
Filling -> 0]
RegionPlot3D[0 <= z <= f[x, y] && x/3 <= y <= 2 && 0 <= x <= 6,
{x, 0, 6}, {y, 0, 2}, {z, 0, 18}, PlotPoints -> 51]
Maximize[{f[x, y], x >= 0, x/3 <= y <= 2}, {x, y}]
{18, {x -> 6, y -> 2}}
answered Nov 24, 2014 at 4:17
$\begingroup$
$\endgroup$
2
Several methods. one of them is:
Plot3D[x (y^3 + 1)^(1/2), {x, 0, 6}, {y, 0, 2},
RegionFunction -> Function[{x, y}, y <= 2 && y >= 3 x && x >= 0]]
answered Nov 24, 2014 at 3:47
$\begingroup$
$\endgroup$
1
In V10+:
Plot3D[x (y^3 + 1)^(1/2),
{x, y} ∈ Polygon[{{0, 0}, {6, 2}, {0, 2}}],
AxesLabel -> Automatic, Filling -> 0]
Also
DiscretizeRegion[
ImplicitRegion[0 <= z <= x (y^3 + 1)^(1/2), {{x, 0, 6}, {y, 0, 2}, {z, 0, 18}}]
]
answered Nov 24, 2014 at 3:58
-
$\begingroup$ I tried this and realized I wrote the problem incorrectly. I don't need the slice of f[x,y] over the triangle. Instead I need the volume between the triangle on the xy plane and f[x,y]. It should be a solid with a triangular base. Thank you for your quick response, and I apologize for my poor wording. This is my first time using the program. $\endgroup$– NickNov 24, 2014 at 4:06
$\begingroup$
$\endgroup$
NIntegrate x (y^3 + 1)^(1/2) over Polygon[{{0, 0}, {6, 2}, {0, 2}}]:
NIntegrate [x (y^3 + 1)^(1/2), {x, y} \[Element] Polygon[{{0, 0}, {6, 2}, {0, 2}}]]
Answer:26.
answered Nov 24, 2014 at 4:35