5
$\begingroup$
f = PlaneCurveData["Superformula", "PolarEquation"][2, 2, 24, 6, 6, 1, 1][t];

PolarPlot[
 {1.1, 2.0, f},
 {t, 0.0, 2.0 Pi},
 ImageSize -> 600,
 PolarAxes -> True,
 PolarGridLines -> {Automatic, None},
 PolarTicks -> {"Degrees", {
    {1.1, Framed[Style[1.1, 12, Bold], Background -> White]},
    {2.0, Framed[Style[2.0, 12, Bold], Background -> White]}}},
 ColorFunction -> Function[{x, y, t, r}, ColorData["DarkRainbow"][r]],
 PlotStyle -> Thickness[0.005]]

enter image description here

I have two questions:

(a) I find it aesthetically displeasing that the "outer degree circle" is so far away from the actual plot,

(b) How can I omit half of the PolarGridLines if I only wanted to plot the maxima, i.e. 0, 330, 300 etc. ?

$\endgroup$
  • 3
    $\begingroup$ You can use: PolarGridLines -> {Range[0, 330 \[Degree], 30 \[Degree]], None}, PolarAxesOrigin -> {0, 2.} $\endgroup$ – Kuba Nov 3 '14 at 22:11
  • 1
    $\begingroup$ And this kind of works for the ticks: PolarTicks->{{\[Pi],180 \[Degree],{pl,0}},{\[Pi]/2,90 \[Degree],{pl,0}},{2 \[Pi]," 0\[Degree]",{pl,0}},{(3 \[Pi])/2,270 \[Degree],{pl,0}},{{1.1,Framed[Style[1.1,12,Bold],Background->White]},{2.,Framed[Style[2.,12,Bold],Background->White]}}} $\endgroup$ – Rolf Mertig Nov 3 '14 at 22:20
7
$\begingroup$

@Kuba, @Rolf Mertig-s comments are summarized by this.

f = PlaneCurveData["Superformula", "PolarEquation"][2, 2, 24, 6, 6, 1,1][t];
PolarPlot[{1.1, 2.0, f}, {t, 0.0, 2.0 Pi},
 PolarTicks -> {Table[{i, 180° i/ π}, {i, 0, 11 π/6, π/6}], 
    {{1.1, 
    Framed[Style[1.1, 12, Bold], Background -> White]}, {2., 
    Framed[Style[2., 12, Bold], Background -> White]}}}, 
    ImageSize -> 600, PolarAxes -> True, 
    ColorFunction -> Function[{x, y, t, r}, ColorData["DarkRainbow"][r]],
    PlotStyle -> Thickness[0.005], 
    PolarGridLines -> {Range[0, 330°, 30°], None}, 
    PolarAxesOrigin -> {0, 2.}
]

enter image description here

$\endgroup$
  • $\begingroup$ Thank you so much, you answered both questions. I have added the output :) $\endgroup$ – eldo Nov 3 '14 at 22:50

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service, privacy policy and cookie policy

Not the answer you're looking for? Browse other questions tagged or ask your own question.