# NIntegrate Error

I am trying to solve this expression with the function NIntegrate:

    NIntegrate[(2Subscript[b, 2])/(0.72*2\[Pi]^2*8.85418782*10^-12*3^2) (NIntegrate[( [Delta]*
(3.482+\[Delta])EllipticE[-((4*0.1516*Subscript[b, 2])/((3.482+\[Delta])^2+
(0.1516-Subscript[b, 2])^2))])/(((3.482+\[Delta])^2+(0.1516+Subscript[b, 2])^2)*
Sqrt[(3.482+\[Delta])^2+(0.1516-Subscript[b, 2])^2]),{\[Delta],-0.36,0.36}]),{Subscript[b, 2],0,3}]


However, when I try to solve it gives me 3 of this error:

    NIntegrate::inumr: "The integrand (\[Delta]\(3.482 +\[Delta])\EllipticE[-((0.6064
Subscript[b, 2])/((3.482 +\[Delta])^2+(<<1>>)^2))])/(Sqrt[(3.482 +\[Delta])^2+
(0.1516 -Subscript[b, 2])^2]\((3.482 +\[Delta])^2+(0.1516 +Subscript[b, 2])^2)) " has
evaluated to non-numerical values for all sampling points in the
region with boundaries {{-0.36,0.}}


By the way it gives the approximate value of my input but I wonder why it gives me these errors. Is it affecting the output? Thnaks.

• You should comment on the answers you receive. If they are right, you should upvote/accept. If they are wrong you should explain why – Dr. belisarius Oct 26 '14 at 18:21

Your inner NIntegrate[] argument is of course non numeric because it depends on the outer NIntegrate[] variables. So,

f[d_, b_] := ((3.482 + d)^2 + (0.1516 - b)^2);
NIntegrate[2 b ((d*(3.482 + d) EllipticE[-((4 0.1516 b)/f[d, b])])/(f[d, b] Sqrt[f[d, b]])),
{d, -0.36, 0.36}, {b, 0, 3}]

(* -0.0103908 *)


You can use Quiet to silence the error warnings

NIntegrate[
2 b2/(0.72*2 \[Pi]^2*8.85418782*10^-12*3^2) (NIntegrate[(d*(3.482 +
d) EllipticE[-(4*0.1516*
b2/((3.482 + d)^2 + (0.1516 - b2)^2))])/(((3.482 +
d)^2 + (0.1516 + b2)^2)*
Sqrt[(3.482 + d)^2 + (0.1516 - b2)^2]), {d, -0.36, 0.36}]), {b2, 0,
3}] // Quiet


-8.01331*10^6

or separate out the inner NIntegrate and define it for only numeric arguments

f[x_?NumericQ] :=
NIntegrate[(d*(3.482 +
d) EllipticE[-(4*0.1516*
x/((3.482 + d)^2 + (0.1516 - x)^2))])/(((3.482 + d)^2 + (0.1516 +
x)^2)*Sqrt[(3.482 + d)^2 + (0.1516 - x)^2]), {d, -0.36, 0.36}];

NIntegrate[2 b2/(0.72*2 \[Pi]^2*8.85418782*10^-12*3^2) f[b2], {b2, 0, 3}]


-8.01331*10^6