Define inverse for the custom operator

Question

I want to define simple matrix algebra (inspired by the following posts: Block Matrix Algebra with Mathematica ; How to define custom operators ).

I assume the funtion MatrixMult[A_,B_] to be the matrix product. I surely can define some properties of this function, like linearity, associativity etc. (see referenced posts). Now I want to solve simple matrix equation

Solve[MatrixMult[A, X]==B,X]

Obviously, the answer is

{{X -> InverseFunction[MatrixMult, 2, 2][A, B]}}

Now the question is how can I explicitly define that the inverse of my function is the following:

InverseFunction[MatrixMult, 2, 2][A_, B_] := MatrixMult[Inverse[A], B]

(the last line results in "Tag InverseFunction is Protected" error)

Answer 1

One can use UpValues to control the behavior of your MatrixMult function. We also need to teach MatrixMult how to handle Inverse as well:

MatrixMult[a_, MatrixMult[Inverse[a_], b_]] := b

MatrixMult /: InverseFunction[MatrixMult, 2, 2] = MatrixMult[Inverse[#1], #2]&

Notice that I don't try to give a definition for InverseFunction[MatrixMult, 2, 2][a_, b_] because then MatrixMult is buried to deep for UpValues to work. Now, let's try using Solve:

Solve[MatrixMult[A, X] == B, X]

Solve::ifun: Inverse functions are being used by Solve, so some solutions may not be found; use Reduce for complete solution information.

{{X -> MatrixMult[Inverse[A], B]}}

One could avoid the message by explicitly telling Solve that you want to use inverse functions:

Solve[MatrixMult[A, X] == B, X, InverseFunctions->True]

{{X -> MatrixMult[Inverse[A], B]}}

VerifySolutions

The MatrixMult DownValues above is needed because Solve tries to verify its solution. An alternative to giving MatrixMult the above DownValues is to tell Solve not to verify its solution:

Clear[MatrixMult]
MatrixMult /: InverseFunction[MatrixMult, 2, 2] = MatrixMult[Inverse[#1], #2]&;

Solve[MatrixMult[A, X] == B, X, InverseFunctions->True, VerifySolutions->False] 

{{X -> MatrixMult[Inverse[A], B]}}