# Switching parameter lines on/off in a 3D parametric plot

In a classroom demonstration for

ParametricPlot3D [{f[u, v], g[u, v], h[u, v]}, {u, ... }, {v, ... }]


I want to show

• u lines only without v,

• v lines only without u,

• no lines, only surface,

• no surface, only u, v lines.

How can it be done?

• Sep 10, 2014 at 17:10
• Let us say we pick up options for two separate images out of the full Manipulate set: GrU= {uMesh True,uMesh=18, v Mesh False,Surface, Boxed -> False} and GrV= {vMesh True, vMesh=10,u Mesh False,WireFrame, Boxed-> True} and combine them in: Show[GrU,GrV]. How it be done? *) Sep 11, 2014 at 9:26

Manipulate[
ParametricPlot3D[
{Cos[u], Sin[u] + Cos[v], Sin[v]},
{u, 0, 2 \[Pi]},
{v, -\[Pi], \[Pi]},
Mesh -> {If[uMeshOn, uMesh, 0],
If[vMeshOn, vMesh, 0]},
Boxed -> boxed,
Axes -> boxed,
PlotStyle -> pltStyle],
Row[{
Control[
{{uMesh, 15, "u Mesh"}, 0, 36, 1,
Appearance -> "Labeled",
ImageSize -> Small}],
Spacer[5],
Control[
{{vMesh, 15, "v Mesh"}, 0, 36, 1,
Appearance -> "Labeled",
ImageSize -> Small}]}],
Row[{Control[
{{uMeshOn, True, "u Mesh"},
{True, False}}],
Spacer[20],
Control[
{{vMeshOn, True, "v Mesh"},
{True, False}}],
Spacer[20],
Control[
{{pltStyle, Automatic, "Plot Style"},
{Automatic -> "Surface",
FaceForm[] -> "Wire Frame"}}],
Spacer[20],
Control[
{{boxed, True, "Boxed"},
{True, False}}]}]]


• A particularly appropriate choice of surface, too! +1
– user484
Sep 10, 2014 at 18:54
• Wondrously beautiful this Bob,can ask for nothing more! Sep 10, 2014 at 19:46