Split matrix by all-zero columns

Question

Below is my input:

mat = {{0, 0, 0, 0, 0, 1}, {1, 0, 0, 1, 0, 1}, {0, 1, 0, 0, 0, 0}, {0,
     0, 0, 0, 0, 1}, {1, 1, 0, 1, 0, 0}, {0, 0, 0, 1, 0, 1}};

$\quad\quad\left( \begin{array}{cccccc} 0 & 0 & 0 & 0 & 0 & 1 \\ 1 & 0 & 0 & 1 & 0 & 1 \\ 0 & 1 & 0 & 0 & 0 & 0 \\ 0 & 0 & 0 & 0 & 0 & 1 \\ 1 & 1 & 0 & 1 & 0 & 0 \\ 0 & 0 & 0 & 1 & 0 & 1 \\ \end{array} \right) $

I would like to split this matrix by the columns with all-zeros, and in the process remove those columns from the matrix. Expected output below:

Answer 1

I'm surprised MMA doesn't have something like StringSplit for list, but maybe I haven't looked hard enough. I added the .. to delete multiple all-zero columns after seeing @Kuba's comment. Please upvote his comment instead of my answer since his was the more succinct.

mat = {{0, 0, 0, 0, 0, 1}, {1, 0, 0, 1, 0, 1}, {0, 1, 0, 0, 0, 0}, {0,
     0, 0, 0, 0, 1}, {1, 1, 0, 1, 0, 0}, {0, 0, 0, 1, 0, 1}};

MatrixForm@Transpose@# & /@ 
 DeleteCases[SplitBy[Transpose@mat, # != {0, 0, 0, 0, 0, 0} &], {{0, 0, 0, 0, 0, 0}..}]

Answer 2

Basically, the same idea as seismatica's answer, but with different details.

m =
  {{0, 0, 0, 0, 0, 1},
   {1, 0, 0, 1, 0, 1},
   {0, 1, 0, 0, 0, 0},
   {0, 0, 0, 0, 0, 1},
   {1, 1, 0, 1, 0, 0},
   {0, 0, 0, 1, 0, 1}};

split =
  Transpose /@
    DeleteCases[
      SplitBy[If[Plus @@ # > 0, #] & /@ Transpose[m], # === Null &], 
      {Null}];

A different approach using Reap and Sow.

split = 
  Module[{tag = 1}, 
    Transpose /@ Last @ Reap[If[Plus @@ # > 0, Sow[#, tag], tag++] & /@ Transpose[m]]]

Both of the above produce

MatrixForm /@ split

Answer 3

In the spirit of Mathematica 10 I would have written it like this:

Composition[
  DeleteCases[{{0} ..}],
  Map[Transpose],
  SplitBy[#, Unitize@*Total] &,
  Transpose
  ]@mat

{{{0, 0}, {1, 0}, {0, 1}, {0, 0}, {1, 1}, {0, 0}}, {{0}, {1}, {0}, {0}, {1}, {1}}, {{1}, {1}, {0}, {1}, {0}, {1}}}

With rules I would write:

Transpose /@ {Transpose[mat] //. {el__, {0 ..}, rest___} :> Sequence[{el}, {rest}]}

{{{0, 0}, {1, 0}, {0, 1}, {0, 0}, {1, 1}, {0, 0}}, {{0}, {1}, {0}, {0}, {1}, {1}}, {{1}, {1}, {0}, {1}, {0}, {1}}}

The first method assumes numeric matrix elements but the second doesn't.

Answer 4

mat =
  {{0, 0, 0, 0, 0, 1},
   {1, 0, 0, 1, 0, 1},
   {0, 1, 0, 0, 0, 0},
   {0, 0, 0, 0, 0, 1},
   {1, 1, 0, 1, 0, 0},
   {0, 0, 0, 1, 0, 1}};

Using SequenceSplit (new in 11.3)

MatrixForm @* Transpose /@ SequenceSplit[Transpose @ mat, {{0 ..}}]

Answer 5

Here is a function hopefully with some amount of reusability:

splitColsByMask[base_, mask_, key_: 1] := 
  base[[All, #]] & /@ Split[Pick[Range@Length@mask, mask, key], #2 - 1 == # &]

A "mask" for your input:

v = Unitize @ Total @ Unitize @ mat

{1, 1, 0, 1, 0, 1}

Applied:

MatrixForm /@ splitColsByMask[mat, v]

The third parameter "key" defaults to 1; it is the "take" pattern for Part.

Answer 6

mat = {{0, 0, 0, 0, 0, 1}, {1, 0, 0, 1, 0, 1}, {0, 1, 0, 0, 0, 0}, {0,
     0, 0, 0, 0, 1}, {1, 1, 0, 1, 0, 0}, {0, 0, 0, 1, 0, 1}};

SplitBy[Transpose@mat, AllTrue[# == 0 &]] /. {{0 ..}} :> Nothing // 
  Map[Transpose] // Map[MatrixForm]

or

SplitBy[Transpose@mat, Apply[DiscreteDelta]] /. {{0 ..}} :> Nothing //
   Map[Transpose] // Map[MatrixForm]

---