2
$\begingroup$

How I can obtain the $n^{th}$ approximation of the following Operator form integral equation? $F(t)=A(t)+\int_0^tds B(s)F(s)$, where

$A(t)=\bigg{(}\begin{matrix}t&0\\Cos(t)&1 \end{matrix}\bigg{)}$,

$B(s)=\bigg{(}\begin{matrix}e^s&0\\0&e^{-s} \end{matrix}\bigg{)}$

Improve this question
$\endgroup$
  • $\begingroup$ Can you provide Mathematica code? :) $\endgroup$ – Öskå Jul 24 '14 at 11:51
  • $\begingroup$ Since you haven't demostrated at least a bit of Mathematica code you shouldn't expect any answers to your question. Answers to your first posts have been exceptions to this general rule of mathematica.stackexchange.com. Don't expect you'll be treated in an exeptional way anymore. $\endgroup$ – Artes Jul 24 '14 at 11:53
  • $\begingroup$ Together with the code I suggest that you explain, why do you solve the integral equation instead of the differential, especially accounting for the simplicity of the latter. $\endgroup$ – Alexei Boulbitch Jul 24 '14 at 12:24
  • 1
    $\begingroup$ Artes is correct that it's nice to see code in the question. Not only does it show some effort on the part of the OP, but it also lends context to the question letting the person answering the question know the appropriate level to write their own code. As I did encourage Javad to ask a follow up to this question, I'll provide an answer soon. $\endgroup$ – Mark McClure Jul 24 '14 at 14:12
2
$\begingroup$

The iteration can be performed as follows:

A[t_] = {{t, 0}, {Cos[t], 1}};
B[t_] = {{Exp[t], 0}, {0, Exp[-t]}};
T[F_] := Expand[A[t] + Integrate[B[s].F /. t -> s, {s, 0, t}]];
iteration = NestList[T, {{t, 0}, {0, t}}, 7];
Column[Framed /@ MatrixForm /@ iteration[[1 ;; 3]]]

enter image description here

Well, it's not immediately clear what the limits are, as it was over in this answer, but we can examine the plots to see if we appear to have convergence.

funcs[i_, j_] := Table[iteration[[k, i, j]], {k, 1, Length[iteration]}];
joined = {{funcs[1, 1], funcs[1, 2]}, {funcs[2, 1], funcs[2, 2]}};
GraphicsGrid[Map[Plot[#, {t, -1, 1}] &, joined, {2}]]

enter image description here

As Alexei suggests, it's easy enough to solve the corresponding set of differential equations and compare the results. The solutions are not elementary, however, and involve integrals of special functions.

Improve this answer
$\endgroup$
  • $\begingroup$ Thanks a lot @Mark McClure. your answers are very helpful for me. $\endgroup$ – Javad Kazemi Jul 24 '14 at 19:11

Not the answer you're looking for? Browse other questions tagged or ask your own question.