3
$\begingroup$

I have a following expression $$ f=\Pi_{i=1}^n \left[ 1 + \frac{1}{t} +\frac{ (m+i)}{t^2} +\frac{ (m+i)^2}{t^3} + \cdots \right] $$ here $m,n,t$ are positive integers.

I want to obtain a series expansion for $f$ as $1/t,1/t^2,1/t^3,\cdots$ up to maybe $1/t^6$. A general expression for any order is not needed.

I used

f = \!\(
\*UnderoverscriptBox[\(\[Product]\), \(i = 1\), \(n\)]\((1 + 
\*FractionBox[\(1\), \(t\)] + 
\*FractionBox[\((m + i)\), \(t^2\)] + 
\*FractionBox[\(\((m + i)\)^2\), \(t^3\)])\)\)

Series[f, {t, Infinity, 3}, Assumptions -> Element[m, Integers]]

Mathematica 7.0 gives me a complicated expression including Arg, Floor, Csc, etc.

Is there any way to obtain simple expression? I can do low order by hand, but for high order, it is increasingly complicated..

$\endgroup$
  • $\begingroup$ Welcome to Mathematica.SE! Could you please add the actual code you evaluated before the Series function? % just refers to the prior evaluation, and we don't know exactly what you've done. $\endgroup$ – Verbeia Oct 16 '14 at 4:11
  • $\begingroup$ Thanks. It is just the expression for f. f = \!( *UnderoverscriptBox[([Product]), (i = 1), (n)]((1 + *FractionBox[(1), (t)] + *FractionBox[((m + i)), (t^2)] + *FractionBox[(((m + i))^2), (t^3)]))) $\endgroup$ – user26143 Oct 16 '14 at 4:12
  • $\begingroup$ I have replaced % as f. In the input, only the expression up to $t^{-3}$ inside multiplication was used. $\endgroup$ – user26143 Oct 16 '14 at 4:14
  • $\begingroup$ I have added f, copied from mathematica. I do not know what is the best way to present it on stackexchange though... $\endgroup$ – user26143 Oct 16 '14 at 4:18
5
$\begingroup$

EDIT: Added verification of Product

f can be expressed in closed form:

f[m_, n_, t_] = Product[1 +
   Sum[(m + i)^k/t^(k + 1), {k, 0, Infinity}],
  {i, 1, n}]

(m - t)/(m + n - t)

Verifying the Product (proof by induction)

s[i_] = 1 + Sum[(m + i)^k/t^(k + 1), {k, 0, Infinity}]

1 - 1/(i + m - t)

f[m, 1, t] == s[1] &&
  f[m, n + 1, t] == f[m, n, t]*s[n + 1] //
 Simplify

True

Your desired expansion is

Series[f[m, n, t], {t, Infinity, 4}] // Simplify

enter image description here

The coefficients are

SeriesCoefficient[f[m, n, t], {t, Infinity, k}]

enter image description here

Verifying the expansion

f[m, n, t] == 1 + Sum[n (m + n)^(k - 1)/t^k, {k, 1, Infinity}] // Simplify

True

| improve this answer | |
$\endgroup$
  • $\begingroup$ Thanks for your answer. Excuse me, I do not know how the closed form expression was derived. When I sum the infinity series, I got $$1 + \frac{1}{t-m-i}$$. How to show $$\Pi_{i=1}^n 1 + \frac{1}{t-m-i} = \frac{ m-t}{m+n-t} $$? $\endgroup$ – user26143 Oct 16 '14 at 5:30
  • $\begingroup$ Evaluating Product[1 + 1/(t - m - i), {i, 1, n}] in Mma gives (m-t)/(m+n-t) $\endgroup$ – Bob Hanlon Oct 16 '14 at 5:41
  • $\begingroup$ I mean the details of derivation, not how mathematica gives the answer... $\endgroup$ – user26143 Oct 16 '14 at 5:50
  • $\begingroup$ Got it, just write the formula explicitly, $\Pi_{i=1}^n 1 + \frac{1}{t-m-i} = \frac{ t-m}{t-m-1} \frac{t-m-1}{t-m-2} \frac{t-m-2}{t-m-3} \cdots \frac{t-m-(n-1)}{t-m-n}$ and cancel the same terms on denominator and numeriator $\endgroup$ – user26143 Oct 16 '14 at 6:34
0
$\begingroup$

Assuming your product is one that Mathematica doesn't know the closed form for, you could use my answer from Infinite product with O[x] here:

Unprotect[Series];

Series[Product[a_, b_], pt_] := Exp[MapAt[Sum[#, b]&, Series[Log[a], pt], 3]]
Series[Inactive[Product][a_, b_], pt_] := Series[Unevaluated[Product[a, b]], pt]

Protect[Series];

Then:

f = Inactive[Product][1 + 1/t + (m + i)/t^2 + (m + i)^2/t^3, {i, 1, n}];

Simplify @ Series[f, {t, Infinity, 3}] //TeXForm

$1+\frac{n}{t}+\frac{n (m+n)}{t^2}+\frac{n (m+n)^2}{t^3}+O\left(\left(\frac{1}{t}\right)^4\right)$

| improve this answer | |
$\endgroup$

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service, privacy policy and cookie policy

Not the answer you're looking for? Browse other questions tagged or ask your own question.