Fitting data to a circle with FindFit

Question

I'm currently trying to use the Mathematica's FindFit command to fit a curve of some data to the bottom half of a circle. The data is of the form

Data = {{a1, a2}, {b1, b2}, ...} 

My code looks like as follows

s = FindFit[Data, y0 - Sqrt[R^2 - (x - x0)^2], {x0, y0, R}, x]

The window is printing the below error,

FindFit::nrlnum: The function value {74724.4 + (-1. + y)^2, 75066.6 + (-1. + y)^2, 75409.6 + (-1. + y)^2, 75753.3 + (-1. + y)^2, 76097.9 + (-1. + y)^2, 76443.2 + (-1. + y)^2, <<40>>, 91274.4 + (-1. + y)^2, 91652.5 + (-1. + y)^2, 92031.4 + (1. + y)^2, 92411.1 + (-1. + y)^2, <<71>>} is not a list of real numbers with dimensions {121} at {x0, y0, R} = {1., 1., 1.}. >>

Any help would be appreciated.

Answer 1

Here is an approach using linear regression:

circfit[pts_] := Module[{reg, lm, bf, exp, center, rad},
  reg = {2 #1, 2 #2, #2^2 + #1^2} & @@@ pts;
  lm = LinearModelFit[reg, {1, x, y}, {x, y}];
  bf = lm["BestFitParameters"];
  exp = (x - #2)^2 + (y - #3)^2 - #1 - #2^2 - #3^2 & @@ bf;
  {center, rad} = {{#2, #3}, Sqrt[#2^2 + #3^2 + #1]} & @@ bf;
  circlefit[{"expression" -> exp, "center" -> center, 
    "radius" -> rad}]]; circlefit[list_][field_] := field /. list;
circlefit[list_]["Properties"] := list /. Rule[field_, _] :> field;
circlefit /: ReplaceAll[fields_, circlefit[list_]] := fields /. list;
Format[circlefit[list_], StandardForm] := 
 HoldForm[circlefit]["<" <> ToString@Length@list <> ">"]

This assumes that underlying data is a circle and aim is to find center and radius. There are doubtless much better ways.

For fun (and done quickly, so apologies for some inefficiencies and ugliness):

Manipulate[
 pt1 = Table[{x, cy + Sqrt[rad^2 - (x - cx)^2]}, {x, -4, 4, 0.1}];
 pt2 = Table[{x, cy - Sqrt[rad^2 - (x - cx)^2]}, {x, -4, 4, 0.1}];
 pt = Cases[Join[pt1, pt2], {_Real, _Real}];
 pts = pt + RandomReal[{-p, p}, {Length[pt], 2}];
 With[{fit = circfit[pts]},
  Column[{Show[
     ContourPlot[Evaluate@fit["expression"], {x, -1, 8}, {y, -1, 8}, 
      Contours -> {0}, ContourShading -> None, 
      ContourStyle -> Directive[Red, Thick]], ListPlot[pts], 
     AspectRatio -> Automatic, PlotLabel -> fit["expression"] == 0, 
     ImageSize -> 400, PlotRange -> {{-1, 8}, {-1, 8}}],
    Grid[{{"variable", "value", "model"}, {"center", {cx, cy}, 
       fit["center"]}, {"radius", rad, fit["radius"]}}]
    }]], {p, 0.05, 1},
 {cx, 0, 2},
 {cy, 0, 2},
 {rad, 1, 5}
 ]

Answer 2

Not exactly the problem, but I have this code languishing on my hard drive to compute a circle center and radius given a bunch of pts. From there it is straight-forward to get the polynomial.

First make some data...

pts =
  Table[RandomReal[{.9, 1.1}] {Sin[#], Cos[#]} & @ RandomReal[{0, 2 π}], {10}]

(* {{0.347046, -0.930661}, {0.218395, -1.07027}, {0.890144, -0.179376}, \
{-0.828852, -0.367061}, {0.770728, 0.607237}, {-0.118834, 
  0.934153}, {0.21855, -0.949232}, {0.136237, 
  1.02154}, {-0.881469, -0.285087}, {-0.878687, -0.377516}}*)

Define a penalty function

penalty[c_, radius_, pts_] := (Map[radius - Norm[# - c] &, pts])^2 // Total

Use Minimize[ ] to find the center of the circle and radius

res = Minimize[penalty[{x, y}, rr, pts], {x, y, rr}]

(* {0.0268756, {x -> 0.0247297, y -> -0.0119147, rr -> 0.969958}} *)

circ = Circle[{x, y}, rr] /. (res // Last)  

Show[circ // Graphics, ListPlot[pts]]

Answer 3

I added a third element to the data list to give a "z" value that is a radius of 1.

Data = {{a1, a2, 1}, {b1, b2, 1}, ...} 

Then, the FindFit function works well.

FindFit[data, ((x - a)^2 + (y - b)^2)/r^2, {a, b, r}, {x, y}]