Add reference letters to multipanel figures

Question

I want to create a multipanel figure like that

and so I would like to add a letter "A", "B", etc to each of the panel I've created. I usually first create each panel with the letter and then assemble them, rather than assemble them and add the letters then:

• For 2D panels, I am able to do so with the Epilog command:

  Epilog -> Style[Text["B", {1.1, 2.3}], 28, Bold]

but the letter is always on the panel, I can't place it on the left of the panel as is the case on the example above

• For 3D panels, I am unable at all to use the Epilog command, so I'm looking for a good alternative

I generally use a combination of Column and Row functions to create my multipanel figure then, I find it easier to put the panels exactly where I want to, rather than using Grid or GraphicsGrid.

What solution would you use to add the reference letters to the multipanel figure?

Answer 1

You can also use Panel and its second and third arguments to place the labels:

 Panel[Plot3D[Sin[x + y^2], {x, -3, 3}, {y, -2, 2}, ImageSize -> 200], 
       Style["A", Bold, 14], {{Left, Top}}]

Or, without the frame, (* thanks: @Karsten7. *)

Panel[Plot3D[Sin[x + y^2], {x, -3, 3}, {y, -2, 2}, ImageSize -> 200],
 Style["A", Bold, 14], {{Left, Top}}, Appearance -> "Frameless"]

Examples:

charts = {Plot3D[Sin[x + y^2], {x, -3, 3}, {y, -2, 2}, ImageSize -> 200], 
          BarChart[{{1, 2, 3}, {1, 3, 2}}], 
          Histogram[RandomVariate[WeibullDistribution[2, 1], 1000], Automatic, "Probability"], 
   ContourPlot3D[x^4 + y^4 + z^4 - (x^2 + y^2 + z^2)^2 + 3 (x^2 + y^2 + z^2) == 3, 
    {x, -2, 2}, {y, -2, 2}, {z, -2, 2}, Mesh -> None, 
    ContourStyle -> Directive[Orange, Opacity[0.8], Specularity[White, 30]], 
    ImageSize -> 300]};

labels = CharacterRange["A", "Z"][[;; 4]];
panels = Partition[Panel[#, Style[#2, Bold, 14], {{Left, Top}}] & @@@ 
            Transpose[{charts, labels}], 2];

Grid[panels, Alignment -> {Left, Top}]

Answer 2

You can use Labeled to add letters outside the margins of your figures.
E.g.:

plot = Labeled[Framed@Plot[Sin[x], {x, 0, 5}], "A", {{Left, Top}}]

histo = Labeled[Histogram[RandomVariate[NormalDistribution[], 100]], "B", {{Left, Top}}]

sphere = Labeled[Graphics3D[{Sphere[]}], Style["C", 28, Bold], {{Left, Top}}]

Regarding the arrangement, you can start with GraphicsGrid and then rearrange the figures by hand. This needs some clicking around, though.

GraphicsGrid[{{plot, histo}, {sphere}}]