Dataset seems unable to handle ListDensityPlot and ListContourPlot

Question

If I create a Dataset:

dataSet = Dataset[
  AssociationThread[{"a", "b", "c", "d", "e"} -> #] & /@ RandomReal[{-1, 1}, {1000, 5}]
];

It should be easy to use a plotting function on it

dataSet[ListContourPlot, {"a", "e", "c"}]

but all I get is the list of associations back.

Why does Dataset not plot my data query?

I don't understand why this happens, since if I replace ListContourPlot with, say ListPointPlot3D (these functions work on lists of triplets), it works fine. ListDensityPlot has the same problem. This doesn't seem to have anything to do with extreme ranges in my dataset, and I can't see anything wrong with the dataset itself; i.e., the following works fine:

With[{
  t = {
    Normal @ dataSet[All, "a"],
    Normal @ dataSet[All, "e"],
    Normal @ dataSet[All, "c"]
    }
  },
  ListContourPlot[Transpose[t]]]

Answer 1

I think what you want is the following:

dataSet[ListContourPlot, {#a, #e, #c} &]

dataSet[ListDensityPlot, {#a, #e, #c} &]

If you still want to use the Keys directly then you'll have to force ListContourPlot and ListDensityPlot to extract only the Values as follows:

dataSet[ListContourPlot[Values@#] &, {"a", "e", "c"}]

Answer 2

The problem does not lie with Dataset, but rather with ListContourPlot:

$data =
  { <|"a"->0.846,"e"->0.770,"c"->0.682|>
  , <|"a"->0.211,"e"->-0.434,"c"->0.944|>
  , <|"a"->0.716,"e"->0.171,"c"->0.529|>
  };

ListContourPlot @ $data

(* ListContourPlot[{ <|a->0.846,e->0.77,c->0.682|>,
     <|a->0.211,e->-0.434,c->0.944|>,<|a->0.716,e->0.171,c->0.529|>}] *)

The result is inert, showing that ListContourPlot does not operate upon associations. It is necessary to explicitly extract the values:

ListContourPlot @ Values @ $data

ListPointPlot3D, by contrast, does operate upon associations:

ListPointPlot3D @ $data

The documentation for ListPointPlot3D makes no mention of this capability.

The documentation for Association says...

Typical list operations (such as Map, Select, and Sort) apply to the values in an association, leaving the keys unchanged.

... and ...

Keys are "transparent" for many operations

... but it remains silent on the identity of those "many operations" beyond a few examples. Apparently ListPointPlot3D is one of those operations, but ListContourPlot is not. Perhaps it is rather that the internal implementation of ListPointPlot3D uses one of those "many operations", but the implementation of ListContourPlot does not.

So, for the moment at least, we must learn the set of "many operations" by experimentation.

Edit

Note that Dataset already has up-value wrapper definitions for many operators, including ListContourPlot. WRI certainly has the option of adjusting the wrapper definition of Dataset instead of making ListContourPlot handle associations, although the latter would seem to have more general applicability.

Answer 3

I can't quite wrap my head around what a Dataset is, and why it does work with ListPointPlot3D. But as a workaround you can just use

dataSet[ListDensityPlot[{"a","e","c"}/.#]&,{"a","e","c"}]

and

dataSet[ListContourPlot[{"a","e","c"}/.#]&,{"a","e","c"}]