I think the title says it all. I know about ImageCapture which seems to capture stills.

Can ImageCapture be made to capture a movie analogous to using say QuickTime player (and export to video format)?

Likewise, if a microphone is connected to your computer (e.g. something that can be used by QuickTime to record) can Mathematica record sound?


Because I was aware of ImageCapture prior to posting this question I did some searches looking for functions that may involve recording e.g.:


But got no hits. It is frustrating to find that capturing an image gets its own intuitive function name whereas recording sound does not. But even more frustration that on my Mac I get this:

SystemDialogInput::unsupt: "The \!\(\"RecordSound\"\) dialog type is not currently supported on this platform. "

Edit 2

Thanks for the frame by frame type capture solutions posted below but I was hoping for a more direct (native) solution -- even if undocumented -- that would be analogous to me just controlling QuickTime from within Mma (which can be done).

As for recording sound, does anyone know why SystemDialogInput["RecordSound"] isn't supported on Macs and what potential methods exist for Mac?



Edit 3

In Version 9 SystemDialogInput["RecordSound"] works on Macs.

  • 1
    $\begingroup$ SystemDialogInput["RecordSound"] brings up a dialog to record sound. With a loop and CurrentImage[] you can probably record video. Is this satisfactory? $\endgroup$
    – Rojo
    Commented Apr 19, 2012 at 4:11
  • $\begingroup$ Whatever you do, don't do a Dynamic@ImageCapture[] :) $\endgroup$
    – CHM
    Commented Apr 19, 2012 at 4:13
  • $\begingroup$ @CHM, I could resist and did it, but nothing exploded :/ $\endgroup$
    – Rojo
    Commented Apr 19, 2012 at 5:23
  • $\begingroup$ @Rojo I'm using MMA 8.0.4 on OSX, and when I evaluated it my MMA froze. I had to force-quit it, because it constantly closed and reopened my iSight. It's not like something blows up, it's just inconvenient :P $\endgroup$
    – CHM
    Commented Apr 19, 2012 at 16:11

5 Answers 5


SystemDialogInput["RecordSound"] will bring up a dialog that let's you record sound. It works both on Windows and Mac in v9, but only on Windows in earlier versions. It doesn't work on Linux.

But what if you need to record sound without user interaction, and you want to avoid a modal dialog? The right way is to use some external and documented tool (e.g. sox), but I happened to try to dissect the "RecordSound" dialog, and here are the results. These may be Mac-specific.

On Mac, I believe some sort of initialisation may be needed, but I'm not entirely sure. Evaluating

FrontEndExecute[FrontEnd`RecordSound[7, 0]]
FrontEndExecute[FrontEnd`RecordSound[8, 0]]

will probably do this. This is the least clear point so far. This may not be needed on Windows.


  • FrontEndExecute[FrontEnd`RecordSound[5]] will list the available devices by number
  • FrontEndExecute[FrontEnd`RecordSound[6, deviceNumber]] will list the available formats for the device
  • FrontEndExecute[FrontEnd`RecordSound[1, deviceNumber, formatNumber]] will start recording. It returns control immediately.
  • FrontEndExecute[FrontEnd`RecordSound[2]] will stop recording and return the duration.
  • FrontEndExecute[FrontEnd`RecordSound[3]] will return the recorded sound (it's the "OK" button in the dialog)
  • FrontEndExecute[FrontEnd`RecordSound[4]] will probably discard the recorded sound (it's the Cancel button)
  • FrontEndExecute[FrontEnd`RecordSound[9, 0]] will return the current volume of the recorded sound, and is used for the progress indicator in the dialog.

Warning: This functionality is undocumented, and not meant for end users. I'm just guessing at how it works. There's a real risk that playing with these will crash your front end, mess up its internal state or will cause a memory leak. Use at own risk.

vid[time_, frame_] := Module[{tag},
  Reap[Do[Sow[CurrentImage[], tag];
     Pause[frame], {Round[time/frame]}]][[2, 1]]]

So, vid[1., 0.001] would return a list of snapshots taken every 0.001 seconds over a second.

This opens a dialog that allows you to record sound and returns it as a Sound object


You can use CurrentImage and set up a ScheduledTask to capture frames at the desired fps. Something like:

frames = {};
fps = 30;
task = CreateScheduledTask[frames = {CurrentImage[], frames};, 1/fps];

Then start and stop recording with


Note that stopping the task won't turn off the camera on a Mac (don't know about other systems). In order to turn it off, you'll have to execute IMAQ`StopCamera[]

Finally, to play the video back, run

ListAnimate[Reverse@Flatten@frames, fps]

Re: sound, SystemDialogInput["RecordSound"]; as Rojo pointed out is the way to go. However, this does not work on a mac and I'm not aware of an easy way to do it. You could perhaps interface with java to record sound, but I don't know anything about it.

  • $\begingroup$ I'm intrigued as to how much you can trust the scheduling to be done in time and not too off $\endgroup$
    – Rojo
    Commented Apr 19, 2012 at 4:25
  • 1
    $\begingroup$ @Rojo you need a RT operating system implementation to be sure that the frames are captured on time ... and none of them runs Mma. $\endgroup$ Commented Apr 19, 2012 at 4:33
  • $\begingroup$ @belisarius my intrigue is more statistic, practical than exact. I'm testing, for example, to run it for 2 seconds at 100fps and get a total of 131 frames recorded $\endgroup$
    – Rojo
    Commented Apr 19, 2012 at 4:50
  • $\begingroup$ My approach also fails. In the sense that it takes 3.5 seconds to record what should be 2 seconds of video at 100fps $\endgroup$
    – Rojo
    Commented Apr 19, 2012 at 4:51
  • $\begingroup$ @Rojo That's because of Mathematica's inherent slowness in accessing the hardware. Yours isn't accurate either — just a different kind of inaccuracy. On my machine, vid[2., 1/100]; // AbsoluteTiming takes 2.14 seconds :) $\endgroup$
    – rm -rf
    Commented Apr 19, 2012 at 4:52

I used the answer above to create a small function to grab a bit of sound using the default microphone on my computer.

recordTime[t_: 1] := 
 Module[{device = FrontEndExecute[FrontEnd`RecordSound[5]]},
  FrontEndExecute[FrontEnd`RecordSound[1, Keys[First[device]], 1]];

This function could easily be extended to control which microphone (if multiple devices were present) and which format to use.

I am using a Mathematica 10 on Windows 8.

NOTE: I really wanted to upvote the answer that gave me the information I needed here, but i'm new and i don't have enough "reputation" to vote yet.

  • 1
    $\begingroup$ Regarding reputation: you do now. $\endgroup$
    – Mr.Wizard
    Commented May 22, 2015 at 12:26

For a GUI experience, you can use VideoCapture[] and AudioCapture[]. If you want to have programmatic control to streams from your camera or microphone, You can look into VideoRecord[] and AudioRecord[]


Your Answer

By clicking “Post Your Answer”, you agree to our terms of service and acknowledge you have read our privacy policy.

Not the answer you're looking for? Browse other questions tagged or ask your own question.