1
$\begingroup$

, Referring to yesterday's "Switching parameter lines on/off in a 3D parametric plot" (Switching parameter lines on/off in a 3D parametric plot)

From reply by Bob Hanlon for example, can we pick up some option combinations resulting in two separate 3D plots out of the above full Manipulate set, approximately indicated as :

GrU= {uMesh True,uMesh=18, v Mesh False,Surface, Boxed -> False} and

GrV= {vMesh True, vMesh=10,u Mesh False,WireFrame, Boxed-> True}

and then combine them into a single plot by:

Show[GrU,GrV] 

How may it be done?

The motivation for this query is qualitatively the following.

If one cannot make a parametrization fully with 2 parameters u,v on a known surface which is undergoing a new parametric definition, sometimes one can start with a single parameter u on the surface while remaining on the surface and design/choose other new parameter v definition. The surface on which v is targeted, or going to be placed, can be a priori visualized while developing v.

For example the sphere can be parametrized either by a set of geodesics and parallel lines (latitudes,longitudes)or by two sets of great circle geodesics.

The above arose in finding a proper parametrization for Helmet Net. In the image there are Shown 2 sets of parallel circles, x-y, y-x are same but distance along arc of neighbor differential arcs is not same. It is not a single parametrization. Distances are more at 45 degree location. Attempt is to make all distances between nodes same in parametrization.It should be sure if all points in either set coincide.

HelmetNet

$\endgroup$
  • $\begingroup$ Wouldn't the single plot combination of those two be equivalent to just (uMesh=True, uMesh=18, vMesh=True, vMesh=10, Surface, Boxed=True)? $\endgroup$ – Bob Hanlon Sep 11 '14 at 11:56
  • $\begingroup$ @BobHanlon I am trying to find out for Helmet Net example. If parametrization is available, it is ok as you suggested. In the image I attached, there is no developed parametrization known to me. $\endgroup$ – Narasimham Sep 11 '14 at 20:52
  • $\begingroup$ Somewhat related: Change all Options of Plot Dynamically $\endgroup$ – Michael E2 Sep 11 '14 at 23:31
2
$\begingroup$

Additional controls added to facilitate exploration:

Manipulate[
 ParametricPlot3D[
  {Cos[u], Sin[u] + Cos[v], Sin[v]},
  {u, uMin, uMax},
  {v, vMin, vMax},
  Mesh -> {
    If[uMeshOn, uMesh, 0],
    If[vMeshOn, vMesh, 0]},
  Boxed -> boxed,
  Axes -> boxed,
  PlotStyle -> pltStyle,
  PlotRange ->
   {{-1.1, 1.1}, {-2.1, 2.1}, {-1.1, 1.1}}],
 Row[{
   Control[{{uMin, 0, "u Min"},
     0, uMax - uDelta, uDelta,
     Appearance -> "Labeled", ImageSize -> Small}],
   Spacer[5],
   Control[{{vMin, -Pi, "v Min"},
     -Pi, vMax - vDelta, vDelta,
     Appearance -> "Labeled", ImageSize -> Small}]}],
 Row[{
   Control[{{uMax, 2 Pi, "u Max"},
     uMin + uDelta, 2 Pi, uDelta,
     Appearance -> "Labeled", ImageSize -> Small}],
   Spacer[5],
   Control[{{vMax, Pi, "v Max"},
     vMin + vDelta, Pi, vDelta,
     Appearance -> "Labeled", ImageSize -> Small}]}],
 Row[{
   Control[{{uMesh, 15, "u Mesh"}, 0, 36, 1,
     Appearance -> "Labeled", ImageSize -> Small}],
   Spacer[5],
   Control[{{vMesh, 15, "v Mesh"}, 0, 36, 1,
     Appearance -> "Labeled", ImageSize -> Small}]}],
 Row[{
   Control[
    {{uMeshOn, True, "u Mesh"}, {True, False}}],
   Spacer[5],
   Control[
    {{vMeshOn, True, "v Mesh"}, {True, False}}],
   Spacer[5],
   Control[
    {{pltStyle, Automatic, "Plot Style"}, {Automatic -> "Surface", 
      FaceForm[] -> "Wire Frame"}}],
   Spacer[5],
   Control[{{boxed, True, "Boxed"}, {True, False}}],
   Spacer[5],
   Button[Style["Reset", Red, Bold],
    {uMin = 0, vMin = -Pi, uMax = 2 Pi, vMax = Pi,
     uMesh = 15, vMesh = 15, boxed = True,
     uMeshOn = True, vMeshOn = True,
     pltStyle = Automatic}]}],
 Initialization :> (uDelta = vDelta = Pi/12)]

enter image description here

$\endgroup$

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service, privacy policy and cookie policy

Not the answer you're looking for? Browse other questions tagged or ask your own question.