# How to do this complex integration on the real line?

$m, r$ are parameters in the following integral:

Integrate[z Exp[I z r]/Sqrt[z^2 + m^2], {z, -∞, ∞}]


How to do this integration directly? The result should be 2 I m BesselK[1, mr]. This post may be helpful, but I haven't found anything to solve this question.

As suggested by b.gatessucks, this integration can be converted to the following one which can be computed by Mathematica:

Integrate[Exp[I z r]/Sqrt[z^2 + m^2], {z, -∞, ∞}]


and its result is 2 BesselK[0, m r]. But this method may be not general, because we do not know which form can be recognized by Mathematica for other similar problems.

• You can omit the z in the numerator, integrate and then differentiate with respect to r. – b.gates.you.know.what Mar 6 '14 at 14:01
• @b.gatessucks Yeap! Thanks! But how to do the new integration? – Eden Harder Mar 6 '14 at 14:19
• Use Assumptions -> r > 0 && m > 0 which will assume that m and r are positive and real numbers. For a detailed discussion of contour integration I recommend e.g. this post How to calculate contour integrals with Mathematica?. – Artes Mar 6 '14 at 14:25
• It diverges. What result were you expecting to obtain? – Daniel Lichtblau Mar 6 '14 at 21:06
• @DanielLichtblau Thanks! I update the question. – Eden Harder Mar 7 '14 at 0:49

I suspect you want the principal value, since the integral is divergent.

Integrate[
z Exp[I z r]/Sqrt[z^2 + m^2], {z, -∞, ∞},
PrincipalValue -> True, Assumptions -> m > 0 && r ∈ Reals]
(*
2 I m BesselK[1, m Abs[r]] Sign[r]
*)


If r > 0, then it agrees with your expected answer.

Another derivation, although it seems more difficult to justify (multiply by Exp[-Abs[a] z] and take the limit as a -> 0):

intplus  = Integrate[(E^(-a z) z Exp[I z r]) / Sqrt[m^2 + z^2], {z, 0, ∞},
Assumptions -> m > 0 && a > 0 && r ∈ Reals];
intminus = Integrate[(E^(a z)  z Exp[I z r]) / Sqrt[m^2 + z^2], {z, -∞, 0},
Assumptions -> m > 0 && a > 0 && r ∈ Reals];
FullSimplify[intminus + intplus /. a -> 0, m > 0 && r > 0]
(*
2 I m BesselK[1, m r]
*)


where the parts are

{intminus, intplus}
(*
{  1/2  m π (BesselY[1, m (a + I r)] + StruveH[-1, m (a + I r)]),
-(1/2) m π (BesselY[1, m (a - I r)] + StruveH[-1, m (a - I r)])}
*)