Strange behavior of Reduce with a cubic equation

Question

This equation: $(\frac{-a}{x})^2=\sqrt{\frac{1}{x}}$ at $a > 0$ and $x > 0$ has a clear solution $x=a^{4/3}$, doesn't it? However,

Reduce[(-(a/x))^2 == (1/x)^(1/2) && x > 0 && a > 0] // ToRadicals

yields

a > 0 && x == (-1)^(2/3) a^(4/3)

where

 ComplexExpand[(-1)^(2/3)]

-(1/2) + (I Sqrt[3])/2

is a complex number, numerically N @ % yields -0.5 + 0.866025 I.

Why?

Answer 1

The issue we encounter here is closely related to the problem exposed more extensively here:
Finding parameters making real part of eigenvalues vanish, however in this case we have to tackle with a bit more harmful problem. This is an undesired feature of the system.
Namely Root[-a^4 + #1^3 &, 1] has been pointed out as a solution, nevertheless since a is symbolic the system doesn't decide at an appropriate order which one of the three solutions Root[-a^4 + #1^3 &, k] where k ∈ { 1, 2, 3} it is and then ToRadicals interprets it arbitrarily:

ToRadicals @ Table[ Root[-a^4 + #1^3 &, k], {k, 3}]

 {(-1)^(2/3) a^(4/3), -(-1)^(1/3) a^(4/3), a^(4/3)}

One can use sometimes options in Reduce: Quartics and Cubics nonetheless they don't help for the problem at hand.

Reduce[(-(a/x))^2 == (1/x)^(1/2) && x > 0 && a > 0, {a, x}, Cubics -> True]

a > 0 && x == Root[-a^4 + #1^3 &, 1]

Since Mathematica allows for various ways of solving problems one can get the proper result e.g. with this:

FullSimplify[ Reduce[ (-(a/x))^2 == (1/x)^(1/2) && x > 0, {x}], a > 0]

a^(4/3) == x

or

FullSimplify[ x /. Solve[(-(a/x))^2 == (1/x)^(1/2) && x > 0 && a > 0,
                          {a, x}] // Quiet, a > 0]