padding with zero in Table

Question

I am creating a grid as

 Print["no of grid points, lattice length, dz " , {max = 10, L = 10.,dz=L/max}]
grid = Table[-L/2 + (n - 1) dz, {n, 1, max}]
grid2 = Table[-L/2 + (n - 1) dz, {n, 1, max, 2}]

The output is During evaluation of

  no of grid points, co-ordinate lattice length, dz {10,10.,1.}

    {-5., -4., -3., -2., -1., 0., 1., 2., 3., 4.}

   {-5., -3., -1., 1., 3.}

I want to pad zeros in the grid2 on the places where I have not shown element. Means I need

 {-5., 0., -3., 0., -1., 0., 1., 0., 3., 0.}

How can I do that?

Also what if I want to pad two or more zeroes as

 {-5., 0., 0., -2., 0, 0., 1., 0., 0., 4.}

Answer 1

max = 10; L = 10.; dz = 1;

grid2 = Riffle[Table[-L/2 + (n - 1) dz, {n, 1, max, 2}], ConstantArray[0., max/2]] 
(* or  Riffle[Table[-L/2 + (n - 1) dz, {n, 1, max, 2}], 0., {2, -1, 2}] *)
(* {-5., 0., -3., 0., -1., 0., 1., 0., 3., 0.} *)

or

grid2b =Join @@ Table[{-L/2 + (n - 1) dz, 0.}, {n, 1, max, 2}]
(* {-5., 0., -3., 0., -1., 0., 1., 0., 3., 0.} *)

or

grid2c = Join @@ Thread[{Table[-L/2 + (n - 1) dz, {n, 1, max, 2}], 0.}]
(* {-5., 0., -3., 0., -1., 0., 1., 0., 3., 0.} *)

Update:

f0 = Module[{ca = ConstantArray[0., Length@#], 
     indices = Range[1, max, #2 + 1]}, ca[[indices]] = #[[indices]]; ca] &;

grid = Table[-L/2 + (n - 1) dz, {n, 1, max}];
f0[grid, 1]
(*  {-5., 0., -3., 0., -1., 0., 1., 0., 3., 0.} *)

f0[grid, 2]
(* {-5., 0., 0., -2., 0., 0., 1., 0., 0., 4.}  *)

Additional alternatives:

Using ReplacePart:

f1 = ReplacePart[#, Except[Alternatives @@ Range[1, max, #2 + 1]] -> 0.] &;

grid = Table[-L/2 + (n - 1) dz, {n, 1, max}];
f1[grid, 1]
(* {-5.,0.,-3.,0.,-1.,0.,1.,0.,3.,0.} *)
f1[grid, 2]
(* {-5.,0.,0.,-2.,0.,0.,1.,0.,0.,4.} *)

Using MapAt:

f2 = MapAt[0. &, #, {{Complement[Range[max], Range[1, max, #2 + 1]]}}] &;

grid = Table[-L/2 + (n - 1) dz, {n, 1, max}];
f2[grid, 1]
(* {-5.,0.,-3.,0.,-1.,0.,1.,0.,3.,0.} *)
f2[grid, 2]
(* {-5.,0.,0.,-2.,0.,0.,1.,0.,0.,4.} *)

Answer 2

Here is a very simple solution to "pad" your grid :

If :

grid={-5., -4., -3., -2., -1., 0., 1., 2., 3., 4.}

then you can just multiply it this way :

grid*{1, 0, 1, 0, 1, 0, 1, 0, 1, 0}
(*{-5., 0., -3., 0., -1., 0., 1., 0., 3., 0.}*)

or

grid*{1, 0, 0, 1, 0, 0, 1, 0, 0, 1}
(*{-5., 0., 0., -2., 0., 0., 1., 0., 0., 4.} *)

To generate automatically the mask list {1,0,..}, you can use this function :

periodicMask[int_Integer, maxpoints_] := Table[Floor[Mod[i - 2, int]/(int - 1)], {i, maxpoints}]

For example :

periodicMask[3, max]
(*{1, 0, 0, 1, 0, 0, 1, 0, 0, 1}*)

then

grid*periodicMask[3, max]
(*{-5., 0., 0., -2., 0., 0., 1., 0., 0., 4.}*)