2
$\begingroup$

I'm trying to solve a set of equations (chemical kinetics for a complex system, but don't worry about that). I ran it for 24 hours and I got no output. Here is the relatively simple code (I want to eliminate everything except for Itot and x and solve for one of them):

eq1 = x == (Etot - M - MI)/(Etot - 1/4 (-Kd + Sqrt[Kd] Sqrt[8 Etot + Kd]))
eq2 = Etot == M + 2*Di + M*Inh
eq3 = Itot == Inh + MI 
eq4 = Kd == M*M/Di
eq5 = Ki == M*Inh/MI
Solve[{eq1, eq2, eq3, eq4, eq5}, Itot, {Di, M, Inh, MI}]

I hoped to benefit from knowing a few things, like the fact that all quantities are nonnegative and real. So I tried this (not sure if I've done it correctly because the documentation on Solve is a little confusing):

Solve[{eq1, eq2, eq3, eq4, eq5, x >= 0, Itot >= 0, Di >= 0, M >= 0, 
      Inh >= 0, MI >= 0}, Itot, {Di, M, Inh, MI}, Reals]

But again nothing in 24 hours. Any suggestions? Would it be helpful if I tried to remove a variable or two myself?

Improve this question
$\endgroup$
1

1 Answer 1

Reset to default
6
$\begingroup$

Here is some preprocessing that might be useful. We will get rid of radicals "by hand", and eliminate variables using GroebnerBasis. The end result will be a single (complicated) expression in several variables.

eqns = {x == (Etot - M - MI)/(
    Etot + 1/4 (Kd - Sqrt[Kd] Sqrt[8 Etot + Kd])), 
   Etot == 2 Di + M + Inh M, Itot == Inh + MI, Kd == M^2/Di, 
   Ki == (Inh M)/MI};

Form expressions, and extract numerators. Strictly speaking we would then need to check subsequent results to make sure they do not allow denominators to vanish. We'll skate on thin ice around this issue today.

exprs = Apply[Subtract, eqns, {1}];
numers = Numerator[Together[exprs]]

(* {-4 Etot + 4 M + 4 MI + 4 Etot x + Kd x - 
  Sqrt[Kd] Sqrt[8 Etot + Kd] x, -2 Di + Etot - M - Inh M, -Inh + 
  Itot - MI, Di Kd - M^2, -Inh M + Ki MI} *)

Now create new variables and defining expressions for the radicals. We will later eliminate those variables.

reps = {Sqrt[Kd] -> sqrt1, Sqrt[8 Etot + Kd] -> sqrt2};
extras = {sqrt1^2 - Kd, sqrt2^2 - (8 Etot + Kd)};

So here is our polynomial system.

new = Join[numers /. reps, extras]

(* {-4 Etot + 4 M + 4 MI + 4 Etot x + Kd x - sqrt1 sqrt2 x, -2 Di + 
  Etot - M - Inh M, -Inh + Itot - MI, 
 Di Kd - M^2, -Inh M + Ki MI, -Kd + sqrt1^2, -8 Etot - Kd + sqrt2^2} *)

Now compute a Groebner basis. It will have but one element (but that element is an elephant).

Timing[
 gb = GroebnerBasis[new, Itot, {sqrt1, sqrt2, Di, M, Inh, MI}, 
   MonomialOrder -> EliminationOrder]]

(* Out[407]= {1.912000, {16 Etot^6 Kd^2 - 64 Etot^5 Itot Kd^2 + 
   96 Etot^4 Itot^2 Kd^2 - 64 Etot^3 Itot^3 Kd^2 + 
   16 Etot^2 Itot^4 Kd^2 - 16 Etot^4 Itot Kd^3 + 
   32 Etot^3 Itot^2 Kd^3 - 16 Etot^2 Itot^3 Kd^3 + 
   4 Etot^2 Itot^2 Kd^4 + 32 Etot^5 Kd^2 Ki - 32 Etot^6 Kd^2 Ki - 
   32 Etot^4 Itot Kd^2 Ki + 128 Etot^5 Itot Kd^2 Ki - 
   32 Etot^3 Itot^2 Kd^2 Ki - 192 Etot^4 Itot^2 Kd^2 Ki + 
   32 Etot^2 Itot^3 Kd^2 Ki + 128 Etot^3 Itot^3 Kd^2 Ki - 
   32 Etot^2 Itot^4 Kd^2 Ki - 16 Etot^3 Itot Kd^3 Ki + 
   48 Etot^4 Itot Kd^3 Ki - 16 Etot^2 Itot^2 Kd^3 Ki - 
   96 Etot^3 Itot^2 Kd^3 Ki + 48 Etot^2 Itot^3 Kd^3 Ki - 
   16 Etot^2 Itot^2 Kd^4 Ki - 64 Etot^5 Kd Ki^2 + 
   128 Etot^4 Itot Kd Ki^2 - 64 Etot^3 Itot^2 Kd Ki^2 + 
   16 Etot^4 Kd^2 Ki^2 - 64 Etot^5 Kd^2 Ki^2 + 16 Etot^6 Kd^2 Ki^2 + 
   64 Etot^3 Itot Kd^2 Ki^2 + 64 Etot^4 Itot Kd^2 Ki^2 - 
   64 Etot^5 Itot Kd^2 Ki^2 + 16 Etot^2 Itot^2 Kd^2 Ki^2 + 
   64 Etot^3 Itot^2 Kd^2 Ki^2 + 96 Etot^4 Itot^2 Kd^2 Ki^2 - 
   64 Etot^2 Itot^3 Kd^2 Ki^2 - 64 Etot^3 Itot^3 Kd^2 Ki^2 + 
   16 Etot^2 Itot^4 Kd^2 Ki^2 + 48 Etot^3 Itot Kd^3 Ki^2 - 
   48 Etot^4 Itot Kd^3 Ki^2 + 48 Etot^2 Itot^2 Kd^3 Ki^2 + 
   96 Etot^3 Itot^2 Kd^3 Ki^2 - 48 Etot^2 Itot^3 Kd^3 Ki^2 + 
   24 Etot^2 Itot^2 Kd^4 Ki^2 - 64 Etot^4 Kd Ki^3 + 
   64 Etot^5 Kd Ki^3 - 64 Etot^3 Itot Kd Ki^3 - 
   128 Etot^4 Itot Kd Ki^3 + 64 Etot^3 Itot^2 Kd Ki^3 - 
   32 Etot^4 Kd^2 Ki^3 + 32 Etot^5 Kd^2 Ki^3 - 
   128 Etot^3 Itot Kd^2 Ki^3 - 32 Etot^4 Itot Kd^2 Ki^3 - 
   32 Etot^2 Itot^2 Kd^2 Ki^3 - 32 Etot^3 Itot^2 Kd^2 Ki^3 + 
   32 Etot^2 Itot^3 Kd^2 Ki^3 - 48 Etot^3 Itot Kd^3 Ki^3 + 
   16 Etot^4 Itot Kd^3 Ki^3 - 48 Etot^2 Itot^2 Kd^3 Ki^3 - 
   32 Etot^3 Itot^2 Kd^3 Ki^3 + 16 Etot^2 Itot^3 Kd^3 Ki^3 - 
   16 Etot^2 Itot^2 Kd^4 Ki^3 + 64 Etot^4 Ki^4 + 64 Etot^4 Kd Ki^4 + 
   64 Etot^3 Itot Kd Ki^4 + 16 Etot^4 Kd^2 Ki^4 + 
   64 Etot^3 Itot Kd^2 Ki^4 + 16 Etot^2 Itot^2 Kd^2 Ki^4 + 
   16 Etot^3 Itot Kd^3 Ki^4 + 16 Etot^2 Itot^2 Kd^3 Ki^4 + 
   4 Etot^2 Itot^2 Kd^4 Ki^4 - 64 Etot^6 Kd^2 x + 
   192 Etot^5 Itot Kd^2 x - 192 Etot^4 Itot^2 Kd^2 x + 
   64 Etot^3 Itot^3 Kd^2 x - 32 Etot^5 Kd^3 x + 
   112 Etot^4 Itot Kd^3 x - 96 Etot^3 Itot^2 Kd^3 x + 
   16 Etot^2 Itot^3 Kd^3 x - 4 Etot^4 Kd^4 x + 
   24 Etot^3 Itot Kd^4 x - 12 Etot^2 Itot^2 Kd^4 x + 
   2 Etot^2 Itot Kd^5 x - 128 Etot^5 Kd^2 Ki x + 
   160 Etot^6 Kd^2 Ki x + 160 Etot^4 Itot Kd^2 Ki x - 
   512 Etot^5 Itot Kd^2 Ki x - 64 Etot^3 Itot^2 Kd^2 Ki x + 
   576 Etot^4 Itot^2 Kd^2 Ki x + 32 Etot^2 Itot^3 Kd^2 Ki x - 
   256 Etot^3 Itot^3 Kd^2 Ki x + 32 Etot^2 Itot^4 Kd^2 Ki x - 
   64 Etot^4 Kd^3 Ki x + 72 Etot^5 Kd^3 Ki x + 
   88 Etot^3 Itot Kd^3 Ki x - 320 Etot^4 Itot Kd^3 Ki x - 
   48 Etot^2 Itot^2 Kd^3 Ki x + 336 Etot^3 Itot^2 Kd^3 Ki x + 
   8 Etot Itot^3 Kd^3 Ki x - 96 Etot^2 Itot^3 Kd^3 Ki x + 
   8 Etot Itot^4 Kd^3 Ki x - 8 Etot^3 Kd^4 Ki x + 
   8 Etot^4 Kd^4 Ki x + 20 Etot^2 Itot Kd^4 Ki x - 
   72 Etot^3 Itot Kd^4 Ki x - 8 Etot Itot^2 Kd^4 Ki x + 
   56 Etot^2 Itot^2 Kd^4 Ki x - 8 Etot Itot^3 Kd^4 Ki x + 
   2 Etot Itot Kd^5 Ki x - 6 Etot^2 Itot Kd^5 Ki x + 
   2 Etot Itot^2 Kd^5 Ki x + 256 Etot^5 Kd Ki^2 x - 
   384 Etot^4 Itot Kd Ki^2 x + 128 Etot^3 Itot^2 Kd Ki^2 x + 
   64 Etot^4 Kd^2 Ki^2 x + 288 Etot^5 Kd^2 Ki^2 x - 
   96 Etot^6 Kd^2 Ki^2 x - 256 Etot^3 Itot Kd^2 Ki^2 x - 
   288 Etot^4 Itot Kd^2 Ki^2 x + 320 Etot^5 Itot Kd^2 Ki^2 x + 
   96 Etot^2 Itot^2 Kd^2 Ki^2 x - 32 Etot^3 Itot^2 Kd^2 Ki^2 x - 
   384 Etot^4 Itot^2 Kd^2 Ki^2 x + 32 Etot^2 Itot^3 Kd^2 Ki^2 x + 
   192 Etot^3 Itot^3 Kd^2 Ki^2 x - 32 Etot^2 Itot^4 Kd^2 Ki^2 x - 
   16 Etot^3 Kd^3 Ki^2 x + 136 Etot^4 Kd^3 Ki^2 x - 
   40 Etot^5 Kd^3 Ki^2 x - 72 Etot^2 Itot Kd^3 Ki^2 x - 
   216 Etot^3 Itot Kd^3 Ki^2 x + 272 Etot^4 Itot Kd^3 Ki^2 x + 
   16 Etot Itot^2 Kd^3 Ki^2 x + 24 Etot^2 Itot^2 Kd^3 Ki^2 x - 
   336 Etot^3 Itot^2 Kd^3 Ki^2 x + 8 Etot Itot^3 Kd^3 Ki^2 x + 
   112 Etot^2 Itot^3 Kd^3 Ki^2 x - 8 Etot Itot^4 Kd^3 Ki^2 x - 
   4 Etot^2 Kd^4 Ki^2 x + 16 Etot^3 Kd^4 Ki^2 x - 
   4 Etot^4 Kd^4 Ki^2 x - 8 Etot Itot Kd^4 Ki^2 x - 
   60 Etot^2 Itot Kd^4 Ki^2 x + 72 Etot^3 Itot Kd^4 Ki^2 x + 
   8 Etot Itot^2 Kd^4 Ki^2 x - 84 Etot^2 Itot^2 Kd^4 Ki^2 x + 
   16 Etot Itot^3 Kd^4 Ki^2 x - 6 Etot Itot Kd^5 Ki^2 x + 
   6 Etot^2 Itot Kd^5 Ki^2 x - 6 Etot Itot^2 Kd^5 Ki^2 x + 
   256 Etot^4 Kd Ki^3 x - 320 Etot^5 Kd Ki^3 x + 
   64 Etot^3 Itot Kd Ki^3 x + 512 Etot^4 Itot Kd Ki^3 x - 
   192 Etot^3 Itot^2 Kd Ki^3 x + 128 Etot^3 Kd^2 Ki^3 x - 
   16 Etot^4 Kd^2 Ki^3 x - 160 Etot^5 Kd^2 Ki^3 x + 
   48 Etot^2 Itot Kd^2 Ki^3 x + 480 Etot^3 Itot Kd^2 Ki^3 x + 
   128 Etot^4 Itot Kd^2 Ki^3 x - 80 Etot^2 Itot^2 Kd^2 Ki^3 x + 
   96 Etot^3 Itot^2 Kd^2 Ki^3 x - 64 Etot^2 Itot^3 Kd^2 Ki^3 x + 
   16 Etot^2 Kd^3 Ki^3 x + 48 Etot^3 Kd^3 Ki^3 x - 
   72 Etot^4 Kd^3 Ki^3 x + 8 Etot Itot Kd^3 Ki^3 x + 
   152 Etot^2 Itot Kd^3 Ki^3 x + 176 Etot^3 Itot Kd^3 Ki^3 x - 
   64 Etot^4 Itot Kd^3 Ki^3 x - 8 Etot Itot^2 Kd^3 Ki^3 x + 
   56 Etot^2 Itot^2 Kd^3 Ki^3 x + 96 Etot^3 Itot^2 Kd^3 Ki^3 x - 
   16 Etot Itot^3 Kd^3 Ki^3 x - 32 Etot^2 Itot^3 Kd^3 Ki^3 x + 
   8 Etot^2 Kd^4 Ki^3 x - 8 Etot^3 Kd^4 Ki^3 x + 
   16 Etot Itot Kd^4 Ki^3 x + 60 Etot^2 Itot Kd^4 Ki^3 x - 
   24 Etot^3 Itot Kd^4 Ki^3 x + 8 Etot Itot^2 Kd^4 Ki^3 x + 
   48 Etot^2 Itot^2 Kd^4 Ki^3 x - 8 Etot Itot^3 Kd^4 Ki^3 x + 
   6 Etot Itot Kd^5 Ki^3 x - 2 Etot^2 Itot Kd^5 Ki^3 x + 
   6 Etot Itot^2 Kd^5 Ki^3 x - 256 Etot^4 Ki^4 x - 
   128 Etot^3 Kd Ki^4 x - 256 Etot^4 Kd Ki^4 x - 
   192 Etot^3 Itot Kd Ki^4 x - 16 Etot^2 Kd^2 Ki^4 x - 
   128 Etot^3 Kd^2 Ki^4 x - 64 Etot^4 Kd^2 Ki^4 x - 
   80 Etot^2 Itot Kd^2 Ki^4 x - 192 Etot^3 Itot Kd^2 Ki^4 x - 
   32 Etot^2 Itot^2 Kd^2 Ki^4 x - 16 Etot^2 Kd^3 Ki^4 x - 
   32 Etot^3 Kd^3 Ki^4 x - 8 Etot Itot Kd^3 Ki^4 x - 
   80 Etot^2 Itot Kd^3 Ki^4 x - 48 Etot^3 Itot Kd^3 Ki^4 x - 
   8 Etot Itot^2 Kd^3 Ki^4 x - 32 Etot^2 Itot^2 Kd^3 Ki^4 x - 
   4 Etot^2 Kd^4 Ki^4 x - 8 Etot Itot Kd^4 Ki^4 x - 
   20 Etot^2 Itot Kd^4 Ki^4 x - 8 Etot Itot^2 Kd^4 Ki^4 x - 
   8 Etot^2 Itot^2 Kd^4 Ki^4 x - 2 Etot Itot Kd^5 Ki^4 x - 
   2 Etot Itot^2 Kd^5 Ki^4 x + 96 Etot^6 Kd^2 x^2 - 
   192 Etot^5 Itot Kd^2 x^2 + 96 Etot^4 Itot^2 Kd^2 x^2 + 
   64 Etot^5 Kd^3 x^2 - 112 Etot^4 Itot Kd^3 x^2 + 
   32 Etot^3 Itot^2 Kd^3 x^2 + 8 Etot^4 Kd^4 x^2 - 
   24 Etot^3 Itot Kd^4 x^2 + 4 Etot^2 Itot^2 Kd^4 x^2 - 
   2 Etot^2 Itot Kd^5 x^2 + 192 Etot^5 Kd^2 Ki x^2 - 
   320 Etot^6 Kd^2 Ki x^2 - 224 Etot^4 Itot Kd^2 Ki x^2 + 
   768 Etot^5 Itot Kd^2 Ki x^2 + 96 Etot^3 Itot^2 Kd^2 Ki x^2 - 
   576 Etot^4 Itot^2 Kd^2 Ki x^2 + 128 Etot^3 Itot^3 Kd^2 Ki x^2 + 
   128 Etot^4 Kd^3 Ki x^2 - 224 Etot^5 Kd^3 Ki x^2 - 
   96 Etot^3 Itot Kd^3 Ki x^2 + 560 Etot^4 Itot Kd^3 Ki x^2 + 
   32 Etot^2 Itot^2 Kd^3 Ki x^2 - 352 Etot^3 Itot^2 Kd^3 Ki x^2 + 
   64 Etot^2 Itot^3 Kd^3 Ki x^2 + 16 Etot^3 Kd^4 Ki x^2 - 
   40 Etot^4 Kd^4 Ki x^2 - 20 Etot^2 Itot Kd^4 Ki x^2 + 
   168 Etot^3 Itot Kd^4 Ki x^2 + 4 Etot Itot^2 Kd^4 Ki x^2 - 
   80 Etot^2 Itot^2 Kd^4 Ki x^2 + 8 Etot Itot^3 Kd^4 Ki x^2 - 
   2 Etot^3 Kd^5 Ki x^2 - 2 Etot Itot Kd^5 Ki x^2 + 
   22 Etot^2 Itot Kd^5 Ki x^2 - 6 Etot Itot^2 Kd^5 Ki x^2 + 
   Etot Itot Kd^6 Ki x^2 - 384 Etot^5 Kd Ki^2 x^2 + 
   384 Etot^4 Itot Kd Ki^2 x^2 - 64 Etot^3 Itot^2 Kd Ki^2 x^2 - 
   160 Etot^4 Kd^2 Ki^2 x^2 - 512 Etot^5 Kd^2 Ki^2 x^2 + 
   240 Etot^6 Kd^2 Ki^2 x^2 + 192 Etot^3 Itot Kd^2 Ki^2 x^2 + 
   480 Etot^4 Itot Kd^2 Ki^2 x^2 - 640 Etot^5 Itot Kd^2 Ki^2 x^2 - 
   48 Etot^2 Itot^2 Kd^2 Ki^2 x^2 - 128 Etot^3 Itot^2 Kd^2 Ki^2 x^2 + 
   576 Etot^4 Itot^2 Kd^2 Ki^2 x^2 + 32 Etot^2 Itot^3 Kd^2 Ki^2 x^2 - 
   192 Etot^3 Itot^3 Kd^2 Ki^2 x^2 + 16 Etot^2 Itot^4 Kd^2 Ki^2 x^2 + 
   32 Etot^3 Kd^3 Ki^2 x^2 - 352 Etot^4 Kd^3 Ki^2 x^2 + 
   160 Etot^5 Kd^3 Ki^2 x^2 + 64 Etot^2 Itot Kd^3 Ki^2 x^2 + 
   224 Etot^3 Itot Kd^3 Ki^2 x^2 - 544 Etot^4 Itot Kd^3 Ki^2 x^2 - 
   8 Etot Itot^2 Kd^3 Ki^2 x^2 - 32 Etot^2 Itot^2 Kd^3 Ki^2 x^2 + 
   416 Etot^3 Itot^2 Kd^3 Ki^2 x^2 - 80 Etot^2 Itot^3 Kd^3 Ki^2 x^2 + 
   8 Etot^2 Kd^4 Ki^2 x^2 - 56 Etot^3 Kd^4 Ki^2 x^2 + 
   32 Etot^4 Kd^4 Ki^2 x^2 + 8 Etot Itot Kd^4 Ki^2 x^2 + 
   48 Etot^2 Itot Kd^4 Ki^2 x^2 - 208 Etot^3 Itot Kd^4 Ki^2 x^2 + 
   112 Etot^2 Itot^2 Kd^4 Ki^2 x^2 - 8 Etot Itot^3 Kd^4 Ki^2 x^2 - 
   2 Etot^2 Kd^5 Ki^2 x^2 + 2 Etot^3 Kd^5 Ki^2 x^2 + 
   4 Etot Itot Kd^5 Ki^2 x^2 - 34 Etot^2 Itot Kd^5 Ki^2 x^2 + 
   10 Etot Itot^2 Kd^5 Ki^2 x^2 - 2 Etot Itot Kd^6 Ki^2 x^2 - 
   384 Etot^4 Kd Ki^3 x^2 + 640 Etot^5 Kd Ki^3 x^2 + 
   64 Etot^3 Itot Kd Ki^3 x^2 - 768 Etot^4 Itot Kd Ki^3 x^2 + 
   192 Etot^3 Itot^2 Kd Ki^3 x^2 - 256 Etot^3 Kd^2 Ki^3 x^2 + 
   256 Etot^4 Kd^2 Ki^3 x^2 + 320 Etot^5 Kd^2 Ki^3 x^2 - 
   32 Etot^2 Itot Kd^2 Ki^3 x^2 - 576 Etot^3 Itot Kd^2 Ki^3 x^2 - 
   192 Etot^4 Itot Kd^2 Ki^3 x^2 + 128 Etot^2 Itot^2 Kd^2 Ki^3 x^2 - 
   96 Etot^3 Itot^2 Kd^2 Ki^3 x^2 + 32 Etot^2 Itot^3 Kd^2 Ki^3 x^2 - 
   32 Etot^2 Kd^3 Ki^3 x^2 - 48 Etot^3 Kd^3 Ki^3 x^2 + 
   224 Etot^4 Kd^3 Ki^3 x^2 - 8 Etot Itot Kd^3 Ki^3 x^2 - 
   176 Etot^2 Itot Kd^3 Ki^3 x^2 - 176 Etot^3 Itot Kd^3 Ki^3 x^2 + 
   96 Etot^4 Itot Kd^3 Ki^3 x^2 + 8 Etot Itot^2 Kd^3 Ki^3 x^2 - 
   16 Etot^2 Itot^2 Kd^3 Ki^3 x^2 - 96 Etot^3 Itot^2 Kd^3 Ki^3 x^2 + 
   16 Etot^2 Itot^3 Kd^3 Ki^3 x^2 - 12 Etot^2 Kd^4 Ki^3 x^2 + 
   40 Etot^3 Kd^4 Ki^3 x^2 - 16 Etot Itot Kd^4 Ki^3 x^2 - 
   52 Etot^2 Itot Kd^4 Ki^3 x^2 + 64 Etot^3 Itot Kd^4 Ki^3 x^2 - 
   4 Etot Itot^2 Kd^4 Ki^3 x^2 - 40 Etot^2 Itot^2 Kd^4 Ki^3 x^2 + 
   2 Etot^2 Kd^5 Ki^3 x^2 - 4 Etot Itot Kd^5 Ki^3 x^2 + 
   14 Etot^2 Itot Kd^5 Ki^3 x^2 - 4 Etot Itot^2 Kd^5 Ki^3 x^2 + 
   Etot Itot Kd^6 Ki^3 x^2 + 384 Etot^4 Ki^4 x^2 + 
   256 Etot^3 Kd Ki^4 x^2 + 384 Etot^4 Kd Ki^4 x^2 + 
   192 Etot^3 Itot Kd Ki^4 x^2 + 32 Etot^2 Kd^2 Ki^4 x^2 + 
   256 Etot^3 Kd^2 Ki^4 x^2 + 96 Etot^4 Kd^2 Ki^4 x^2 + 
   96 Etot^2 Itot Kd^2 Ki^4 x^2 + 192 Etot^3 Itot Kd^2 Ki^4 x^2 + 
   16 Etot^2 Itot^2 Kd^2 Ki^4 x^2 + 32 Etot^2 Kd^3 Ki^4 x^2 + 
   64 Etot^3 Kd^3 Ki^4 x^2 + 8 Etot Itot Kd^3 Ki^4 x^2 + 
   96 Etot^2 Itot Kd^3 Ki^4 x^2 + 48 Etot^3 Itot Kd^3 Ki^4 x^2 + 
   16 Etot^2 Itot^2 Kd^3 Ki^4 x^2 + 8 Etot^2 Kd^4 Ki^4 x^2 + 
   8 Etot Itot Kd^4 Ki^4 x^2 + 24 Etot^2 Itot Kd^4 Ki^4 x^2 + 
   4 Etot^2 Itot^2 Kd^4 Ki^4 x^2 + 2 Etot Itot Kd^5 Ki^4 x^2 - 
   64 Etot^6 Kd^2 x^3 + 64 Etot^5 Itot Kd^2 x^3 - 
   32 Etot^5 Kd^3 x^3 + 16 Etot^4 Itot Kd^3 x^3 - 4 Etot^4 Kd^4 x^3 - 
   128 Etot^5 Kd^2 Ki x^3 + 320 Etot^6 Kd^2 Ki x^3 + 
   96 Etot^4 Itot Kd^2 Ki x^3 - 512 Etot^5 Itot Kd^2 Ki x^3 + 
   192 Etot^4 Itot^2 Kd^2 Ki x^3 - 64 Etot^4 Kd^3 Ki x^3 + 
   240 Etot^5 Kd^3 Ki x^3 + 24 Etot^3 Itot Kd^3 Ki x^3 - 
   352 Etot^4 Itot Kd^3 Ki x^3 + 112 Etot^3 Itot^2 Kd^3 Ki x^3 - 
   8 Etot^3 Kd^4 Ki x^3 + 56 Etot^4 Kd^4 Ki x^3 - 
   104 Etot^3 Itot Kd^4 Ki x^3 + 24 Etot^2 Itot^2 Kd^4 Ki x^3 + 
   4 Etot^3 Kd^5 Ki x^3 - 16 Etot^2 Itot Kd^5 Ki x^3 + 
   2 Etot Itot^2 Kd^5 Ki x^3 - Etot Itot Kd^6 Ki x^3 + 
   256 Etot^5 Kd Ki^2 x^3 - 128 Etot^4 Itot Kd Ki^2 x^3 + 
   64 Etot^4 Kd^2 Ki^2 x^3 + 448 Etot^5 Kd^2 Ki^2 x^3 - 
   320 Etot^6 Kd^2 Ki^2 x^3 - 352 Etot^4 Itot Kd^2 Ki^2 x^3 + 
   640 Etot^5 Itot Kd^2 Ki^2 x^3 + 96 Etot^3 Itot^2 Kd^2 Ki^2 x^3 - 
   384 Etot^4 Itot^2 Kd^2 Ki^2 x^3 + 64 Etot^3 Itot^3 Kd^2 Ki^2 x^3 - 
   16 Etot^3 Kd^3 Ki^2 x^3 + 304 Etot^4 Kd^3 Ki^2 x^3 - 
   240 Etot^5 Kd^3 Ki^2 x^3 + 8 Etot^2 Itot Kd^3 Ki^2 x^3 - 
   88 Etot^3 Itot Kd^3 Ki^2 x^3 + 480 Etot^4 Itot Kd^3 Ki^2 x^3 + 
   24 Etot^2 Itot^2 Kd^3 Ki^2 x^3 - 208 Etot^3 Itot^2 Kd^3 Ki^2 x^3 + 
   16 Etot^2 Itot^3 Kd^3 Ki^2 x^3 - 4 Etot^2 Kd^4 Ki^2 x^3 + 
   64 Etot^3 Kd^4 Ki^2 x^3 - 56 Etot^4 Kd^4 Ki^2 x^3 + 
   8 Etot^2 Itot Kd^4 Ki^2 x^3 + 168 Etot^3 Itot Kd^4 Ki^2 x^3 - 
   36 Etot^2 Itot^2 Kd^4 Ki^2 x^3 + 4 Etot^2 Kd^5 Ki^2 x^3 - 
   4 Etot^3 Kd^5 Ki^2 x^3 + 2 Etot Itot Kd^5 Ki^2 x^3 + 
   30 Etot^2 Itot Kd^5 Ki^2 x^3 - 2 Etot Itot^2 Kd^5 Ki^2 x^3 + 
   2 Etot Itot Kd^6 Ki^2 x^3 + 256 Etot^4 Kd Ki^3 x^3 - 
   640 Etot^5 Kd Ki^3 x^3 - 64 Etot^3 Itot Kd Ki^3 x^3 + 
   512 Etot^4 Itot Kd Ki^3 x^3 - 64 Etot^3 Itot^2 Kd Ki^3 x^3 + 
   128 Etot^3 Kd^2 Ki^3 x^3 - 352 Etot^4 Kd^2 Ki^3 x^3 - 
   320 Etot^5 Kd^2 Ki^3 x^3 - 16 Etot^2 Itot Kd^2 Ki^3 x^3 + 
   224 Etot^3 Itot Kd^2 Ki^3 x^3 + 128 Etot^4 Itot Kd^2 Ki^3 x^3 - 
   16 Etot^2 Itot^2 Kd^2 Ki^3 x^3 + 32 Etot^3 Itot^2 Kd^2 Ki^3 x^3 + 
   16 Etot^2 Kd^3 Ki^3 x^3 - 48 Etot^3 Kd^3 Ki^3 x^3 - 
   240 Etot^4 Kd^3 Ki^3 x^3 + 24 Etot^2 Itot Kd^3 Ki^3 x^3 + 
   16 Etot^3 Itot Kd^3 Ki^3 x^3 - 64 Etot^4 Itot Kd^3 Ki^3 x^3 + 
   8 Etot^2 Itot^2 Kd^3 Ki^3 x^3 + 32 Etot^3 Itot^2 Kd^3 Ki^3 x^3 - 
   56 Etot^3 Kd^4 Ki^3 x^3 - 12 Etot^2 Itot Kd^4 Ki^3 x^3 - 
   56 Etot^3 Itot Kd^4 Ki^3 x^3 + 8 Etot^2 Itot^2 Kd^4 Ki^3 x^3 - 
   4 Etot^2 Kd^5 Ki^3 x^3 - 2 Etot Itot Kd^5 Ki^3 x^3 - 
   14 Etot^2 Itot Kd^5 Ki^3 x^3 - Etot Itot Kd^6 Ki^3 x^3 - 
   256 Etot^4 Ki^4 x^3 - 128 Etot^3 Kd Ki^4 x^3 - 
   256 Etot^4 Kd Ki^4 x^3 - 64 Etot^3 Itot Kd Ki^4 x^3 - 
   16 Etot^2 Kd^2 Ki^4 x^3 - 128 Etot^3 Kd^2 Ki^4 x^3 - 
   64 Etot^4 Kd^2 Ki^4 x^3 - 16 Etot^2 Itot Kd^2 Ki^4 x^3 - 
   64 Etot^3 Itot Kd^2 Ki^4 x^3 - 16 Etot^2 Kd^3 Ki^4 x^3 - 
   32 Etot^3 Kd^3 Ki^4 x^3 - 16 Etot^2 Itot Kd^3 Ki^4 x^3 - 
   16 Etot^3 Itot Kd^3 Ki^4 x^3 - 4 Etot^2 Kd^4 Ki^4 x^3 - 
   4 Etot^2 Itot Kd^4 Ki^4 x^3 + 16 Etot^6 Kd^2 x^4 + 
   32 Etot^5 Kd^2 Ki x^4 - 160 Etot^6 Kd^2 Ki x^4 + 
   128 Etot^5 Itot Kd^2 Ki x^4 - 96 Etot^5 Kd^3 Ki x^4 + 
   64 Etot^4 Itot Kd^3 Ki x^4 - 24 Etot^4 Kd^4 Ki x^4 + 
   8 Etot^3 Itot Kd^4 Ki x^4 - 2 Etot^3 Kd^5 Ki x^4 - 
   64 Etot^5 Kd Ki^2 x^4 + 16 Etot^4 Kd^2 Ki^2 x^4 - 
   192 Etot^5 Kd^2 Ki^2 x^4 + 240 Etot^6 Kd^2 Ki^2 x^4 + 
   96 Etot^4 Itot Kd^2 Ki^2 x^4 - 320 Etot^5 Itot Kd^2 Ki^2 x^4 + 
   96 Etot^4 Itot^2 Kd^2 Ki^2 x^4 - 96 Etot^4 Kd^3 Ki^2 x^4 + 
   160 Etot^5 Kd^3 Ki^2 x^4 + 32 Etot^3 Itot Kd^3 Ki^2 x^4 - 
   176 Etot^4 Itot Kd^3 Ki^2 x^4 + 32 Etot^3 Itot^2 Kd^3 Ki^2 x^4 - 
   24 Etot^3 Kd^4 Ki^2 x^4 + 32 Etot^4 Kd^4 Ki^2 x^4 + 
   4 Etot^2 Itot Kd^4 Ki^2 x^4 - 32 Etot^3 Itot Kd^4 Ki^2 x^4 + 
   4 Etot^2 Itot^2 Kd^4 Ki^2 x^4 - 2 Etot^2 Kd^5 Ki^2 x^4 + 
   2 Etot^3 Kd^5 Ki^2 x^4 - 2 Etot^2 Itot Kd^5 Ki^2 x^4 - 
   64 Etot^4 Kd Ki^3 x^4 + 320 Etot^5 Kd Ki^3 x^4 - 
   128 Etot^4 Itot Kd Ki^3 x^4 + 160 Etot^4 Kd^2 Ki^3 x^4 + 
   160 Etot^5 Kd^2 Ki^3 x^4 - 32 Etot^4 Itot Kd^2 Ki^3 x^4 + 
   48 Etot^3 Kd^3 Ki^3 x^4 + 96 Etot^4 Kd^3 Ki^3 x^4 + 
   32 Etot^3 Itot Kd^3 Ki^3 x^4 + 16 Etot^4 Itot Kd^3 Ki^3 x^4 + 
   4 Etot^2 Kd^4 Ki^3 x^4 + 24 Etot^3 Kd^4 Ki^3 x^4 + 
   4 Etot^2 Itot Kd^4 Ki^3 x^4 + 16 Etot^3 Itot Kd^4 Ki^3 x^4 + 
   2 Etot^2 Kd^5 Ki^3 x^4 + 2 Etot^2 Itot Kd^5 Ki^3 x^4 + 
   64 Etot^4 Ki^4 x^4 + 64 Etot^4 Kd Ki^4 x^4 + 
   16 Etot^4 Kd^2 Ki^4 x^4 + 32 Etot^6 Kd^2 Ki x^5 + 
   8 Etot^5 Kd^3 Ki x^5 + 32 Etot^5 Kd^2 Ki^2 x^5 - 
   96 Etot^6 Kd^2 Ki^2 x^5 + 64 Etot^5 Itot Kd^2 Ki^2 x^5 + 
   8 Etot^4 Kd^3 Ki^2 x^5 - 40 Etot^5 Kd^3 Ki^2 x^5 + 
   16 Etot^4 Itot Kd^3 Ki^2 x^5 - 4 Etot^4 Kd^4 Ki^2 x^5 - 
   64 Etot^5 Kd Ki^3 x^5 - 16 Etot^4 Kd^2 Ki^3 x^5 - 
   32 Etot^5 Kd^2 Ki^3 x^5 - 8 Etot^4 Kd^3 Ki^3 x^5 + 
   16 Etot^6 Kd^2 Ki^2 x^6}} *)

It's a quartic polynomial in the variable of interest, Itot.

Exponent[gb[[1]], Itot]

(* Out[409]= 4 *)

Solutions being real will depend on values of the other parameters. But at least the thing is narrowed to one equation in one (main) variable.

Improve this answer
$\endgroup$
1
  • $\begingroup$ Wow, that is really fast way to eliminate variables. I'm still hoping to find a symbolic solution for x (or Itot, either will work) but this should hopefully speed up that calculation. $\endgroup$
    – cgreen
    Jul 2, 2014 at 18:12

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service and acknowledge that you have read and understand our privacy policy and code of conduct.

Not the answer you're looking for? Browse other questions tagged or ask your own question.