5
$\begingroup$

In a classroom demonstration for

ParametricPlot3D [{f[u, v], g[u, v], h[u, v]}, {u, ... }, {v, ... }]

I want to show

  • u lines only without v,

  • v lines only without u,

  • no lines, only surface,

  • no surface, only u, v lines.

How can it be done?

$\endgroup$
2
7
$\begingroup$
Manipulate[
 ParametricPlot3D[
  {Cos[u], Sin[u] + Cos[v], Sin[v]},
  {u, 0, 2 \[Pi]},
  {v, -\[Pi], \[Pi]},
  Mesh -> {If[uMeshOn, uMesh, 0],
    If[vMeshOn, vMesh, 0]},
  Boxed -> boxed,
  Axes -> boxed,
  PlotStyle -> pltStyle],
 Row[{
   Control[
    {{uMesh, 15, "u Mesh"}, 0, 36, 1,
     Appearance -> "Labeled",
     ImageSize -> Small}],
   Spacer[5],
   Control[
    {{vMesh, 15, "v Mesh"}, 0, 36, 1,
     Appearance -> "Labeled",
     ImageSize -> Small}]}],
 Row[{Control[
    {{uMeshOn, True, "u Mesh"},
     {True, False}}],
   Spacer[20],
   Control[
    {{vMeshOn, True, "v Mesh"},
     {True, False}}],
   Spacer[20],
   Control[
    {{pltStyle, Automatic, "Plot Style"},
     {Automatic -> "Surface",
      FaceForm[] -> "Wire Frame"}}],
   Spacer[20],
   Control[
    {{boxed, True, "Boxed"},
     {True, False}}]}]]

enter image description here

$\endgroup$
2
  • $\begingroup$ A particularly appropriate choice of surface, too! +1 $\endgroup$
    – user484
    Sep 10 '14 at 18:54
  • $\begingroup$ Wondrously beautiful this Bob,can ask for nothing more! $\endgroup$
    – Narasimham
    Sep 10 '14 at 19:46

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service, privacy policy and cookie policy

Not the answer you're looking for? Browse other questions tagged or ask your own question.