0
$\begingroup$

This question already has an answer here:

I have a two lists: list1 = {{x1, y1}, {x2, y2}, {x3, y3}, {x4, y4}, {x5, y5}} and list2 = {z1, z2, z3, z4, z5} and I want to make a third one like this output = {{x1, y1, z1}, {x2, y2, z2}, {x3, y3, z3}, {x4, y4,z4}, {x5, y5, z5}} What nice command can do the trick? It is to do a ListPlot3D with two lists with more than 10000 entries. I tried with Map and pure function but it is giving me troubles. Thank you

$\endgroup$

marked as duplicate by Kuba, Öskå, Michael E2, ciao, m_goldberg Jun 13 '14 at 22:50

This question has been asked before and already has an answer. If those answers do not fully address your question, please ask a new question.

2
$\begingroup$

Try this

Transpose@{list1[[All,1]],list1[[All,2]],list2}

or this

MapThread[{#1[[1]], #1[[2]], #2} &, {list1, list2}]
$\endgroup$
  • $\begingroup$ Thanks, I will use the MapThread, it is nice! $\endgroup$ – lambertmular Jun 13 '14 at 16:08
3
$\begingroup$
Transpose[Join @@ {Transpose@list1, {list2}}]

or

Join @@@ Transpose[{list1, List /@ list2}]

or

Transpose[{Sequence @@ Transpose@list1, list2}]

or

ArrayReshape[{list1, list2}, Dimensions[list1] + {0, 1}]

(* {{x1,y1,z1},{x2,y2,z2},{x3,y3,z3},{x4,y4,z4},{x5,y5,z5}} *)
$\endgroup$
2
$\begingroup$

With the last parameter of Join:

Join[list1, List /@ list2, 2]
$\endgroup$
2
$\begingroup$
Flatten /@ MapThread[List, {list1, list2}]

or

MapThread[Append, {list1, list2}]

or

Thread[f[list1, list2]] /. f -> Append
$\endgroup$
1
$\begingroup$

Here is another one, with MapIndexed

 MapIndexed[ {list1[[Last@#2,1]],list1[[Last@#2,2]],#1},list2]
$\endgroup$

Not the answer you're looking for? Browse other questions tagged or ask your own question.