4
$\begingroup$

I would like to create a contour plot of $e^z-\dfrac{z-1}{z+1}$ that looks like the picture on the left, but can only manage the one on the right. I have tried incrreasing the number of contours, but this doesn't have any effect. Am I missing something fundamental?

Show[Table[ContourPlot[{Im[E^(x + I y) - ((x + I y) - 1)/(x + I y) + 1] == k, 
Re[E^(x + I y) - ((x + I y) - 1)/(x + I y) + 1] == k}, {x, -4, 4}, {y, -20, 20}, 
ContourStyle -> {Directive[{Red}], Directive[{Blue}]}, 
PlotPoints -> 100, Contours -> 20, AspectRatio -> Automatic], {k, -10, 10, 2}]]

The plot I am trying to recreate is from this website (specific PDF).

$\endgroup$
9
$\begingroup$

The main thing you missed was that the picture on the left shows contours of the amplitude and phase, not the real and imaginary parts.

I couldn't get a good result for both sets of contours in one plot, so here I create the two plots separately and combine them with Show:

f[z_] := Exp[z] - (z - 1)/(z + 1)

Show[
 ContourPlot[#1[f[x + I y]], {x, -4, 4}, {y, -20, 20},
    ContourStyle -> #2, Contours -> #3, 
    AspectRatio -> Automatic, ContourShading -> None, PlotPoints -> 30] & @@@ 
   {{Abs, Blue, Exp @ Range[-5, 5]},
   {Arg, Red, Range[-Pi, Pi, Pi/5]}}
]

enter image description here

$\endgroup$
  • $\begingroup$ Great - that you ! I just tried something different, but you are right, I did miss that - thank you again :) $\endgroup$ – martin Jun 8 '14 at 13:27

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service, privacy policy and cookie policy

Not the answer you're looking for? Browse other questions tagged or ask your own question.