1
$\begingroup$

Hello I am New in Mathematica. I have a set of points and I want to visualize in Wolfram Mathematica.

I want to see big blue points and small green points in one picture.

Big Blue points

{{0.35, 5.9709, -0.494276}, 
 {0.25, 6.4709, -0.794276},
 {0.3, 6.2709, -0.564276}, 
 {0.3, 5.6709, -0.594276}}

Little Green points

{{0.3, -3.41212, -1.20591}, 
 {0.4, -3.21543, -1.12591}, 
 {0.4, -3.61472, -1.33312}}

I wrote the code, but it doesn't work

gg4 = ListPointPlot3D[{{0.35, 5.9709, -0.494276}, {0.25, 
    6.4709, -0.794276}, {0.3, 6.2709, -0.564276}, {0.3, 
    5.6709, -0.594276}}, PlotStyle -> {Blue, PointSize[0.04]}]
gg2 = ListPointPlot3D[{{0.3, -3.41212, -1.20591}, {0.4, -3.21543, \
-1.12591}, {0.4, -3.61472, -1.33312}},
  PlotStyle -> {Green, PointSize[0.01]}]
Show[gg4, gg2]

I see 2 problems:

  1. The function Show , shows date only from gg4
  2. The PointSize function doesn't work. It is working, when I write PlotStyle -> { PointSize[0.01], Green} , but the colour function is not working in this case.
$\endgroup$
  • $\begingroup$ gg4 = ListPointPlot3D[{{0.35, 5.9709, -0.494276}, {0.25, 6.4709, -0.794276}, {0.3, 6.2709, -0.564276}, {0.3, 5.6709, -0.594276}}, PlotStyle -> Directive[Blue, PointSize[0.05]]]; gg2 = ListPointPlot3D[{{0.3, -3.41212, -1.20591}, {0.4, -3.21543, -1.12591}, {0.4, -3.61472, -1.33312}},PlotStyle -> Directive[Green, PointSize[0.05]]]; Show[gg4, gg2, PlotRange -> All] gives !Mathematica graphics $\endgroup$ – Nasser Jun 15 '14 at 22:49
  • $\begingroup$ cross posted here community.wolfram.com/groups/-/m/t/276618?p_p_auth=d6m9oI1v $\endgroup$ – Nasser Jun 15 '14 at 22:54
2
$\begingroup$
lst1 = {{0.35, 5.9709, -0.494276}, {0.25, 6.4709, -0.794276},   
        {0.3,  6.2709, -0.564276}, {0.3, 5.6709, -0.594276}};
lst2 = {{0.3, -3.41212, -1.20591}, {0.4, -3.21543, -1.12591}, {0.4, -3.61472, -1.33312}};
ListPointPlot3D[{lst1, lst2}, 
    PlotStyle -> {Directive[Blue, PointSize[0.04]], 
                   Directive[Green, PointSize[0.02]]}]

enter image description here

$\endgroup$
  • $\begingroup$ @lol - +1 on simultaneous answer... $\endgroup$ – ciao Jun 15 '14 at 22:48
  • $\begingroup$ @rasher, I accidentally/luckily hit Submit before loading the picture - it would have taken more than two seconds to load it :) $\endgroup$ – kglr Jun 15 '14 at 22:54
2
$\begingroup$
ListPointPlot3D[{{{0.35, 5.9709, -0.494276}, {0.25, 
    6.4709, -0.794276}, {0.3, 6.2709, -0.564276}, {0.3, 
    5.6709, -0.594276}}, {{0.3, -3.41212, -1.20591}, {0.4, -3.21543, -1.12591}, 
    {0.4, -3.61472, -1.33312}}}, 
 PlotStyle -> {Directive[{Blue, PointSize[0.02]}], 
   Directive[{Darker[Green], PointSize[0.01]}]}]

enter image description here

$\endgroup$
0
$\begingroup$

This answer may be out of scope of your question but you can see how powerful is Mathematica.

 lst1 = {{0.35, 5.9709, -0.494276}, {0.25, 6.4709, -0.794276},
            {0.3,6.2709, -0.564276}, {0.3,5.6709, -0.594276}};
lst2 = {{0.3, -3.41212, -1.20591}, {0.4,-3.21543, -1.12591}, {0.4, -3.61472, -1.33312}};

Manipulate[
 ListPointPlot3D[{lst1, lst2}, 
  PlotStyle -> {Directive[color1, PointSize[size1]], 
    Directive[color2, PointSize[size2]]}], {color1, 
  ColorSlider}, {color2, ColorSlider}, {size1, 0.01, 0.1}, {size2, 
  0.01, 0.1}]
$\endgroup$
0
$\begingroup$

I post this just for variety (using Graphics3D):

bb = {{0.35, 5.9709, -0.494276}, {0.25, 6.4709, -0.794276}, {0.3, 
    6.2709, -0.564276}, {0.3, 5.6709, -0.594276}};
lg = {{0.3, -3.41212, -1.20591}, {0.4, -3.21543, -1.12591}, {0.4, \
-3.61472, -1.33312}};
style = {{Blue, PointSize[0.04]}, {Green, PointSize[0.02]}};
Graphics3D[MapThread[{Sequence @@ #1, Point@#2} &, {style, {bb, lg}}],
  Axes -> True, BoxRatios -> {1, 0.5, 1}]

enter image description here

$\endgroup$

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service, privacy policy and cookie policy

Not the answer you're looking for? Browse other questions tagged or ask your own question.