44
$\begingroup$

How does one set a logarithmic scale for both x and y axes in ContourPlot in Mathematica?

$\endgroup$
41
$\begingroup$

One possibility is to plot the contour plot with linear scales using ContourPlot and use ListLogLogPlot to transform this plot to one with logarithmic scales:

pl = Normal@
  ContourPlot[
   Sin[3 x] + Cos[3 y] == 1/2, {x, .01 Pi, 3 Pi}, {y, .01 Pi, 3 Pi}, 
   PlotPoints -> 30]

Mathematica graphics

ListLogLogPlot[Cases[pl, Line[a_, b___] :> a, Infinity], 
 Joined -> True, Frame -> True, PlotRange -> All, AspectRatio -> 1, 
 PlotStyle -> ColorData[1][1]]

Mathematica graphics

$\endgroup$
  • 1
    $\begingroup$ I keep missing the fun questions. Nice answer. +1 $\endgroup$ – Mr.Wizard May 7 '12 at 8:56
  • $\begingroup$ Great idea! I never thought of that. $\endgroup$ – sebhofer May 7 '12 at 15:15
  • 6
    $\begingroup$ One disadvantage this method might have is that of point sampling. The right hand and the upper parts are better sampled than the left hand and lower parts of the plot. This might lead to curves that are less smooth on one side than on the other. $\endgroup$ – Sjoerd C. de Vries May 7 '12 at 17:33
  • 1
    $\begingroup$ I think that there are actually a lot of other limitations... It's a pity the scaling functions are still not available to this type of plot... For instance, as long as we choose a simple option like ContourLabels, everything becomes more messy... $\endgroup$ – P. Fonseca May 1 '16 at 10:29
  • $\begingroup$ Hahllelujah! Now if only they would provide better Tick control options for Log Plots $\endgroup$ – Paul Drake Apr 8 '18 at 15:58
28
$\begingroup$

Instead of doing some transformation on the original ContourPlot we can do an exponential rescaling of the original variables in the ContourPlot, so this is somewhat different approach to get roughly the same result :

ContourPlot[ Sin[ 3 Exp@x] + Cos[ 3 Exp@y ] == 1/2, 
             {x, Log[0.01 Pi], Log[3 Pi]}, {y, Log[0.01 Pi], Log[3 Pi]}, PlotPoints -> 30]

enter image description here

The only difference is a different coordinate system.

$\endgroup$
  • $\begingroup$ The downside is the ticks placement and labels. $\endgroup$ – becko Oct 3 '17 at 23:37
  • $\begingroup$ @becko If you had read the answer below you wouldn't have mentioned this at all. $\endgroup$ – Artes Oct 4 '17 at 7:37
15
$\begingroup$

As a slight variation of the nice suggestion above add FrameTicks to get the tick labels you want.

ContourPlot[
 Sin[3 Exp[x]] + Cos[3 Exp[y]] == 1/2, {x, Log[0.01 Pi], 
  Log[3 Pi]}, {y, Log[0.01 Pi], Log[3 Pi]}, PlotPoints -> 30, 
 FrameTicks -> {Table[{y, ToString[Round[10^y, 0.001]]}, {y, 
     Log[10, 0.001], Log[10, 100]}], 
   Table[{y, ToString[Round[10^y, 0.001]]}, {y, Log[10, 0.001], 
     Log[10, 100]}]}]
$\endgroup$
  • 6
    $\begingroup$ Your example uses a base-E log scale for the plotting and a base-10 log scale for the ticks. Shouldn't these be consistent? $\endgroup$ – Sean Colsen Nov 16 '13 at 4:16
10
$\begingroup$

As of M11, you can use the ScalingFunctions option:

ContourPlot[
    Sin[3 x]+Cos[3 y]==1/2,
    {x,.01 Pi,3 Pi},
    {y,.01 Pi,3 Pi},
    ScalingFunctions->{"Log","Log"}
]

enter image description here

$\endgroup$
  • $\begingroup$ It appears that I'm six months late to this answer. :) $\endgroup$ – rcollyer Jul 10 '18 at 20:02
  • $\begingroup$ Unfortunately this option is just a patch job, it just log's the data and relabels the axes in one step, therefore you cannot combine this plot with other true log plots e.g. LogListPlot. $\endgroup$ – Jay Oct 8 at 18:48
  • $\begingroup$ @Jay Can you provide an example where plots can't be combined? Perhaps in another question. $\endgroup$ – Carl Woll Oct 8 at 19:12
  • $\begingroup$ There is a simple workaround: use scaling functions for ListPlot instead of LogListPlot.. I don't know if this warrants it's own question. $\endgroup$ – Jay Oct 9 at 20:36

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service, privacy policy and cookie policy

Not the answer you're looking for? Browse other questions tagged or ask your own question.