2
$\begingroup$

I'd like to look at some group transformation of curves in the plane. As a start, I'd like to try to do use the rotation group. Here's the code I tried to rotate a parabola so that I can watch the rotation:

x1[t_] := t*Cos[c] - t^2*Sin[c];
u1[t_] := t*Sin[c] + t^2*Cos[c];
Manipulate[
 ParametricPlot[{x1[t], u1[t]}, {t, -3, 3}, 
  PlotRange -> {{-9, 9}, {-9, 9}}], {c, 0, 2}]

If I fix a value for c, and remove the manipulate command, this works fine:

x1[t_] := t*Cos[c] - t^2*Sin[c];
u1[t_] := t*Sin[c] + t^2*Cos[c];
c=2;
 ParametricPlot[{x1[t], u1[t]}, {t, -3, 3}, 
  PlotRange -> {{-9, 9}, {-9, 9}}]

Are there any suggestions out there, or reasons why the above doesn't work? I'd like to manipulate the group parameter to watch the resulting transformations of the curve.

$\endgroup$
2
$\begingroup$

you can try also this:

x1[t_] := t*Cos[c] - t^2*Sin[c]; 
u1[t_] := t*Sin[c] + t^2*Cos[c]; 
Manipulate[
  ParametricPlot[{x1[t], u1[t]} /. c -> d, {t, -3, 3}, 
  PlotRange -> {{-9, 9}, {-9, 9}}], {d, 0, 2}]
$\endgroup$
2
$\begingroup$
Manipulate[ ParametricPlot[RotationMatrix[c].{t, t^2}, {t, -2, 2}, 
            PlotRange -> {{-5, 5}, {-5, 5}}], {c, 0, 2 Pi}]

Mathematica graphics

Other transformations can be handled the same way. For example for SL2(R)

Manipulate[ ParametricPlot[LinearFractionalTransform[{{{a, b}, {c, (1 + b c)/a}}}][{t,t^2}], 
                          {t, -5, 5}, PlotRange -> 9{{-1, 1}, {-1, 1}}], 
           {a, .1, 5}, {b, 0, 5}, {c, 0, 5}]

Mathematica graphics

$\endgroup$
1
$\begingroup$

Okay, if I let x1 and u1 be functions of c also, this seems to work:

x1[t_, c_] := t*Cos[c] - t^2*Sin[c];
u1[t_, c_] := t*Sin[c] + t^2*Cos[c];
Manipulate[
 ParametricPlot[{x1[t, c], u1[t, c]}, {t, -3, 3}, 
  PlotRange -> {{-9, 9}, {-9, 9}}], {c, 0, 2}]
$\endgroup$
  • 1
    $\begingroup$ You should correct your question itself. If you think there is no more issue and you found your own mistake, then you can delete the question. $\endgroup$ – Nasser Sep 28 '14 at 1:35
  • $\begingroup$ @Nasser Why should he delete it? Perhaps somebody comes up with a better solution! $\endgroup$ – Dr. belisarius Sep 28 '14 at 1:38
  • 1
    $\begingroup$ @Nasser Perhaps the question is interesting to others. I don't see a compelling reason to delete it. $\endgroup$ – mathgeek420 Sep 28 '14 at 1:40

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service, privacy policy and cookie policy

Not the answer you're looking for? Browse other questions tagged or ask your own question.