I have a two lists:
list1 = {{x1, y1}, {x2, y2}, {x3, y3}, {x4, y4}, {x5, y5}} and list2 = {z1, z2, z3, z4, z5} and I want to make a third one like this output = {{x1, y1, z1}, {x2, y2, z2}, {x3, y3, z3}, {x4, y4,z4}, {x5, y5, z5}}
What nice command can do the trick? It is to do a ListPlot3D with two lists with more than 10000 entries.
I tried with Map and pure function but it is giving me troubles.
Thank you
$\begingroup$
$\endgroup$
4
5 Answers
$\begingroup$
$\endgroup$
1
Try this
Transpose@{list1[[All,1]],list1[[All,2]],list2}
or this
MapThread[{#1[[1]], #1[[2]], #2} &, {list1, list2}]
answered Jun 13, 2014 at 15:31
-
$\begingroup$ Thanks, I will use the MapThread, it is nice! $\endgroup$ Jun 13, 2014 at 16:08
$\begingroup$
$\endgroup$
Transpose[Join @@ {Transpose@list1, {list2}}]
or
Join @@@ Transpose[{list1, List /@ list2}]
or
Transpose[{Sequence @@ Transpose@list1, list2}]
or
ArrayReshape[{list1, list2}, Dimensions[list1] + {0, 1}]
(* {{x1,y1,z1},{x2,y2,z2},{x3,y3,z3},{x4,y4,z4},{x5,y5,z5}} *)
$\begingroup$
$\endgroup$
With the last parameter of Join:
Join[list1, List /@ list2, 2]
$\begingroup$
$\endgroup$
Flatten /@ MapThread[List, {list1, list2}]
or
MapThread[Append, {list1, list2}]
or
Thread[f[list1, list2]] /. f -> Append
answered Jun 13, 2014 at 18:10
$\begingroup$
$\endgroup$
Here is another one, with MapIndexed
MapIndexed[ {list1[[Last@#2,1]],list1[[Last@#2,2]],#1},list2]
MapThread[Append, {list1, list2}]$\endgroup$ArrayReshape, see e.g. this question How to partition a list in a specific way? $\endgroup$