How do I select only those lists whose elements are all above a certain number?

Question

I'm essentially doing coin flips, using RandomReal to populate a bunch of lists, each with 8 elements. I then want to select only those lists for which all elements are greater than a certain number, e.g. .5.

So far I have this:

class = RandomReal[1, {100, 8}];
pass = Select[class, #[[1]] > (.5) &]

but this doesn't work. I suspect a simple Select function would do the trick, but I can't seem to get the syntax right to test every element of the nested listed against a certain number and then only return those lists for which every element passes. Or indeed simply to return the number of sublists for which every element passes. Thanks.

Answer 1

Maybe I'm missing something but this seems like a straightforward application of Min:

SeedRandom[1]
class = RandomReal[1, {100, 5}];

Select[class, Min[#] > 0.5 &]

{{0.823403, 0.551229, 0.746259, 0.964339, 0.89009},
 {0.745146, 0.714426, 0.809069, 0.833149, 0.725859}}

Answer 2

This answer summarizes the answers given in the comments to this question. I have changed two parameter values to keep the output small. Since set the values of the two parameters with With, it will to restore the original values should that be desired.

With[{size = 4}, SeedRandom @ 42; class = RandomReal[1, {100, size}]];

With[{threshold = .6}, Column@Select[class, And @@ ((# > threshold &) /@ #) &]]

With[{threshold = .6}, Column@Select[class, And @@ Thread[# > threshold] &]]

With[{threshold = .6}, Column@Select[class, Total[UnitStep[threshold - #]] == 0 &]]

With[{threshold = .6}, Column@Pick[class, Times @@ UnitStep[#] == 1 & /@ (class - threshold)]]

All of the four above expressions return

{0.717287,0.754353,0.860349,0.996966}
{0.763037,0.631343,0.89637,0.621647}

Answer 3

Maybe it can be done also as follows:

Select[Select[#, # > 0.5 &] & /@ class, Length[#] == 8 &]