Solution for equation system with piece-wise defined functions

Question

As I could swear this worked just yesterday, I am probably just doing something stupid here and I am sorry to bother you :)

I am trying to find the point where a curve crosses a line. In this case, the curve is a box, but it should work for other things, too, so I need to find the problem here, not better ways for a solution for boxes.

boxCurve[boundaries_List] := Module[{b = boundaries, bH, bW, cf},
  bH = b[[2, 2]] - b[[2, 1]];
  bW = b[[1, 2]] - b[[1, 1]];
  cf = 2 bH + 2 bW;
  Function[t, Piecewise[{
     {{b[[1, 1]] + cf t, b[[2, 1]]}, 0 <= cf t < bW},
     {{b[[1, 2]], b[[2, 1]] + (cf t - bW)}, bW <= cf t < bW + bH},
     {{b[[1, 2]] - (cf t - bW - bH), b[[2, 2]]}, 
      bW + bH <= cf t < 2 bW + bH},
     {{b[[1, 1]], b[[2, 2]] - (cf t - 2 bW - bH)}, 
      2 bW + bH <= cf t < 2 bW + 2 bH}
     }, {b[[1, 1]], b[[2, 1]] + bH/4}]]
  ]

The box does work ParametricPlot[boxCurve[{{-1, 1}, {-1, 1}}][s], {s, 0, 1}] But, when I am trying to calculate the crossing point

Solve[boxCurve[{{-1, 1}, {-1, 1}}][s] == {-1, 1} + {1, -1} t, {s, t}]
Solve[boxCurve[{{-1, 1}, {-1, 1}}][s] == {-0.9, 1} + {1, -1} t, {s, t}]
Solve[boxCurve[{{-1, 1}, {-1, 1}}][s] == {0, 0} + {1, 0} t, {s, t}]

I get no result, although two of the base points of the lines are already on the box. This is true for both NSolve and Solve.

As said I could swear that something like this worked yesterday, because I got conditional expressions depending on s, when I only solved for t.

Answer 1

For a function defined using Piecewise you could try something like this

SetAttributes[solve, HoldAll];

solve[(bc : boxCurve[a_][s_]) == b_, c__] := Solve[
  Or @@ Append[(#1 == b && #2) & @@@ bc[[1]],
    bc[[2]] == b && Not[Or @@ bc[[1, All, 2]]]], c]

solve[boxCurve[{{-1, 1}, {-1, 1}}][s] == {t, t/2}, {s, t}]    

(* {{t -> ConditionalExpression[-1, s >= 1 || s < 0]}, 
    {s -> 7/16, t -> 1}, {s -> 15/16, t -> -1}} *)

Edit

I've wrapped the whole thing in a function to make it more manageable. The default value works as well. This actually already worked in the previous version, but I've added the conditions for which the default value should be taken to the equations used in Solve.

Answer 2

My friend Sam noticed that if you split it up into two functions it works:

Second = Part[#, 2] &;
boxCurve1[boundaries_List] := 
     Module[{b = boundaries, bH, bW, cf}, bH = b[[2, 2]] - b[[2, 1]];
      bW = b[[1, 2]] - b[[1, 1]];
      cf = 2 bH + 2 bW;
      Function[t, Piecewise[{{First@{b[[1, 1]] + cf t, b[[2, 1]]}, 
          0 <= cf t < bW}, {First@{b[[1, 2]], b[[2, 1]] + (cf t - bW)}, 
          bW <= cf t < 
           bW + bH}, {First@{b[[1, 2]] - (cf t - bW - bH), b[[2, 2]]}, 
          bW + bH <= cf t < 
           2 bW + bH}, {First@{b[[1, 1]], b[[2, 2]] - (cf t - 2 bW - bH)},
           2 bW + bH <= cf t < 2 bW + 2 bH}}, 
        First @ {b[[1, 1]], b[[2, 1]]}]]];

boxCurve2[boundaries_List] := 
     Module[{b = boundaries, bH, bW, cf}, bH = b[[2, 2]] - b[[2, 1]];
      bW = b[[1, 2]] - b[[1, 1]];
      cf = 2 bH + 2 bW;
      Function[t, Piecewise[{{Second@{b[[1, 1]] + cf t, b[[2, 1]]}, 
          0 <= cf t < bW}, {Second@{b[[1, 2]], b[[2, 1]] + (cf t - bW)}, 
          bW <= cf t < bW + bH}, 
          {Second@{b[[1, 2]] - (cf t - bW - bH), b[[2, 2]]}, 
          bW + bH <= cf t < 2 bW + bH}, {Second@{b[[1, 1]], 
            b[[2, 2]] - (cf t - 2 bW - bH)}, 
          2 bW + bH <= cf t < 2 bW + 2 bH}}, 
        Second@{b[[1, 1]], b[[2, 1]]}]]];

Solve[boxCurve1[{{-1, 1}, {-1, 1}}][s] == t && 
      boxCurve2[{{-1, 1}, {-1, 1}}][s] == t - 1/2, {s, t}]
boxCurve[{{-1, 1}, {-1, 1}}][1/16]
boxCurve[{{-1, 1}, {-1, 1}}][7/16]
(* 
    {{s -> 1/16, t -> -(1/2)}, {s -> 7/16, t -> 1}}
    {-(1/2), -1}
    {1, 1/2}
*)

Answer 3

I got an answer from Wolfram Premier support. Their final solution boiled down to basically what Heike wrote. However, they provided an explanation that explains Mike's remark (and renders it really close to the solution) and also helped me to develop a Solution that suits me better (I'm not saying that it is generally better. I'll give the bounty to whoever has the most votes on Thursday).

The reason for the problem is that Solve (and Reduce) use Thread internally. If fun1 is not a list, but e.g. a Piecewise defined function, that fun1 == {t-1,t+2} is evaluated to fun1 == t-1 && fun1 == t+2

Knowing this, it is clear that Mike's example works, as it does not contain lists anymore.

My final solution now is to use

Solve[Evaluate[
  Simplify[
     boxCurve[{{-1, 1}, {-1, 1}}][s].{1, 0}] == {t/2, t}.{1, 0} &&
   Simplify[boxCurve[{{-1, 1}, {-1, 1}}][s].{0, 1}] == {t/2, t}.{0, 1}
  ], {s, t}]

as this still perfectly works for normal, non-Piecewise function.