-3
$\begingroup$

i have this integral shown below is equal to 1, and i need to find "a" on mathematica, but I'm not sure how.

integral (from 0 to a) sqrt((-50.8938 sin(8.4823 t))^2+(4-11.3097 sin(11.3097 t))^2) dt = 1

any suggestions?

$\endgroup$
  • 1
    $\begingroup$ If you are asking a question about Mathematica why don't you write your code in a Mathematica-friendly way? $\endgroup$ – Öskå Jun 19 '14 at 13:54
  • 1
    $\begingroup$ Start with the free-form input, see closely related: Symbolic Definite Integration $\endgroup$ – Artes Jun 19 '14 at 15:03
4
$\begingroup$
f[t_?NumericQ] = 
  Sqrt[(-50.8938 Sin[8.4823 t])^2 + (4 - 11.3097 Sin[11.3097 t])^2];

Looking at a plot of f[t] to find an initial value for t in FindRoot

Plot[f[t], {t, 0, .1}]

enter image description here

Clear[a]

a = a /. FindRoot[
    NIntegrate[f[t], {t, 0, a}] == 1, {a, 0.08}] //
  Quiet

0.0680318

Check

NIntegrate[f[t], {t, 0, a}]

1.

Show[
 RegionPlot[0 <= t <= a && y <= f[t],
  {t, 0, .1}, {y, 0, 40},
  PlotPoints -> 50,
  AspectRatio -> 1/GoldenRatio],
 Plot[f[t], {t, 0, .1}]]

enter image description here

$\endgroup$

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service, privacy policy and cookie policy

Not the answer you're looking for? Browse other questions tagged or ask your own question.