How to obtain transparent animated gif via Export?

Question

I have the following code to create animated GIFs:

ClearAll["`*"];
xmin = -3;
xmax = 4;
ymin = -10;
ymax = 3;
line1 = Line[{{xmin, ymin}, {xmin, ymax}}];
line2 = Line[{{xmax, ymin}, {xmax, ymax}}]; 
slides = 8; 
cmin = -10; 
cmax = 5/2; 
v = Table[Manipulate[
     Plot[{1/3 x^3 + x^2 + x - (2 x^2 + 4 x), c}, {x, xmin, xmax}, 
      PlotStyle -> {Blue, Red}, AspectRatio -> GoldenRatio, 
      PlotRange -> {{xmin, xmax}, {ymin, ymax}}, 
      Epilog -> {Directive[{Green, Green}], line1, line2}, 
      Background -> None], {{c, k/slides, "Constant:"}, cmin, cmax}],  
     {k, cmin*slides, cmax*slides}]; 
v = Join[v[[1 ;; Dimensions[v][[1]] - 1]], Reverse[v]];

When I use:

Export["testManip007.gif", v]

I obtained:

In order to get transparent background gif, I tried the following which worked for other cases:

Export["testManip007t.gif", v, "TransparentColor" -> White]

but the resulted is:

Additionally:

Export["testManip003t.gif", v, "DisplayDurations" -> 0.1, 
 "TransparentColor" -> White]

always causes error message and empty output.

How to solve the problems?

Answer 1

Note for Version 11.1: As commented by LCFactorization the option setting

"TransitionEffect" -> Background 

is no longer working (error message + nothing exported).

The solution is to use "TransitionEffect" -> "Background" instead, which doesn't produce the desired result in version 10.4 and earlier.

---

By default the frames of a GIF are stacked on top of each other. One can change this behavior using the Export option "TransitionEffect" -> Background:

Export["testManip007t.gif", v, "TransparentColor" -> White, "TransitionEffect" -> Background]

The default setting is "TransitionEffect" -> None.

Answer 2

Since Mathematica still seems not to support transparent animated gifs, one can work around the problem by exporting ".png" files and using an external program to stitch them together into an animated gif. For example:

ExportAsTransparentGIF[dir_, basefn_, frames_, ExportOptions___] := 
 Module[{b = 10, n, filename, filenames},
  n = 1 + Round@Log[b, Length[frames]];
  filenames = 
   Table[filename = dir <> basefn <> IntegerString[i, b, n] <> ".png";
     Export[filename, frames[[i]], Background -> None, 
     ExportOptions];
    filename, {i, Length[frames]}];
  command = 
   "/opt/homebrew/bin/convert -dispose 2 -set delay 0 " <> 
    StringRiffle[filenames] <> " " <> dir <> basefn <> 
    "animated.gif";
  Run[command];
  (* cleanup *) 
  command = "rm " <> StringRiffle[filenames];
  Run[command];
  ]

Here I am using the convert command from ImageMagick, installed on my mac with homebrew.

gTetra = Tetrahedron[];
Nt = 150;
frames = Table[t = (2. Pi) i/Nt;
   Show[Graphics3D[
     GeometricTransformation[gTetra, 
      RotationTransform[t, UnitVector[3, 3]]]], 
    Boxed -> False, SphericalRegion -> Sphere[{0, 0, 0}, 0.7]], {i, 
    Nt}];

ExportAsTransparentGIF["~/png-repo/", "Tetra-spin-", frames];