21
$\begingroup$

MapThread works fine and dandy with rectangular list structures:

MapThread[f, {{{a, b}, {c, d}}, {{1, 2}, {3, 4}}}, 2]

{{f[a, 1], f[b, 2]}, {f[c, 3], f[d, 4]}}

But with a ragged structure, it starts complaining:

MapThread[f, {{{a, b}, {c, d, e}}, {{1, 2}, {3, 4, 5}}}, 2]

MapThread::mptd: "Object {{a,b},{c,d,e}} at position {2, 1} in MapThread[f,{{{a,b},{c,d,e}},{{1,2},{3,4,5}}},2] has only 1 of required 2 dimensions."

whereas I'd like:

{{f[a, 1], f[b, 2]}, {f[c, 3], f[d, 4], f[e, 5]}}

I can't see any obvious way to achieve a pairing of the corresponding elements, but maybe you can?

Improve this question
$\endgroup$

9 Answers 9

Reset to default
16
$\begingroup$

Perhaps something like this, as a more general alternative? However, without tweaking it forget about level specification

Function[Null, f[##], Listable] @@ A
Improve this answer
$\endgroup$
3
  • $\begingroup$ The magic of Listable! I knew there must have been some nice way to do it. $\endgroup$
    – wxffles
    May 28, 2012 at 4:27
  • $\begingroup$ @wxffles I like it. If you actually want to give the arguments as separate lists like in your solution, you don't even need the Apply $\endgroup$
    – Rojo
    May 28, 2012 at 4:37
  • $\begingroup$ This is crazy amazing! MMA is effin' nuts in its state space a.e.! $\endgroup$
    – Gravifer
    Nov 1, 2022 at 14:09
13
$\begingroup$

Here's a way to do it by mapping MapThread:

MapThread[f, #] & /@ Transpose[{{{a, b}, {c, d, e}}, {{1, 2}, {3, 4, 5}}}]
(* {{f[a, 1], f[b, 2]}, {f[c, 3], f[d, 4], f[e, 5]}} *)
Improve this answer
$\endgroup$
2
  • 1
    $\begingroup$ This works great if you are working at level 2. I was hoping for something more general. Next time I'll try asking! $\endgroup$
    – wxffles
    May 28, 2012 at 3:42
  • 4
    $\begingroup$ @wxffles please provide more examples if you want a more general solution. $\endgroup$
    – Mr.Wizard
    May 28, 2012 at 3:47
12
$\begingroup$

It's probably bad form to answer your own question, but I did manage to get something to work while I was waiting:

myMapThread[f_, list1_, list2_, level_] := 
  Module[{s}, Function[s, 
     Reap[MapIndexed[Sow[f[#1, s[[Sequence @@ #2]]]] &, list1, {level}]][[1]]]
     [list2]];

Usage:

myMapThread[f, {{a, b}, {c, d, e}}, {{1, 2}, {3, 4, 5}}, 2]

{{f[a, 1], f[b, 2]}, {f[c, 3], f[d, 4], f[e, 5]}}

It's quite ugly though.

Improve this answer
$\endgroup$
1
7
$\begingroup$ 
ClearAll[raggedThread]
raggedThread = Inner[Thread @* #, ##2, List] &;

Example:

raggedThread[f, {{a, b}, {c, d, e}}, {{1, 2}, {3, 4, 5}}]

{{f[a, 1], f[b, 2]}, {f[c, 3], f[d, 4], f[e, 5]}}
Improve this answer
$\endgroup$
2
  • $\begingroup$ Necromancer badge :-) $\endgroup$
    – Mr.Wizard
    Jun 13, 2020 at 13:38
  • $\begingroup$ Thank you @Mr.Wizard. $\endgroup$
    – kglr
    Jun 13, 2020 at 16:03
6
$\begingroup$ 
MapThread[f, lst[[1 ;; 2, #]]] & /@ {1, 2}

gives

(*{{f[a, 1], f[b, 2]}, {f[c, 3], f[d, 4], f[e, 5]}}*)

If

lst2 = {{{a, b}, {c, d, e}}, {{1, 2}, {3, 4, 5}}, {{aa, bb}, {cc, dd, ee}}};
MapThread[f, lst2[[1 ;; 3, #]]] & /@ {1, 2}

gives

(*{{f[a, 1, aa], f[b, 2, bb]}, {f[c, 3, cc], f[d, 4, dd], f[e, 5, ee]}}*)
Improve this answer
$\endgroup$
2
$\begingroup$ 
x = {{a, b}, {c, d, e}};
y = {{1, 2}, {3, 4, 5}};

MapApply[f] /@ Transpose /@ Transpose[{x, y}]

{{f[a, 1], f[b, 2]}, {f[c, 3], f[d, 4], f[e, 5]}}

Improve this answer
$\endgroup$
0
$\begingroup$ 
threadRagged = Apply[#, Flatten[{##2}, {{2}, {3}}], {2}] &;

Examples:

{x, y} = {{{a, b}, {c, d, e}}, y = {{1, 2}, {3, 4, 5}}};

threadRagged[f, x, y]

{{f[a, 1], f[b, 2]},   
 {f[c, 3], f[d, 4], f[e, 5]}}

lst2 = {{{a, b}, {c, d, e}}, {{1, 2}, {3, 4, 5}}, {{aa, bb}, {cc, dd, ee}}};

threadRagged[F, ## & @@ lst2]

 {{F[a, 1, aa], F[b, 2, bb]},   
  {F[c, 3, cc], F[d, 4, dd], F[e, 5, ee]}}
Improve this answer
$\endgroup$
0
$\begingroup$ 
threadTwice = Map[Thread]@Thread[#@##2, List, Length @ {##2}] &;

Examples:

{x, y} = {{{a, b}, {c, d, e}}, y = {{1, 2}, {3, 4, 5}}};

threadTwice[f, x, y]

 {{f[a, 1], f[b, 2]},   
  {f[c, 3], f[d, 4], f[e, 5]}}

lst2 = {{{a, b}, {c, d, e}}, {{1, 2}, {3, 4, 5}}, {{aa, bb}, {cc, dd, ee}}};

threadTwice[f, ## & @@ lst2]

{{f[a, 1, aa], f[b, 2, bb]},   
 {f[c, 3, cc], f[d, 4, dd], f[e, 5, ee]}}
Improve this answer
$\endgroup$
0
$\begingroup$

Using the third argument of GroupBy to cover the ragged array case:

myMapThread[f_, list_] := 
If[TensorQ[list], f @@@ # &@*Thread /@ Transpose@list, 
Values[GroupBy[Catenate[list], Length, f @@@ # &@*Thread]]]

Testing myMapThread:

list1 = {{{a, b}, {c, d}}, {{1, 2}, {3, 4}}};
list2 = {{{a, b}, {c, d, e}}, {{1, 2}, {3, 4, 5}}};

myMapThread[f, list1]

(*{{f[a, 1], f[b, 2]}, {f[c, 3], f[d, 4]}}*)

myMapThread[f, list2]

(*{{f[a, 1], f[b, 2]}, {f[c, 3], f[d, 4], f[e, 5]}}*)
Improve this answer
$\endgroup$

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service and acknowledge that you have read and understand our privacy policy and code of conduct.

Not the answer you're looking for? Browse other questions tagged or ask your own question.