I am plotting to data curves using ListLinePlot. I like the look of Filling, but this is going to be printed, so I want something both black and white friendly, but giving more definition and separation than changing the opacity of the filling. Ideally, I would either have one hatched and the other filled solid gray, or both hatched in opposite directions or something such that they can be identified separately. This is what I have so far that I may just use if I can't find anything better:

data1 = exPDMIABSA[[1]];
data2 = exPDMIAwater[[1]];
ListLinePlot[{data1, data2},
  PlotStyle -> {Black, Directive[Dashed, Black]},
  Filling -> Axis,
  FillingStyle -> Directive[Opacity[0.7], Gray]]

enter image description here

Three related questions I've found are

RegionPlot (or FillingStyle) using hash lines?


Filling a polygon with a pattern of insets


How can I make hatching filling of plot

but none seems to address this situation. They seem to be dealing with shapes and (region)plots and not ListPlots. While it is entirely possible that they are very closely related, I'm not sure how to use any of those answers for my situation.


  • $\begingroup$ The image link is broken. $\endgroup$
    – Szabolcs
    Commented Jun 5, 2014 at 21:31
  • $\begingroup$ I updated it a few minutes ago, and it seems to be working for me. Is it still not working? Is it possible that my edit hasn't updated yet? @Szabolcs $\endgroup$
    – ThomasH
    Commented Jun 5, 2014 at 21:35
  • $\begingroup$ It's working now. Please use's SE's image hosting if possible (I do not know if it's possible for new users). $\endgroup$
    – Szabolcs
    Commented Jun 5, 2014 at 21:48
  • 1
    $\begingroup$ What I'd try is using the approach shown in the posts you linked, especially the last one. These rely on having a function to plot, not discrete data. You have discrete data, however, you can convert it to a function using Interpolation. Set InterpolationOrder -> 1 if that's what you need (this is what List(Line)Plot does). $\endgroup$
    – Szabolcs
    Commented Jun 5, 2014 at 21:51
  • $\begingroup$ @Szabolcs The use of the interpolation function and the last linked question worked well and seemed pretty easy and short to implement. Here is the new figure. $\endgroup$
    – ThomasH
    Commented Jun 6, 2014 at 13:21

3 Answers 3


Since Mathematica 12.1 it is possible to do this with HatchFilling:

ListPlot[Transpose@Table[{15 - x, 2 Sin[x] + x}, {x, 0, 15, 0.1}], 
    PlotStyle -> Black, Filling -> Bottom, 
    FillingStyle -> {1 -> HatchFilling[-Pi/4], 2 -> HatchFilling[Pi/4]}, 
    Joined -> True]

enter image description here

Of course, the hashing can be styled in many ways.


This is what I've ended up doing.

data1 = exPDMIABSA[[1]];
data2 = exPDMIAwater[[1]];
Show[ListLinePlot[{data1, data2}, 
  PlotStyle -> {Directive[Dashed, Black], Black}, 
  Filling -> {2 -> Axis}, FillingStyle -> Gray], 
  y < Interpolation[data1, InterpolationOrder -> 1][x] && y > 0, {x, 
   300, 375}, {y, 0, 17000}, Mesh -> 50, MeshFunctions -> {1000 #1 - #2 &}, 
  BoundaryStyle -> None, MeshStyle -> Thickness[.005], 
  PlotStyle -> Transparent]]

Mathematica graphics

The RegionPlot is based on this question after a suggestion in the comments to the question by Szabolcs.

Of course the same could be done for the other region in the opposite direction by switching the sign in the MeshFunctions. Also, because of the scale, the slope of the MeshFunctions was changed. The number of hatchings can be changed by changing Mesh. The default lines were a little thin for me so I thickened them with MeshStyle -> Thickness[.005].

For certain circumstances, it might be easier to define interpolation functions for each data set such as data1func = Interpolation[data1, InterpolationOrder -> 1] and just Plot that.

To me this seemed a little simpler, faster, and more general than the answer by Kuba to this question.


This is not the fastest way but I think it is fast and short enough. And, first of all, clear.

dat = RandomReal[2, 10];
dat2 = RandomReal[2, 10];
poly = ListLinePlot[{dat, dat2}, Filling -> Axis, PlotStyle -> [email protected]
       ] // Normal // Cases[#, Polygon[x_] :> x, \[Infinity]] &;

inPolyQ[poly_, pt_] := Graphics`Mesh`PointWindingNumber[poly, pt] =!= 0

With[{copt = Sequence[MaxRecursion -> 1, PlotPoints -> 100, BoundaryStyle -> Black,
                      Mesh -> {Range[0, 15, .1]}, MeshStyle -> Black, PlotStyle -> None]},
  Quiet@RegionPlot[ inPolyQ[poly[[1]], {x, y}], {x, 0, 11}, {y, -.1, 2.1}, 
                    MeshFunctions -> {# + #2 &}, copt],
  Quiet@RegionPlot[ inPolyQ[poly[[2]], {x, y}], {x, 0, 11}, {y, -.1, 2.1}, 
                    MeshFunctions -> {# - #2 &}, copt],
  AspectRatio -> Automatic, ImageSize -> 600]]

enter image description here

Based on:

RegionPlot (or FillingStyle) using hash lines? by Heike


How to check if a 2D point is in a polygon? by rm-rf

  • $\begingroup$ Thanks @Kuba! That is a pretty graphic. I think I'll go with @Szabolcs suggestion in the comments to the question as that seems easier to me, and I understand it better. I might just post it as my own answer for others who might be wondering. $\endgroup$
    – ThomasH
    Commented Jun 6, 2014 at 13:25

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service and acknowledge you have read our privacy policy.

Not the answer you're looking for? Browse other questions tagged or ask your own question.