# Why is ((v k)^-n (k v^n - v k^n))/(n - 1) == b so hard for Mathematica to solve (for v)?

I've tried using both Solve and Reduce. For something that takes maybe 3 minutes to solve with paper and pencil, I'm very surprised and disappointed.

Am I doing something inherently wrong? Making a stupid mistake? Is there some other function I should be using? Sorry if you've seen this one before.

Solve[((v k)^-n (k v^n - v k^n))/(n - 1) == b, v]

• Welcome to Mathematica.SE! I suggest the following: 1) As you receive help, try to give it too, by answering questions in your area of expertise. 2) Read the faq! 3) When you see good questions and answers, vote them up by clicking the gray triangles, because the credibility of the system is based on the reputation gained by users sharing their knowledge. Also, please remember to accept the answer, if any, that solves your problem, by clicking the checkmark sign!
– user9660
Nov 11, 2014 at 20:22
• What are you solving for? Also, make sure you have specified Assumptions for all the parameters. Nov 11, 2014 at 20:35
• Thanks to Karsten for restoring my original question. Solving for v. Only assumption used is n!=1. Nov 11, 2014 at 20:49
• And everything Real perhaps? Nov 11, 2014 at 20:55

It requires a transformation that is not generically valid. Also it is a bit hard to make it happen using Simplify due to the default complexity measure.

Solve[
Simplify[((v k)^-n (k v^n - v k^n))/(n - 1) == b,
Assumptions -> k > 0,
ComplexityFunction -> (LeafCount[#] +
5*Count[#, Power[aa_, Except[_Integer]], Infinity] &)], v]

During evaluation of In[181]:= Solve::ifun: Inverse functions are being used by Solve, so some solutions may not be found; use Reduce for complete solution information. >>

(* Out[181]= {{v -> ((-b - k^(1 - n)/(1 - n)) (-1 + n))^(1/(1 - n))}} *)


Instead of Simplify one might use PowerExpand with appropriate assumption.

Solve[
PowerExpand[((v k)^-n (k v^n - v k^n))/(n - 1) == b,
Assumptions -> k > 0], v]

During evaluation of In[182]:= Solve::ifun: Inverse functions are being used by Solve, so some solutions may not be found; use Reduce for complete solution information. >>

(* Out[182]= {{v -> ((-b - k^(1 - n)/(1 - n)) (-1 + n))^(1/(1 - n))}} *)
`