How to create a writable and clearable symbol? [duplicate]

Question

I'm trying to create several symbols and assign values to them. Here's what currently appears to work:

Evaluate[Symbol["fdds" <> ToString[10]]] = 1

But there's then another problem: I can't clear it without explicitly saying fdds10, i.e. this code

Evaluate[Symbol["fdds" <> ToString[10]]] =.

as well as this

Clear[Evaluate[Symbol["fdds" <> ToString[10]]]]

give errors: the former gives

Unset::usraw: Cannot unset raw object 1. >>

and the latter results in

Clear::ssym: 1 is not a symbol or a string. >>

How do I create good easily manageable symbols?

_{PS: I know I could use something like fdds[[10]] here, but I'm interested in symbol-based solution.}

Answer 1

You can apply Clear to the result of the expression generated by the string by using the optional third argument of ToExpression:

Evaluate[Symbol["fdds" <> ToString[10]]] = 1

(* ==> 1 *)

fdds10

(* ==> 1 *)

ToExpression["fdds" <> ToString[10], InputForm, Clear]

fdds10

(* ==> fdds10 *)

The third argument of ToExpression is Clear and wraps the expression fdds10 before it is evaluated.

Answer 2

Clear works on Strings exactly for such cases (I believe).
You must still evaluate StringJoin, my favorite way being Apply:

Clear @@ {"fdds" <> ToString[10]}

If this is all you need the question should be marked as a duplicate of:

• How to Clear variables represented as a list of strings?

If we wish to make the question unique we can look at the more difficult case of Unset as applied to other kinds of definitions (those besides OwnValues). For example:

Evaluate[Symbol["foo" <> ToString[10]][x_?Negative]] = 1;
Evaluate[Symbol["foo" <> ToString[10]][x_]] = 2;

How to Unset the first definition leaving the second in place?

These definitions work:

foo10[-3]
foo10[5]

1
2

However, due to the generic nature of the second definition this will evaluate in a way we do not want:

Evaluate[Symbol["foo" <> ToString[10]][x_?Negative]]   (* Evaluate merely for consistency *)

2

We can evaluate the Symbol foo10, since here it does have a value assigned, and insert it with Function:

Unset[#[x_?Negative]] & @ Symbol["foo" <> ToString[10]]

Definition[foo10]

foo10[x_] = 2

---

Also related:

• How can I test properties of a symbol from the string name without the symbol completely evaluating
• Assigning values to a list of variable names
• Elegant manipulation of the variables list

Answer 3

I don't understand exactly what your application is, but looking at your usage I would guess, you don't want fdds[[10]] as you would need to initialize an array?

fdds[[10]] // FullForm

Part[fdds,10]

In this case you could use fdds[10]. Note that [[]] is not [] and you do not need to initialize anything.

fdds[10] // FullForm

fdds[10]

fdds[5] = 1;
fdds[10] = 2;
fdds // Definition

fdds[5]=1
fdds[10]=2

Unset[fdds[10]]
fdds // Definition

fdds[5] = 1

edit: Now I know, this is answer is not suitable for OPs case, but maybe the answer helps someone new to Mathematica to avoid messy method.