I have $${\frac{(6 k+1)^{k}}{(2 k+5)^{k}}}*(z-2 i)^k$$ and I need to find it's limit for $k$ approaching infinity.

Limit[((6*k+1)/(2*k+5))^k*(z-2*I)^k, k -> ∞,
  Assumptions -> {Element[z, Complexes], -∞ < z < ∞}]

It is returned unevaluated. But it is interesting to note here, for all values of z ∈ {(3+4*I), (3-4*I), (-3-4*I), (-4*I), (4*I), (4), (-4)} it returns ComplexInfinity.

Can someone give a strong reason why it is preferable to return it unevaluated rather than using such heuristics?

If k -> 0 then limit is 1.


1 Answer 1


First we can see that ${\frac{(6k+1)^{k}}{(2k+5)^{k}}}$ behaves asymptotically as $3^k$, while $(z-2i)^k$ is divergent if $\|z-2i\|>1 $, however when $\|z-2i\|<1 $ it is convergent. For $\|z-2i\|=1$ this criterion is not conclusive. On the other hand we can carefully extend this argument to the full sequence, so we need only $\|z-2i\| < \frac{1}{3} $ to ensure that the sequence is convergent, and in fact Mathematica can tackle with an approprate assumption:

Limit[ ((6k + 1)/(2k + 5))^k (z - 2I)^k, k -> Infinity, 
        Assumptions -> 3 Abs[-2 I + z] < 1]

However putting Assumptions -> Abs[-2 I + z] >= 1/3 Mathematica returns ComplexInfinity which is only generically true i.e. there are exceptional arguments satisfying Abs[-2 I + z] == 1/3 where the sequence converges. So in general assumming Abs[-2 I + z] == 1/3 the limit is left unevaluated. This issue is acceptable however as mentioned before here the limit can be convergent only conditionally.

E.g. let's assume z == 2 I + 1/3, no we can find the symbolic limit:

Limit[ ((6 k + 1)/(2 k + 5))^k (z - 2 I)^k, k -> Infinity, 
       Assumptions -> z == 2 I + 1/3]

For other arguments satisfying Abs[-2 I + z] == 1/3 e.g. find five of them:

FindInstance[ Abs[-2 I + z] == 1/3, z, 5]
{{z -> 149/752 + (I (4512 - Sqrt[365695]))/2256}, 
 {z -> 47 - 2/141 I (-141 + 5 Sqrt[22])}, 
 {z -> -(55/752) + (4512 + Sqrt[538279]))/2256}, 
 {z -> 1/47 + 2/141 I (141 + 5 Sqrt[22])}, {z -> 1/3 + 2 I}}

the sequence is not convergent however the limit is resticted to appropriate geometric subset of the complex plane:

Limit[ ((6 k + 1)/(2 k + 5))^k (z - 2 I)^k, k -> Infinity, 
       Assumptions -> z == 149/752 + (I (4512 - Sqrt[365695]))/2256]
E^(-(7/3) + 2 I Interval[{0, Pi}])    

With Mathematica we can also verify convergence of the adequate series, this provides the condition for convergence:

SumConvergence[((6k + 1)/(2k + 5))^k (z - 2I)^k, k]
3 Abs[-2 I + z] < 1

Mathematica correctly returned ComplexInfinity for provided values of z since they did not satisfied the appropiate condition:

Abs[{3 + 4I, 3 - 4I, -3 - 4I, -4I, 4I, 4, -4}]
{5, 5, 5, 4, 4, 4, 4}

Concluding we can say that Mathematica still requires a quantum of mathematical knowledge and I think it is quite fine. I'm quite convinced that the perspective that in the distant future mathematics will be only the field of computer activity is an unrealizable dream (and it seems some kind of S.Wolfram's publicity). See Computational Knowledge and the Future of Pure Mathematics. Nevertheless we can still expect quite reasonably that Mathematica will be able to do much more in mathematics.

  • $\begingroup$ Answers to this question are slightly related: Convergence and value of a complex power series. $\endgroup$
    – Artes
    Oct 29, 2014 at 9:38
  • $\begingroup$ your argument suits well, thanks for sharing this observation. Mathematica could have some function like LimitConvergence. S.Wolfram's conversation on axioms in Mathematica have been realized to some extent by AXIOM cas already by having different domains and with their own rules.Axioms seems famous only among pure mathematicians but its complicated to learn hence not as popular as Mathematica.I hope they get better at solving larger class of problems. $\endgroup$ Oct 29, 2014 at 11:05

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service and acknowledge you have read our privacy policy.

Not the answer you're looking for? Browse other questions tagged or ask your own question.