Consider this sequence of commands:

foo10 = RandomReal[{0, 1}, {5000, 10}];
Export["D:\\Dropper\\Dropbox\\footest.csv", foo10] // AbsoluteTiming
{0.898086, "D:\\Dropper\\Dropbox\\footest.csv"}

foo100 = RandomReal[{0, 1}, {5000, 100}];
Export["D:\\Dropper\\Dropbox\\footest.csv", foo100] // AbsoluteTiming
{7.428425, "D:\\Dropper\\Dropbox\\footest.csv"}

foo1000 = RandomReal[{0, 1}, {5000, 1000}];
Export["D:\\Dropper\\Dropbox\\footest.csv", foo1000] // AbsoluteTiming
{65.063763, "D:\\Dropper\\Dropbox\\footest.csv"}

Two (at least) things leap to mind:

The first is that the performance is truly atrocious (this is on a very fast machine, on a local file system.

The second is that the times grow sublinearly in the size of the input, which indicates a whole'nother kind of weirdness.

Does anyone understand what is going on, and if there is a reasonable workaround?

EDIT Following up on @belisarius' suggestion, here are the Timing[] results for the three commands:

0.671875 4.65250 47.968750

From which we see that both the OS interaction and the internal computation are ridiculously slow. But it gets worse. In the middle of doing this experiment, when I was running the commands exactly as above with AbsoluteTiming[] replaced by Timing[], between the first and the second command Mathematica informed me that it could not do the Export[] because the "footest.csv" file was already open (which means that it did not do the necessary fclose(), or whatever Windows calls it, of course changing the file name fixed it.

For posterity, this is Mathematica 10.0.1 on Windows 8.1

ANOTHER EDIT Just for completeness: I tried the same experiment with ".dat" instead of ".csv", and the results were essentially identical (including the fclose() bug). Which makes it surprising (though gratifying) that there is an actual format that works quickly, as pointed out by @Jens.

  • $\begingroup$ Can you count the I/O operations performed? $\endgroup$ Commented Sep 18, 2014 at 23:36
  • $\begingroup$ @belisarius I would love to hear a suggestion about how to count them... $\endgroup$
    – Igor Rivin
    Commented Sep 18, 2014 at 23:38
  • 1
    $\begingroup$ Well, you nailed it. Somebody should get fired from a well known company :) $\endgroup$ Commented Sep 19, 2014 at 1:40
  • 2
    $\begingroup$ @belisarius Unfortunately, there is evidence that at least the performance problem (don't know about the fclose()) has been around for years. Since csv is a somewhat popular format for numerical data, I am at a loss as to why this is not a priority for the well-known company in question. $\endgroup$
    – Igor Rivin
    Commented Sep 19, 2014 at 1:46
  • 3
    $\begingroup$ These are the kind of issues that always prevent me for suggesting Mma as an enterprise production environment. Probably there is a solution using some mixed-language environment, but you never know where the devil's tail can flog you again. It's a very nice prototyping and R&D platform, though. $\endgroup$ Commented Sep 19, 2014 at 2:08

2 Answers 2


The speed issue is similar on Mac OS X. I can only speculate what's going on, so I better not even start.

But let me suggest a work-around. Since CSV is not in any way optimized for exporting numerical data, I would instead suggest to use a different format that has similar flexibility but is particularly designed for numerical data.

Of course, this is a workaround only if your intention is to save numerical data for later use by an application that's also able to read the alternate format. Here is what I tried, and it's very fast by comparison:

foo1000 = RandomReal[{0, 1}, {5000, 1000}];

Export["footest.h5", foo1000] // AbsoluteTiming

(* ==> {0.521861, "footest.h5"} *)

foo = Import["footest.h5", "Data"]; // AbsoluteTiming

(* ==> {0.145216, Null} *)

foo[[1]] == foo1000

(* ==> True *)

The format I used is HDF5.

If you're able to work with packed arrays, then things get even faster:

foo1000 = 
  Developer`ToPackedArray@RandomReal[{0, 1}, {5000, 1000}];

Export["footest.h5", foo1000] // AbsoluteTiming

(* ==> {0.358825, "footest.h5"} *)

foo = Import["footest.h5", "Data"]; // AbsoluteTiming

(* ==> {0.084686, Null} *)

foo[[1]] == foo1000

(* ==> True *)
  • $\begingroup$ This is very helpful (and certainly is the kind of workaround I was looking for)! $\endgroup$
    – Igor Rivin
    Commented Sep 19, 2014 at 11:26

This may be a bit of a digression, but a raw binary write is faster still than 'hd5': ( On Windows w/ v.9.01 )

 x = RandomReal[{-1, 1}, {2560, 2560}];
 ByteCount[x]/1024^2 // N                  (* 50.0001 *)
 Export["test.csv", x] // AbsoluteTiming  (*  120.05  *)
 Export["test.h5", x] // AbsoluteTiming   (*  1.965550  *)
 (f = OpenWrite["test.dat", BinaryFormat -> True];
      BinaryWrite[f, Flatten@x, "Real64"];
      Close[f];) // AbsoluteTiming        (*  0.452388 *)

Obviously issues with other application reading the file may dwarf the timing difference. (I use the raw BinaryWrite to exchange data with C++ all the time )

hmm.. you can write a csv like this is near 10x faster than Export

 (f = OpenWrite["test2.csv", BinaryFormat -> True];
    StringJoin[Riffle[StringJoin[Riffle[#, ","]] & /@ 
             Map[ToString[#, CForm] &, x, {2}], "\r\n"]]];  (*note windows line end
                                                             used here*)
   Close[f]) // AbsoluteTiming   (* 23.337002 *)

makes you wonder what Export is doing...

 Import["test.csv"] == Import["test2.csv"]


  • $\begingroup$ On my Mac, with Mathematica version 8, the h5 export is still faster than the BinaryWrite: the result were: {0.575183,test.h5}, and {0.588023,Null} respectively. $\endgroup$
    – Jens
    Commented Sep 19, 2014 at 18:54
  • $\begingroup$ Could be a windows issue then. $\endgroup$
    – george2079
    Commented Sep 19, 2014 at 19:19
  • $\begingroup$ Actually, it's not a Windows issue. On my Windows 8.1 machine the timings are : {0.275268, test.h5} vs {0.344335, Null}. v10.0.1 $\endgroup$
    – RunnyKine
    Commented Sep 19, 2014 at 19:24
  • $\begingroup$ On my Vista 32bit, with v9.0.1, the timings are: {2.566000, "test.h5"} vs {3.374000, Null} $\endgroup$
    – xzczd
    Commented Sep 20, 2014 at 4:11

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service and acknowledge you have read our privacy policy.

Not the answer you're looking for? Browse other questions tagged or ask your own question.