I want to LogPlot a function, but I have the trouble in the number format in the ticks.

For example,

LogPlot[Abs[BesselJ[1, x] Sin[x]^2], {x, -10, 10},
   Frame -> True, FrameTicks -> {{Automatic, None}, {None, None}}]

The output is

Plot output

If I use the command

LogPlot[Abs[BesselJ[1, x] Sin[x]^2], {x, -10, 10}, Frame -> True,  
  FrameTicks -> {
    {{#, HoldForm[#]} & /@ {10^0, 10^-1, 10^-2, 10^-3, 10^-4, 10^-5}, None},
    {None, None}

I can get

Plot output

Actually, I prefer the all the ticks in the form of 10^n, and none of the commands shown above works.

Is there any simple and clever way to cope with it? I'll be grateful for your reply.


3 Answers 3


Perhaps this?

LogPlot[Abs[BesselJ[1, x] Sin[x]^2], {x, -10, 10}, Frame -> True, 
 FrameTicks -> {{{#, Superscript[10, Log10@#]} & /@ ({10^0, 10^-1, 
       10^-2, 10^-3, 10^-4, 10^-5}), None}, {None, None}}]

Mathematica graphics

Here's a completely different approach, manipulating the existing tick labels in the generated graph, and preserving the unlabeled ticks. This seems much cleaner to me than Peter's approach, assuming that it works on version 8 as it does on version 7.

format =
  Replace[#, {p_, n_?NumericQ} :> {p, Superscript[10, Round@Log10@n]}, {#2}] &;

ticks = MapThread[format, {Options[#, {Ticks, FrameTicks}], {3, 4}}] &;


p = LogPlot[Abs[BesselJ[1, x] Sin[x]^2], {x, -10, 10}, Frame -> True];

Show[p, ticks[p]]

enter image description here

Update 2015

The new Ticks subsystem

Recent versions of Mathematica use a different ticks rendering system wherein functions specified for Ticks or FrameTicks are passed to the Front End (which calls the Kernel) rather than being evaluated beforehand. If we look at the options of p above we now see:

Options[p, {Ticks, FrameTicks}]
 Ticks -> {Automatic, Charting`ScaledTicks[{Log, Exp}]}, 
 FrameTicks -> {{Charting`ScaledTicks[{Log, Exp}], 
    Charting`ScaledFrameTicks[{Log, Exp}]}, {Automatic, Automatic}}

We could use these functions to compute tick specifications external to plotting, but to follow the spirit of the new paradigm we can modify the output of these functions instead.

ScaledTicks returns (at least?) three different label formats which we must handle:

Charting`ScaledTicks[{Log, Exp}][-11.7, 1.618][[2 ;; 4, 2]] // InputForm
{Superscript[10, -4], 0.001, NumberForm[0.01, {Infinity, 3}]}

The Superscript is already our desired format. The other two may be handled with replacement:

format2 =
  Replace[#, n_?NumericQ | NumberForm[n_, _] :> Superscript[10, Round@Log10@n]] &;

We can then use this to apply the formatting:

relabel = # /. CST_Charting`ScaledTicks :> (MapAt[format2, CST[##], {All, 2}] &) &;

LogPlot[Abs[BesselJ[1, x] Sin[x]^2], {x, -10, 10}] // relabel

enter image description here

relabel also works with framed plots.

Spelunking internal functions

One may be interested is the source of the original label formatting. Charting`ScaledTicks calls:


which takes the option "CutoffExponent" which we would like to use, but unfortunately ScaledTicks overrides it. If we use:

ClearAttributes[Charting`ScaledTicks, {Protected, ReadProtected}]

And then modify the definition to replace:

"CutoffExponent" -> 
    Visualization`Utilities`ScalingDump`if} === {Identity, Identity}, 6, 4]


"CutoffExponent" -> 1

We will find that the desired formatting has been effected:

LogPlot[Abs[BesselJ[1, x] Sin[x]^2], {x, -10, 10}, Frame -> True]

enter image description here

This modification is inadvisable however, and sadly Charting`ScaledTicks does not itself take "CutoffExponent" as an option that would be passed on. One could modify its definition to add this option, but it is safer to use relabel defined above.

  • $\begingroup$ Yes, it is a similiar way to mine. LogPlot[Abs[BesselJ[1, x] Sin[x]^2], {x, -10, 10}, Frame -> True, FrameTicks -> {{{10^-#, Superscript[10, -#]} & /@ {0, 1, 2, 3, 4}, None}, {None, None}}] $\endgroup$
    – yulinlinyu
    Commented May 9, 2012 at 10:06
  • $\begingroup$ could you also write how to modify the number of digits for the tick labels, for example according to NumberForm[tick, {3, 2}]? thanks $\endgroup$
    – Valerio
    Commented Mar 4, 2013 at 8:29
  • $\begingroup$ @Valerio I don't know exactly what you want. Are you also working with LogPlot or just plain Plot? Do you want to change the tick labels on both axes or just the Y axis as done here? If you are around in the next couple of hours we could chat about it. $\endgroup$
    – Mr.Wizard
    Commented Mar 4, 2013 at 13:02
  • 1
    $\begingroup$ @Valerio you can manually specify which ticks to use with the Ticks or FrameTicks option. You can also define a function that generates these ticks, for example: tf = N@FindDivisions[{#, #2}, 20] &; Plot[Sin[x], {x, 0, 2 Pi}, Ticks -> tf] -- this can be done for each axis independently. Be aware with my example that FindDivisions will generate about the number of divisions you specify and not that number exactly. $\endgroup$
    – Mr.Wizard
    Commented Mar 13, 2013 at 16:02
  • 2
    $\begingroup$ the opposite. Usually, something is released, and over time the internal functions are hunted down, tagged, and added to personal libraries, and it usually doesn't take to long. I find it impressive. $\endgroup$
    – rcollyer
    Commented Mar 3, 2015 at 20:48

If you want the minor ticks too, you can use the following function:

SetAttributes[dtZahl, Listable]
dtZahl[x_] := Block[{n}, If[IntegerQ[n = Rationalize[x]], n, x]]

exponentForm[x_?NumberQ] := 
  Module[{me = MantissaExponent[x], num, exp}, 
   If[MemberQ[{0, 0., 1, 1., -1, -1.}, x], Return[IntegerPart[x]]];
   exp = Superscript["\[CenterDot]10", me[[2]] - 1];
   num = NumberForm[N[me[[1]]]*10 // dtZahl, 3];
   If[me[[1]] == 0.1,(*no mantissa*)num = "";
    exp = Superscript[10, me[[2]] - 1], 
    If[me[[2]] == 1,(*range 0..10*)exp = ""]];
   Row[{num, exp}]];
exponentForm[x_] := x

Options[logTicks] = {TicksFaktor -> 1};
logTicks[von_Integer, bis_Integer, werte_List, subwerte_List, 
  OptionsPattern[]] :=
 Module[{mt, st, ticks, res, tf},
  tf = OptionValue[TicksFaktor];
  mt = {#, exponentForm[N[#]], {0.01, 0}*tf} & /@ 
    Flatten@Table[10^i*werte, {i, von, bis}];
  st = {#, Null, {0.005, 0}*tf} & /@ 
    Flatten@Table[10^i*subwerte, {i, von, bis}];
  Join[mt, st]]

logTicks takes the following Parameters:
von and bis are the lowest and highest exponent. The list werte is the list of labeled ticks in one decade and subwerte the list of unlabeled ticks in one decade.


  ticks = logTicks[-4, 1, {1}, {2, 3, 5, 7}];
  LogPlot[Abs[BesselJ[1, x] Sin[x]^2], {x, -10, 10}, Frame -> True, 
   FrameTicks -> {{ticks, None}, {None, None}}],
  ticks = logTicks[-4, 1, {1, 3}, {2, 5, 7}];
  LogPlot[Abs[BesselJ[1, x] Sin[x]^2], {x, -10, 10}, Frame -> True, 
   FrameTicks -> {{ticks, None}, {None, None}}]

Output: Mathematica graphics

  • 2
    $\begingroup$ +1 very nice function! Don't know why this tick feature is still missing in MMA9... $\endgroup$
    – Leo Fang
    Commented Aug 24, 2013 at 4:04

Is there any simple and clever way to cope with it?

Why yes there is, just use the CustomTicks package,

Plot[Log10@Abs[BesselJ[1, x] Sin[x]^2], {x, -10, 10}, Frame -> True, 
 FrameTicks -> {{LogTicks, None}, {None, None}}, Axes -> None]

enter image description here

  • 1
    $\begingroup$ It is better to use updated version of the CustomTicks package from the SciDraw package instead of the vastly outdated version available from library.wolfram.com. $\endgroup$ Commented Feb 16, 2016 at 17:16
  • $\begingroup$ @AlexeyPopkov I will check which version I have, they should take the trouble to update the post on the library though since it is the top google search result.is $\endgroup$
    – Jason B.
    Commented Feb 16, 2016 at 17:32

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service and acknowledge you have read our privacy policy.

Not the answer you're looking for? Browse other questions tagged or ask your own question.