# Improper mutiple integral

I would like to solve the following integral:

Integrate[y Erf[a Sqrt[x^2 + y^2]]/Sqrt[x^2 + y^2]
Exp[-b ((x - c)^2 + y^2)], {x, -∞, ∞},
{y, 0, ∞}, Assumptions -> {a > 0, b > 0, c > 0}]


If I add such input in Mathematica, it takes ages to solve it and in the end it could not. The solution is obviously a function of a, b, and c. Any ideas, tricks how to tackle this problem?

Here's a way...

Convert to polar coordinates

Integrate[
r (r Sin[t]) Erf[a r]/r Exp[-b ((r Cos[t] - c)^2 + (r Sin[t])^2)],
{r, 0, Infinity}, {t, 0, Pi}, Assumptions -> {a > 0, b > 0, c > 0}]


But that doesn't work, so...

Do the t integral first

tInt = Integrate[r r Sin[t] Erf[a r]/r Exp[-b ((r Cos[t] - c)^2 + (r Sin[t])^2)],
{t, 0, Pi}]
(*
(E^(-b (c + r)^2) (-1 + E^(4 b c r)) Erf[a r])/(2 b c)
*)


The r integral won't evaluate still, so...

Try differentiating with respect to the parameter a

This trick I learned in Salomon Bochner's Fourier Integrals. In this case, I should note that tInt equals zero at a -> 0. The value of daInt is the partial derivative with respect to a of the integral we wish to find. Later we will antidifferentiate with respect to a (using a substitution). Normally, by the Fundamental Theorem of Calculus, I would subtract the value at a == 0, but since the value is zero, you won't see that step below.

daInt = Integrate[D[tInt, a], {r, 0, Infinity}, Assumptions -> {a > 0, b > 0, c > 0}]
(*
E^(-((a^2 b c^2)/(a^2 + b)))/(a^2 + b)^(3/2)
*)


But this won't integrate with respect to a, so...

Try another substitution, u = a^2 + b

The Jacobian factor is 1/(2 Sqrt[u - b]).

aInt = Integrate[1/(2 Sqrt[u - b]) daInt /. a^2 -> u - b,
u, Assumptions -> {a > 0, b > 0, c > 0}];
Simplify[aInt /. u -> a^2 + b, a > 0 && b > 0 && c > 0]
(* (Sqrt[π] Erf[a Sqrt[b/(a^2 + b)] c])/(2 b^(3/2) c) *)


To me, getting an answer at this step was a miracle....so

Check numerically

With[{a = 2, b = 1, c = 1},
{NIntegrate[
y Erf[a Sqrt[x^2 + y^2]] / Sqrt[x^2 + y^2] Exp[-b ((x - c)^2 + y^2)],
{x, -∞, ∞}, {y, 0, ∞}],
(Sqrt[π] Erf[a Sqrt[b/(a^2 + b)] c])/(2 b^(3/2) c) // N}
]
(* {0.70375, 0.70375} *)


You can verify for other values as well. Seems like I didn't make a mistake. So the answer is $$\frac{\sqrt{\pi }\ \text{erf}\left(a c \sqrt{\frac{b}{a^2+b}}\right)}{2 b^{3/2} c}$$

• Thank you very much. Now I will go trough all the steps! Commented Jan 30, 2014 at 22:56
• @user113891 You're welcome! I added some explanation of some steps. Commented Jan 30, 2014 at 23:06
• You're the real baba ji :) Commented Jan 31, 2014 at 12:23
• @MichaelE2 I have tried now to solve the similar integral following your steps. Now the integral is Commented Feb 1, 2014 at 11:25
• @MichaelE2 I have tried now to solve the similar integral following your steps. The only difference is that the erf and exp functions in the original integral are multiplied by x, instead of y. After the conversion to Polar Coordinates, I would get: tInt = Integrate[r r Cos[t] Erf[a r]/r Exp[-b ((r Cos[t] - c)^2 + (r Sin[t])^2)], {t, 0, Pi}] (* E^(-b (c^2 + r^2)) [Pi] r BesselI[1, 2 b c r] Erf[a r] *) Now with BesselI function it is not possible anymore to do the last step integration. I tried to express cos[t] with sin[t] via trigonometric identities, but it didn't work. Any idea? Commented Feb 1, 2014 at 11:54