3
$\begingroup$

I have a plane 2x + 5y + z = 10. I have determined that its intercepts are:

x = 5, y = 2, z = 10

I need to use Plot3D specifically to plot the plane formed by these three points. How might I go about doing that?

Improve this question
$\endgroup$
1
  • 1
    $\begingroup$ Welcome to Mathematica.SE! I suggest the following: 1) As you receive help, try to give it too, by answering questions in your area of expertise. 2) Read the faq! 3) When you see good questions and answers, vote them up by clicking the gray triangles, because the credibility of the system is based on the reputation gained by users sharing their knowledge. Also, please remember to accept the answer, if any, that solves your problem, by clicking the checkmark sign! $\endgroup$
    – user9660
    Nov 11, 2014 at 21:42

3 Answers 3

Reset to default
2
$\begingroup$ 
ContourPlot3D[2 x + 5 y + z == 10, {x, 0, 6}, {y, 0, 3}, {z, 0, 11}, Mesh -> None]

enter image description here

or

Graphics3D[Polygon[{{5, 0, 0}, {0, 2, 0}, {0, 0, 10}}],  BoxRatios -> 1, Axes -> True]

enter image description here

or

Plot3D[ Piecewise[{{10 - 2 x - 5 y, 10 - 2 x - 5 y >= 0}}, 
  Indeterminate], {x, 0, 6}, {y, 0, 3}, Mesh -> None, BoxRatios -> 1]

enter image description here

Improve this answer
$\endgroup$
4
$\begingroup$

You can use

InfinitePlane[{{5, 0, 0}, {0, 2, 0}, {0, 0, 10}}]

The plane will extend throughout the plot range:

Graphics3D[{
  InfinitePlane[{{5, 0, 0}, {0, 2, 0}, {0, 0, 10}}]
  },
 PlotRange -> {{0, 10}, {0, 10}, {0, 10}},
 Axes -> True]]

and

Graphics3D[{
  InfinitePlane[{{5, 0, 0}, {0, 2, 0}, {0, 0, 10}}]
  },
 PlotRange -> 10,
 Axes -> True]

preoduce, respectively,

Mathematica graphics

Improve this answer
$\endgroup$
1
$\begingroup$ 
Plot3D[10 - 2 x - 5 y, {x, 0, 6}, {y, 0, 3}, 
 RegionFunction -> Function[{x, y, z}, 0 < x && 0 < y && 0 < z], 
 Axes -> True, AxesOrigin -> {0, 0, 0}, Boxed -> False]

for view:

points = {{5, 0, 0}, {0, 2, 0}, {0, 0, 10}};
    Show[Graphics3D[{Blue, Sphere[points, .2]}, Axes -> True, 
      Boxed -> False, AxesOrigin -> {0, 0, 0}, 
      AxesStyle -> Directive[{Thick, Black}]], 
     Plot3D[10 - 2 x - 5 y, {x, 0, 6}, {y, 0, 3}, 
      RegionFunction -> Function[{x, y, z}, 0 < x && 0 < y && 0 < z], 
      Mesh -> None]]

enter image description here

Improve this answer
$\endgroup$

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service and acknowledge that you have read and understand our privacy policy and code of conduct.

Not the answer you're looking for? Browse other questions tagged or ask your own question.