Plotting a region with polar axes

Question

I'd want to plot the region of points which satisfy the following equation:

2 < r <= 5 && 3/4 π < θ <= 5/4 π

I have been able to plot the region in Cartesian coordinates:

h[r_, θ_] := 2 < r <= 5 && 3/4 π < θ < 5/4 π
RegionPlot[h[Sqrt[x^2 + y^2], ArcTan[x, y]], {x, -6, 6}, {y, -6, 6}, PlotPoints -> 100]

I would like to plot the region with polar axes, but I don't think I can make PolarPlot plot a region probably.

Answer 1

Update

Compare two pictures. First is able to make mistake like you made the code.

You need to do like this code using Mod[ArcTan[x, y], 2π].

h[r_,θ_] := 2 < r <= 5 && 3/4 π < θ < 3/2 π
RegionPlot[
 h[Sqrt[x^2 + y^2], Mod[ArcTan[x, y], 2π]], {x, -6, 6}, {y, -6, 6}]

So I suggest to use ParametricPlot like this.

rg = 6; mg = 3;

ParametricPlot[{r Cos[θ], r Sin[θ]}, {r, 2, 5}, {θ, 3/4 π, 5/4 π},
 Frame -> False, Axes -> False,
 PlotRange -> {-rg - mg, rg + mg},
 Epilog -> PolarPlot[rg, {θ, 0, $MachineEpsilon}, 
    PolarAxes -> True,
    PolarGridLines -> {Automatic, Range[rg]},
    PolarTicks -> {Drop[Table[i, {i, 0, 2 Pi, Pi/8}], -1], 
      Automatic}][[1]]
 ]

---

Origin

This is my trick. I used option Epilog.

RegionPlot[
 h[Sqrt[x^2 + y^2], ArcTan[x, y]], {x, -6, 6}, {y, -6, 6}, 
 Frame -> False, PlotPoints -> 30,
 Epilog -> PolarPlot[5, {\[Theta], 0, $MachineEpsilon},
    PolarAxes -> True, 
    PolarGridLines -> Automatic,
    PolarTicks -> {"Degrees", Automatic}][[1]]
 ]

And I tried also PolarTicks like this.

PolarTicks -> {Drop[Table[i, {i, 0, 2 Pi, Pi/4}], -1], Automatic}

PolarGridLines Usage

RegionPlot[
 h[Sqrt[x^2 + y^2], ArcTan[x, y]], {x, -6, 6}, {y, -6, 6}, 
 Frame -> False, PlotPoints -> 30,
 Epilog -> PolarPlot[6, {\[Theta], 0, $MachineEpsilon},
    PolarAxes -> True, 
    PolarGridLines -> {Automatic, Range[6]},
    PolarTicks -> {Drop[Table[i, {i, 0, 2 Pi, Pi/4}], -1], 
      Automatic}][[1]]
 ]