Map 2 list to a function

Question

Im playing around with CountryData and I want to pass it 2 lists as argument, listCountries = {...} and data = {"GDP","ExternalDebt"}

If I do CountryData[#, "GDP"]& /@ listCountries it works well, but I want something like

CountryData[#1, #2]& /@ {listCountries,data}

I read something about MapThread but can make it.

Answer 1

Consider these two lists:

listCountries = {
   "Bangladesh",
   "India",
   "Monaco"
   };
data = {
   "GDP",
   "Population",
   "Area"
   };

There are two cases: you want the GDP, population and area of each country in the first list. The most elegant solution I can think of is Outer:

Outer[CountryData, listCountries, data]

The other is that you want the GDP of Bangladesh, the Population of India and the area of Monaco; this can be achieved by either

CountryData @@ # & /@ Thread@{listCountries, data}

or

MapThread[CountryData, {listCountries, data}]

Answer 2

Would this work for you? Using Map twice feels like the most intuitive approach to me.

listCountries = {"United States", "Mexico", "Canada"};
data = {"GDP", "ExternalDebt"};
Function[{country}, CountryData[country, #] & /@ data] /@ listCountries

If you want to display the country next to its data, just modify your Function to include that information.

listCountries = {"United States", "Mexico", "Canada"};
data = {"GDP", "ExternalDebt"};
Function[{country}, Prepend[CountryData[country, #] & /@ data, 
   country]] /@ listCountries