How does one set a logarithmic scale for both x and y axes in ContourPlot in Mathematica?
$\begingroup$
$\endgroup$
0
asked May 7, 2012 at 8:23
Add a comment
|
4 Answers
$\begingroup$
$\endgroup$
5
One possibility is to plot the contour plot with linear scales using ContourPlot and use ListLogLogPlot to transform this plot to one with logarithmic scales:
pl = Normal@
ContourPlot[
Sin[3 x] + Cos[3 y] == 1/2, {x, .01 Pi, 3 Pi}, {y, .01 Pi, 3 Pi},
PlotPoints -> 30]
ListLogLogPlot[Cases[pl, Line[a_, b___] :> a, Infinity],
Joined -> True, Frame -> True, PlotRange -> All, AspectRatio -> 1,
PlotStyle -> ColorData[1][1]]
-
1$\begingroup$ I keep missing the fun questions. Nice answer. +1 $\endgroup$ May 7, 2012 at 8:56
-
-
6$\begingroup$ One disadvantage this method might have is that of point sampling. The right hand and the upper parts are better sampled than the left hand and lower parts of the plot. This might lead to curves that are less smooth on one side than on the other. $\endgroup$ May 7, 2012 at 17:33
-
1$\begingroup$ I think that there are actually a lot of other limitations... It's a pity the scaling functions are still not available to this type of plot... For instance, as long as we choose a simple option like ContourLabels, everything becomes more messy... $\endgroup$ May 1, 2016 at 10:29
-
$\begingroup$ Hahllelujah! Now if only they would provide better Tick control options for Log Plots $\endgroup$ Apr 8, 2018 at 15:58
$\begingroup$
$\endgroup$
2
Instead of doing some transformation on the original ContourPlot we can do an exponential rescaling of the original variables in the ContourPlot, so this is somewhat different approach to get roughly the same result :
ContourPlot[ Sin[ 3 Exp@x] + Cos[ 3 Exp@y ] == 1/2,
{x, Log[0.01 Pi], Log[3 Pi]}, {y, Log[0.01 Pi], Log[3 Pi]}, PlotPoints -> 30]
The only difference is a different coordinate system.
$\begingroup$
$\endgroup$
5
As of M11, you can use the ScalingFunctions option:
ContourPlot[
Sin[3 x]+Cos[3 y]==1/2,
{x,.01 Pi,3 Pi},
{y,.01 Pi,3 Pi},
ScalingFunctions->{"Log","Log"}
]
answered Jan 28, 2018 at 4:23
-
$\begingroup$ It appears that I'm six months late to this answer. :) $\endgroup$– rcollyerJul 10, 2018 at 20:02
-
$\begingroup$ Unfortunately this option is just a patch job, it just log's the data and relabels the axes in one step, therefore you cannot combine this plot with other true log plots e.g. LogListPlot. $\endgroup$– JayOct 8, 2019 at 18:48
-
$\begingroup$ @Jay Can you provide an example where plots can't be combined? Perhaps in another question. $\endgroup$ Oct 8, 2019 at 19:12
-
1$\begingroup$ There is a simple workaround: use scaling functions for ListPlot instead of LogListPlot.. I don't know if this warrants it's own question. $\endgroup$– JayOct 9, 2019 at 20:36
-
1$\begingroup$ What if I wanted to Log only one axis? what would I replace "Log" with for the one I wanted to stay linear? $\endgroup$– RudyardMar 30, 2021 at 13:43
$\begingroup$
$\endgroup$
1
As a slight variation of the nice suggestion above add FrameTicks to get the tick labels you want.
ContourPlot[
Sin[3 Exp[x]] + Cos[3 Exp[y]] == 1/2, {x, Log[0.01 Pi],
Log[3 Pi]}, {y, Log[0.01 Pi], Log[3 Pi]}, PlotPoints -> 30,
FrameTicks -> {Table[{y, ToString[Round[10^y, 0.001]]}, {y,
Log[10, 0.001], Log[10, 100]}],
Table[{y, ToString[Round[10^y, 0.001]]}, {y, Log[10, 0.001],
Log[10, 100]}]}]
-
6$\begingroup$ Your example uses a base-E log scale for the plotting and a base-10 log scale for the ticks. Shouldn't these be consistent? $\endgroup$– SeanNov 16, 2013 at 4:16