I want to export a figure from Mathematica in PDF format. Moreover, I want to fill Author and Title fields of the PDF. For example, to fill Author field, I use the following code:
pp = Plot[{x^2}, {x, -1, 1}]
Export["plot-example.pdf", pp, "Author" -> "Dmitry"]
However, when I open generated PDF file in a PDF viewer, the "Author" field is not filled.
How should I specify Export call to include Author and Title fields in the generated PDF file?
The package and all code of this answer can be found on my GitHub account.
A solution that takes only small amount of time is to follow this route:
JLink` directly to access the PDF library. This is often harder to read IMO and I would recommend this only in rare casesThe structure of the finished package layout can be as easy as this
PDFMetaData
├── Java
│ └── PDFMetaData.jar
└── PDFMetaData.m
In this simple case PDFMetaData.m contains a function like this
SetPDFMetaData[file_String][meta : {(_String -> _String)..}] := JavaBlock[
InstallJava[];
LoadJavaClass["de.halirutan.pdfmetadata.PDFMetaDataSetter",
StaticsVisible -> True];
PDFMetaDataSetter`setMetaData[file, Flatten[List @@@ meta]]
];
The static Java function that is called at the end, is rather simple too. I should note, that I have compiled my source and packed the created class file together with the PDF library itself into PDFMetaData.jar. This jar is now selfcontained.
The package needs to be put into a place where Mathematica can find it, like
FileNameJoin[{$UserBaseDirectory, "Applications"}]
This is especially important, because then, the Java folder is automatically added to the java CLASSPATH.
Well, that's basically it. Go and use it
<< PDFMetaData`
SetPDFMetaData[
Export["tmp/meta.pdf", "Hello"]][{"Author" -> "Xavier Breath",
"Title" -> "Stop Arguing!", "Creator" -> "Funny Inc.",
"Producer" -> "Nick R. Elastic",
"Keywords" -> "Mathematica PDF"}]
Final note, please just change the call pattern of SetPDFMetaData[file][metalist] to SetPDFMetaData[file, metalist] if you feel more comfortable with it. I had no specific reason to use SubValues.
1234 in the linked example. I already added this to the package, but as I said, for me it doesn't work. If you want I can still push it so you can testIt
$\endgroup$
– halirutan♦
Sep 23 '15 at 5:51
From the PDF file definitions (7.5.4 - 7.5.6) you don't need to modify the inner structure of a PDF file to make changes, its enough to append the new definitions of the components (New or old) and suitable cross-reference section with pointers to the shift positions of some relevant components for random access.
Here I attempt some code to do all the work in Mathematica. It still needs some polishing, probably with some help I could write a reasonable package.
fn = "test.PDF";
Export[fn, α];
pdfWriteInfo[fn, {
"Title" -> "Alpha"
, "Producer" -> "Mod by RH"
, "Author" -> $UserName
, "Subject" -> "mathematica.stackexchange.com/questions/59270"
, "Keywords" -> "PDF,Mathematica"
}]
we are dealing whith this portion of plaintext at the end of the PDF
Open the file to read the last 30 bytes, finds the "startxref" and reads the shift position of "xref". Checks that the files ends in "%%EOF".
We need this to avoid a long search in a potentially huge file.
pdfReadStartXref::notPDF = "`1` does not comply with the PDF format";
pdfReadStartXref[file_String] := If[
FileExistsQ[file],
Block[{fs, sxref} (* File Stream ; Start of Cross refference*),
fs = OpenRead[file, BinaryFormat -> True];
SetStreamPosition[fs, -30];
If[Find[fs, "startxref"] === EndOfFile, Close[fs];
Message[pdfReadStartXref::notPDF, file]; Return[Null]];
sxref = Read[fs, Number];
If[Find[fs, "%%EOF"] === EndOfFile, Close[fs];
Message[pdfReadStartXref::notPDF, file]; Return[Null]];
Close[fs];
sxref
]]
test
pdfReadStartXref[fn]
4041
That number we use to SetStreamPosition next to the xref and trailer section.
pdfReadTrailer[file_String, esxref_: 0] := If[
FileExistsQ[file],
Block[{filestream, startxref, trailer, starttrailer} (*
File Stream *),
filestream = OpenRead[file, BinaryFormat -> True];
startxref = If[
esxref === 0,
SetStreamPosition[filestream, -30];
Read[
StringToStream[
Read[filestream, Record,
RecordSeparators -> {{"startxref"}, {"%%EOF"}}]], Number],
esxref
];
SetStreamPosition[filestream, startxref];
Find[filestream, "trailer"];
starttrailer = StreamPosition[filestream];
trailer = Association@Flatten@StringSplit[
ReadList[
StringToStream[
Read[filestream, Record, RecordSeparators -> {{"<<"}, {">>"}}]
], Record],
Shortest[___ ~~ "/" ~~ key__ ~~ Whitespace] ~~
Longest[value___ ~~ EndOfString] :> key -> value];
Close[filestream];
{
starttrailer,
Map[If[StringMatchQ[#, NumberString],
Interpreter["Number"][#], #] &, Map[StringSplit, trailer], {2}]
}
]
]
test
pdfReadTrailer[fn]
{4358, <|"Size" -> {15}, "Root" -> {14, 0, "R"}, "Info" -> {13, 0, "R"}|>}
Now we know that the Info section is labeled "13 0".
pdfReadXRef[file_String, esxref_: 0] := If[
FileExistsQ[file],
Block[{filestream, startxref, xref} (* File Stream *),
startxref = If[esxref === 0, pdfReadStartXref[file], esxref];
filestream = OpenRead[file, BinaryFormat -> True];
SetStreamPosition[filestream, startxref];
Find[filestream, "xref"];
xref = Association@Table[
{i -> Read[filestream, {Number, Number, String}]}
, {i, #1, #1 + #2 - 1}] & @@ Read[filestream, {Number, Number}];
Close[filestream];
{startxref, xref}
]
]
test
pdfReadXRef[fn]
{4041, <|0 -> {0, 65535, " f "}, 1 -> {3721, 0, " n "}, 2 -> {182, 0, " n "}, 3 -> {15, 0, " n "}, 4 -> {161, 0, " n "}, 5 -> {3557, 0, " n "}, 6 -> {291, 0, " n "}, 7 -> {502, 0, " n "}, 8 -> {2690, 0, " n "}, 9 -> {2713, 0, " n "}, 10 -> {3015, 0, " n "}, 11 -> {3038, 0, " n "}, 12 -> {3317, 0, " n "}, 13 -> {3786, 0, " n "}, 14 -> {3988, 0, " n "}|>}
Now we know where in the file is defined each section. We care only for "13 0". The number we were looking for was "3786".
Now we can SetStreamPosition to "3786" where Info is defined and read its contents.
pdfReadInfo::xref = "Failed parsing xref in file `1` .";
pdfReadInfo[file_String] := If[
FileExistsQ[file],
Block[{startxref, xref, trailer, trailerinfo, startInfo, filestream,
info, infohead, inforef} ,
{startxref, xref} = pdfReadXRef[file];
trailer = Last@pdfReadTrailer[file, startxref];
trailerinfo = trailer["Info"];
inforef = xref[First[trailerinfo]];
If[Head[inforef] === Missing, Message[pdfReadInfo::xref, file];,
startInfo = First[inforef];
infohead = Flatten[{Most@trailerinfo, " obj"}];
filestream = OpenRead[file, BinaryFormat -> True];
SetStreamPosition[filestream, startInfo];
If[Read[filestream, {Number, Number, String}] =!= infohead,
Abort[]];
info = Association@Flatten@StringSplit[
ReadList[
StringToStream[
Read[filestream, Record,
RecordSeparators -> {{"<<"}, {">>"}}]], Record],
Shortest[___ ~~ "/" ~~ key__ ~~ Whitespace] ~~
Longest["(" ~~ value___ ~~ ")"] :> key -> value];
Close[filestream];
{infohead, info}
]
]
]
test
pdfReadInfo[fn]
{{13, 0, " obj"}, <|"Creator" -> "Wolfram Mathematica 10.2.0.0 for Microsoft Windows (64-bit) (July 7, 2015)", "Producer" -> "", "CreationDate" -> "20150918133940+01'00", "ModDate" -> "20150918133940+01'00"|>}
That's the old Info we will keep that as long as the user doesn't define the same key.
pdfWriteInfo::nowrite = " `1` file its not writable.";
pdfWriteInfo[file_String, options_: {"Producer" -> "Code by RH"}] :=
If[
FileExistsQ[file],
Block[{rinfo, infohead, info, newinfo, filestream, newstartxref,
oldstartxref, startinfo, trailer, moddatestr} ,
startinfo = FileByteCount[file];
If[startinfo > 100,
oldstartxref = pdfReadStartXref[file];
rinfo = pdfReadInfo[file];
If[rinfo =!= Null,
{infohead, info} = rinfo;
moddatestr =
"D:" <> StringReplace[
DateString[{"Year", "Month", "Day", "Hour", "Minute",
"Second", "ISOTimeZone"}], ":" -> "'"] <> "'";
newinfo =
Join[info, Association@options, <|"ModDate" -> moddatestr |>];
trailer = Last@pdfReadTrailer[file];
filestream = Check[OpenAppend[file, BinaryFormat -> True], Null];
If[filestream =!= Null,
WriteString[filestream, infohead[[1]], " ", infohead[[2]],
" obj\r\n<<\r\n"];
Table[
WriteString[filestream, " /", First[item], " (", Last[item],
")\r\n"]
, {item, Normal[newinfo]}
];
WriteString[filestream, ">>\r\n", "endobj", "\r\n"];
newstartxref = StreamPosition[filestream];
WriteString[filestream, "xref\r\n", "0 1\r\n",
"0000000000 65535 f\r\n", infohead[[1]], " ", infohead[[2]],
"\r\n",
IntegerString[startinfo, 10, 10], " ",
IntegerString[infohead[[2]], 10, 5], " n\r\n",
"trailer\r\n<<"];
Table[
WriteString[filestream, " /", First[item2], " ",
Sequence @@ Riffle[Last[item2], " "], "\r\n"]
, {item2, Normal[trailer]}];
WriteString[filestream, " /Prev ", oldstartxref, "\r\n",
">>\r\n", "startxref\r\n", newstartxref, "\r\n", "%%EOF"];
]
Close[filestream];
, Message[pdfWriteInfo::nowrite, file]
]]]]
test
pdfWriteInfo[fn, {
"Title" -> "Alpha"
, "Producer" -> "Mod by RH"
, "Author" -> $UserName}
]
Voila.
