One-column table not properly displayed by TableForm

Question

I want a table with a single column of data, and with headings along both the rows and the column. One might expect it to work like this:

TableForm[{"one", "two", "three"}, 
 TableHeadings -> {{"$10MM", "$20MM", "$30MM"}, {"col"}}]

But this does not work; it displays the data and the row labels correctly, but it does not label the column. What am I missing?

Answer 1

You present a single row vector to TableForm, which is rather hankering for a column vector (or matrix).

Instead of {"one", "two", "three"} you need {{"one"}, {"two"}, {"three"}}. There are many ways to achieve this, one of them List /@ {"one", "two", "three"}:

TableForm[List /@ {"one", "two", "three"}, 
 TableHeadings -> {{"$10MM", "$20MM", "$30MM"}, {"col"}}]

Answer 2

I would prefer:

Grid[{{"", "col"}}~Join~
  Transpose[{{"$10M", "$20M", "$30M"}, {"one", "two", "three"}}], 
 Dividers -> All]

because of its clarity and all the additional Grid-options.

Answer 3

To be different, and to illustrate behavior of TableForm which I previously described here, which is that directions flip with every additional List level:

TableForm[
 {{{"one", "two", "three"}}}, 
 TableHeadings -> {{Column@{"$10MM", "$20MM", "$30MM"}}, {"col"}}
]

There may be a cleaner way to do the headings than using Column but I can't think of it at the moment.