Computing the distance between two curves obtained from image data?

Question

I've got some image data that I've binarized. The image contains two curves, from which I'd like to compute the distance between (eventually computing an average radius for each point in the picture). I've done the computation, but it's done in C programmer style, and fairly ugly

data = ImageData[ b ] ;
{h, w} = Dimensions[data] ;

min = Table[0, {w}] ;
max = Table[0, {w}] ;
averageRadiusList = {} ;
scale = 0.1 / w  ;

For [ column = 1, column < w + 1, column++,
 For [ row = 1, row < h/2, row++,
   If [
    data[[row, column]] != 1,
       min[[column]] =  row ; Break
    ]
   ]
  For [ row = h, row > h/2, row--,
   If [
    data[[row, column]] != 1,
      max[[column]] =  row ; Break
    ]
   ]
  If [ min[[column]] !=  0  && max[[column]] != 0,

   AppendTo[
    averageRadiusList, {column * scale,
     scale * (max[[column]] - min[[column]])/2} ]
   ]
 ]

I was wondering if there's a more natural "Mathematica way" of doing things ... something that is presumably more elegant, efficient, compact, and more general?

Answer 1

Lets start with an example image

img = Binarize@
  Image[Plot[{Sin[2 x], 2 + Cos[3 x]}, {x, 0, 2 Pi}, Axes -> False, 
    PlotStyle -> Black, Background -> White, ImagePadding -> None, 
    PlotRangePadding -> {None, .1}]]

To find the distance between the two curves you could do something like

data = ImageData[img];
w = Dimensions[data][[2]];
scale = .1/w;

averageRadiusList = Reap[Sow @@@ Position[data, 0], Range[w],
    {scale #1, scale (Max[#2] - Min[#2])/2} &][[2, All, 1]];

ListPlot[averageRadiusList]

What this code does is to find the indices of all black points in img. The combination of Sow and Reap will effectively group these coordinates by their column index and for each group return {scale c, scale (Max[rows]-Min[rows])/2} where c is the column index, and rows is a list of row indices of all black points in the plot that have column index c.